lib/PublicInbox/Watch.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::Watch;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable qw(eml_from_path warn_ignore_cb);
  11 use PublicInbox::Filter::Base qw(REJECT);
  12 use PublicInbox::Spamcheck;
  13 use PublicInbox::Sigfd;
  14 use PublicInbox::DS qw(now);
  15 use PublicInbox::MID qw(mids);
  16 use PublicInbox::ContentHash qw(content_hash);
  17 use PublicInbox::EOFpipe;
  18 use POSIX qw(_exit WNOHANG);
  19
  20 sub compile_watchheaders ($) {
  21         my ($ibx) = @_;
  22         my $watch_hdrs = [];
  23         if (my $whs = $ibx->{watchheader}) {
  24                 for (@$whs) {
  25                         my ($k, $v) = split(/:/, $_, 2);
  26                         # XXX should this be case-insensitive?
  27                         # Or, mutt-style, case-sensitive iff
  28                         # a capital letter exists?
  29                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  30                 }
  31         }
  32         if (my $list_ids = $ibx->{listid}) {
  33                 for (@$list_ids) {
  34                         # RFC2919 section 6 stipulates
  35                         # "case insensitive equality"
  36                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  37                         push @$watch_hdrs, ['List-Id', $re ];
  38                 }
  39         }
  40         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  41 }
  42
  43 sub new {
  44         my ($class, $cfg) = @_;
  45         my (%mdmap, $spamc);
  46         my (%imap, %nntp); # url => [inbox objects] or 'watchspam'
  47
  48         # "publicinboxwatch" is the documented namespace
  49         # "publicinboxlearn" is legacy but may be supported
  50         # indefinitely...
  51         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  52                 my $k = "$pfx.watchspam";
  53                 defined(my $dirs = $cfg->{$k}) or next;
  54                 $dirs = PublicInbox::Config::_array($dirs);
  55                 for my $dir (@$dirs) {
  56                         my $url;
  57                         if (is_maildir($dir)) {
  58                                 # skip "new", no MUA has seen it, yet.
  59                                 $mdmap{"$dir/cur"} = 'watchspam';
  60                         } elsif ($url = imap_url($dir)) {
  61                                 $imap{$url} = 'watchspam';
  62                         } elsif ($url = nntp_url($dir)) {
  63                                 $nntp{$url} = 'watchspam';
  64                         } else {
  65                                 warn "unsupported $k=$dir\n";
  66                         }
  67                 }
  68         }
  69
  70         my $k = 'publicinboxwatch.spamcheck';
  71         my $default = undef;
  72         my $spamcheck = PublicInbox::Spamcheck::get($cfg, $k, $default);
  73         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  74
  75         $cfg->each_inbox(sub {
  76                 # need to make all inboxes writable for spam removal:
  77                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  78
  79                 my $watches = $ibx->{watch} or return;
  80                 $watches = PublicInbox::Config::_array($watches);
  81                 for my $watch (@$watches) {
  82                         my $url;
  83                         if (is_maildir($watch)) {
  84                                 compile_watchheaders($ibx);
  85                                 my ($new, $cur) = ("$watch/new", "$watch/cur");
  86                                 my $cur_dst = $mdmap{$cur} //= [];
  87                                 return if is_watchspam($cur, $cur_dst, $ibx);
  88                                 push @{$mdmap{$new} //= []}, $ibx;
  89                                 push @$cur_dst, $ibx;
  90                         } elsif ($url = imap_url($watch)) {
  91                                 return if is_watchspam($url, $imap{$url}, $ibx);
  92                                 compile_watchheaders($ibx);
  93                                 push @{$imap{$url} ||= []}, $ibx;
  94                         } elsif ($url = nntp_url($watch)) {
  95                                 return if is_watchspam($url, $nntp{$url}, $ibx);
  96                                 compile_watchheaders($ibx);
  97                                 push @{$nntp{$url} ||= []}, $ibx;
  98                         } else {
  99                                 warn "watch unsupported: $k=$watch\n";
 100                         }
 101                 }
 102         });
 103
 104         my $mdre;
 105         if (scalar keys %mdmap) {
 106                 $mdre = join('|', map { quotemeta($_) } keys %mdmap);
 107                 $mdre = qr!\A($mdre)/!;
 108         }
 109         return unless $mdre || scalar(keys %imap) || scalar(keys %nntp);
 110
 111         bless {
 112                 max_batch => 10, # avoid hogging locks for too long
 113                 spamcheck => $spamcheck,
 114                 mdmap => \%mdmap,
 115                 mdre => $mdre,
 116                 pi_cfg => $cfg,
 117                 imap => scalar keys %imap ? \%imap : undef,
 118                 nntp => scalar keys %nntp? \%nntp : undef,
 119                 importers => {},
 120                 opendirs => {}, # dirname => dirhandle (in progress scans)
 121                 ops => [], # 'quit', 'full'
 122         }, $class;
 123 }
 124
 125 sub _done_for_now {
 126         my ($self) = @_;
 127         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 128         for my $im (values %{$self->{importers}}) {
 129                 next if !$im; # $im may be undef during cleanup
 130                 eval { $im->done };
 131                 warn "$im->{ibx}->{name} ->done: $@\n" if $@;
 132         }
 133 }
 134
 135 sub remove_eml_i { # each_inbox callback
 136         my ($ibx, $self, $eml, $loc) = @_;
 137
 138         eval {
 139                 # try to avoid taking a lock or unnecessary spawning
 140                 my $im = $self->{importers}->{"$ibx"};
 141                 my $scrubbed;
 142                 if ((!$im || !$im->active) && $ibx->over) {
 143                         if (content_exists($ibx, $eml)) {
 144                                 # continue
 145                         } elsif (my $scrub = $ibx->filter($im)) {
 146                                 $scrubbed = $scrub->scrub($eml, 1);
 147                                 if ($scrubbed && $scrubbed != REJECT &&
 148                                           !content_exists($ibx, $scrubbed)) {
 149                                         return;
 150                                 }
 151                         } else {
 152                                 return;
 153                         }
 154                 }
 155
 156                 $im //= _importer_for($self, $ibx); # may spawn fast-import
 157                 $im->remove($eml, 'spam');
 158                 $scrubbed //= do {
 159                         my $scrub = $ibx->filter($im);
 160                         $scrub ? $scrub->scrub($eml, 1) : undef;
 161                 };
 162                 if ($scrubbed && $scrubbed != REJECT) {
 163                         $im->remove($scrubbed, 'spam');
 164                 }
 165         };
 166         if ($@) {
 167                 warn "error removing spam at: $loc from $ibx->{name}: $@\n";
 168                 _done_for_now($self);
 169         }
 170 }
 171
 172 sub _remove_spam {
 173         my ($self, $path) = @_;
 174         # path must be marked as (S)een
 175         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 176         my $eml = eml_from_path($path) or return;
 177         local $SIG{__WARN__} = warn_ignore_cb();
 178         $self->{pi_cfg}->each_inbox(\&remove_eml_i, $self, $eml, $path);
 179 }
 180
 181 sub import_eml ($$$) {
 182         my ($self, $ibx, $eml) = @_;
 183
 184         # any header match means it's eligible for the inbox:
 185         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 186                 my $ok;
 187                 for my $wh (@$watch_hdrs) {
 188                         my @v = $eml->header_raw($wh->[0]);
 189                         $ok = grep(/$wh->[1]/, @v) and last;
 190                 }
 191                 return unless $ok;
 192         }
 193         eval {
 194                 my $im = _importer_for($self, $ibx);
 195                 if (my $scrub = $ibx->filter($im)) {
 196                         my $scrubbed = $scrub->scrub($eml) or return;
 197                         $scrubbed == REJECT and return;
 198                         $eml = $scrubbed;
 199                 }
 200                 $im->add($eml, $self->{spamcheck});
 201         };
 202         if ($@) {
 203                 warn "$ibx->{name} add failed: $@\n";
 204                 _done_for_now($self);
 205         }
 206 }
 207
 208 sub _try_path {
 209         my ($self, $path) = @_;
 210         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 211         if ($path !~ $self->{mdre}) {
 212                 warn "unrecognized path: $path\n";
 213                 return;
 214         }
 215         my $inboxes = $self->{mdmap}->{$1};
 216         unless ($inboxes) {
 217                 warn "unmappable dir: $1\n";
 218                 return;
 219         }
 220         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 221         local $SIG{__WARN__} = sub {
 222                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 223                 $warn_cb->($pfx, "path: $path\n", @_);
 224         };
 225         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 226                 return _remove_spam($self, $path);
 227         }
 228         foreach my $ibx (@$inboxes) {
 229                 my $eml = eml_from_path($path) or next;
 230                 import_eml($self, $ibx, $eml);
 231         }
 232 }
 233
 234 sub quit_done ($) {
 235         my ($self) = @_;
 236         return unless $self->{quit};
 237
 238         # don't have reliable wakeups, keep signalling
 239         my $done = 1;
 240         for (qw(idle_pids poll_pids)) {
 241                 my $pids = $self->{$_} or next;
 242                 for (keys %$pids) {
 243                         $done = undef if kill('QUIT', $_);
 244                 }
 245         }
 246         $done;
 247 }
 248
 249 sub quit {
 250         my ($self) = @_;
 251         $self->{quit} = 1;
 252         %{$self->{opendirs}} = ();
 253         _done_for_now($self);
 254         quit_done($self);
 255         if (my $idle_mic = $self->{idle_mic}) {
 256                 eval { $idle_mic->done };
 257                 if ($@) {
 258                         warn "IDLE DONE error: $@\n";
 259                         eval { $idle_mic->disconnect };
 260                         warn "IDLE LOGOUT error: $@\n" if $@;
 261                 }
 262         }
 263 }
 264
 265 sub watch_fs_init ($) {
 266         my ($self) = @_;
 267         my $done = sub {
 268                 delete $self->{done_timer};
 269                 _done_for_now($self);
 270         };
 271         my $cb = sub { # called by PublicInbox::DirIdle::event_step
 272                 _try_path($self, $_[0]->fullname);
 273                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 274         };
 275         require PublicInbox::DirIdle;
 276         # inotify_create + EPOLL_CTL_ADD
 277         PublicInbox::DirIdle->new([keys %{$self->{mdmap}}], $cb);
 278 }
 279
 280 # avoid exposing deprecated "snews" to users.
 281 my %SCHEME_MAP = ('snews' => 'nntps');
 282
 283 sub uri_scheme ($) {
 284         my ($uri) = @_;
 285         my $scheme = $uri->scheme;
 286         $SCHEME_MAP{$scheme} // $scheme;
 287 }
 288
 289 # returns the git config section name, e.g [imap "imaps://user@example.com"]
 290 # without the mailbox, so we can share connections between different inboxes
 291 sub uri_section ($) {
 292         my ($uri) = @_;
 293         uri_scheme($uri) . '://' . $uri->authority;
 294 }
 295
 296 sub cfg_intvl ($$$) {
 297         my ($cfg, $key, $url) = @_;
 298         my $v = $cfg->urlmatch($key, $url) // return;
 299         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 300         if (ref($v) eq 'ARRAY') {
 301                 $v = join(', ', @$v);
 302                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 303         } else {
 304                 warn "W: $key=$v is not a numeric value in seconds\n";
 305         }
 306 }
 307
 308 sub cfg_bool ($$$) {
 309         my ($cfg, $key, $url) = @_;
 310         my $orig = $cfg->urlmatch($key, $url) // return;
 311         my $bool = $cfg->git_bool($orig);
 312         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 313         $bool;
 314 }
 315
 316 # flesh out common IMAP-specific data structures
 317 sub imap_common_init ($) {
 318         my ($self) = @_;
 319         my $cfg = $self->{pi_cfg};
 320         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 321         for my $url (sort keys %{$self->{imap}}) {
 322                 my $uri = PublicInbox::URIimap->new($url);
 323                 my $sec = uri_section($uri);
 324                 for my $k (qw(Starttls Debug Compress)) {
 325                         my $bool = cfg_bool($cfg, "imap.$k", $url) // next;
 326                         $mic_args->{$sec}->{$k} = $bool;
 327                 }
 328                 my $to = cfg_intvl($cfg, 'imap.timeout', $url);
 329                 $mic_args->{$sec}->{Timeout} = $to if $to;
 330                 for my $k (qw(pollInterval idleInterval)) {
 331                         $to = cfg_intvl($cfg, "imap.$k", $url) // next;
 332                         $self->{imap_opt}->{$sec}->{$k} = $to;
 333                 }
 334                 my $k = 'imap.fetchBatchSize';
 335                 my $bs = $cfg->urlmatch($k, $url) // next;
 336                 if ($bs =~ /\A([0-9]+)\z/) {
 337                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 338                 } else {
 339                         warn "$k=$bs is not an integer\n";
 340                 }
 341         }
 342         $mic_args;
 343 }
 344
 345 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
 346
 347 sub mic_for ($$$) { # mic = Mail::IMAPClient
 348         my ($self, $url, $mic_args) = @_;
 349         my $uri = PublicInbox::URIimap->new($url);
 350         require PublicInbox::GitCredential;
 351         my $cred = bless {
 352                 url => $url,
 353                 protocol => $uri->scheme,
 354                 host => $uri->host,
 355                 username => $uri->user,
 356                 password => $uri->password,
 357         }, 'PublicInbox::GitCredential';
 358         my $common = $mic_args->{uri_section($uri)} // {};
 359         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 360         my $host = $cred->{host};
 361         $host = '127.0.0.1' if $host eq '0';
 362         my $mic_arg = {
 363                 Port => $uri->port,
 364                 Server => $host,
 365                 Ssl => $uri->scheme eq 'imaps',
 366                 Keepalive => 1, # SO_KEEPALIVE
 367                 %$common, # may set Starttls, Compress, Debug ....
 368         };
 369         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
 370                 die "E: <$url> new: $@\n";
 371
 372         # default to using STARTTLS if it's available, but allow
 373         # it to be disabled since I usually connect to localhost
 374         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 375                         $mic->has_capability('STARTTLS') &&
 376                         $mic->can('starttls')) {
 377                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
 378         }
 379
 380         # do we even need credentials?
 381         if (!defined($cred->{username}) &&
 382                         $mic->has_capability('AUTH=ANONYMOUS')) {
 383                 $cred = undef;
 384         }
 385         if ($cred) {
 386                 $cred->check_netrc unless defined $cred->{password};
 387                 $cred->fill; # may prompt user here
 388                 $mic->User($mic_arg->{User} = $cred->{username});
 389                 $mic->Password($mic_arg->{Password} = $cred->{password});
 390         } else { # AUTH=ANONYMOUS
 391                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 392                 $mic->Authcallback($mic_arg->{Authcallback} = \&auth_anon_cb);
 393         }
 394         if ($mic->login && $mic->IsAuthenticated) {
 395                 # success! keep IMAPClient->new arg in case we get disconnected
 396                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
 397         } else {
 398                 warn "E: <$url> LOGIN: $@\n";
 399                 $mic = undef;
 400         }
 401         $cred->run($mic ? 'approve' : 'reject') if $cred;
 402         $mic;
 403 }
 404
 405 sub imap_import_msg ($$$$$) {
 406         my ($self, $url, $uid, $raw, $flags) = @_;
 407         # our target audience expects LF-only, save storage
 408         $$raw =~ s/\r\n/\n/sg;
 409
 410         my $inboxes = $self->{imap}->{$url};
 411         if (ref($inboxes)) {
 412                 for my $ibx (@$inboxes) {
 413                         my $eml = PublicInbox::Eml->new($$raw);
 414                         import_eml($self, $ibx, $eml);
 415                 }
 416         } elsif ($inboxes eq 'watchspam') {
 417                 # we don't remove unseen messages
 418                 if ($flags =~ /\\Seen\b/) {
 419                         local $SIG{__WARN__} = warn_ignore_cb();
 420                         my $eml = PublicInbox::Eml->new($raw);
 421                         $self->{pi_cfg}->each_inbox(\&remove_eml_i,
 422                                                 $self, $eml, "$url UID:$uid");
 423                 }
 424         } else {
 425                 die "BUG: destination unknown $inboxes";
 426         }
 427 }
 428
 429 sub imap_fetch_all ($$$) {
 430         my ($self, $mic, $url) = @_;
 431         my $uri = PublicInbox::URIimap->new($url);
 432         my $sec = uri_section($uri);
 433         my $mbx = $uri->mailbox;
 434         $mic->Clear(1); # trim results history
 435         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 436         my ($r_uidval, $r_uidnext);
 437         for ($mic->Results) {
 438                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 439                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 440                 last if $r_uidval && $r_uidnext;
 441         }
 442         $r_uidval //= $mic->uidvalidity($mbx) //
 443                 return "E: $url cannot get UIDVALIDITY";
 444         $r_uidnext //= $mic->uidnext($mbx) //
 445                 return "E: $url cannot get UIDNEXT";
 446         my $itrk = PublicInbox::IMAPTracker->new($url);
 447         my ($l_uidval, $l_uid) = $itrk->get_last;
 448         $l_uidval //= $r_uidval; # first time
 449         $l_uid //= 1;
 450         if ($l_uidval != $r_uidval) {
 451                 return "E: $url UIDVALIDITY mismatch\n".
 452                         "E: local=$l_uidval != remote=$r_uidval";
 453         }
 454         my $r_uid = $r_uidnext - 1;
 455         if ($l_uid != 1 && $l_uid > $r_uid) {
 456                 return "E: $url local UID exceeds remote ($l_uid > $r_uid)\n".
 457                         "E: $url strangely, UIDVALIDLITY matches ($l_uidval)\n";
 458         }
 459         return if $l_uid >= $r_uid; # nothing to do
 460
 461         warn "I: $url fetching UID $l_uid:$r_uid\n";
 462         $mic->Uid(1); # the default, we hope
 463         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 464         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 465
 466         # TODO: FLAGS may be useful for personal use
 467         my $key = $req;
 468         $key =~ s/\.PEEK//;
 469         my ($uids, $batch);
 470         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 471         local $SIG{__WARN__} = sub {
 472                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 473                 $batch //= '?';
 474                 $warn_cb->("$pfx$url UID:$batch\n", @_);
 475         };
 476         my $err;
 477         do {
 478                 # I wish "UID FETCH $START:*" could work, but:
 479                 # 1) servers do not need to return results in any order
 480                 # 2) Mail::IMAPClient doesn't offer a streaming API
 481                 $uids = $mic->search("UID $l_uid:*") or
 482                         return "E: $url UID SEARCH $l_uid:* error: $!";
 483                 return if scalar(@$uids) == 0;
 484
 485                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 486                 # responses, so sort it ourselves.  Order matters so
 487                 # IMAPTracker can store the newest UID.
 488                 @$uids = sort { $a <=> $b } @$uids;
 489
 490                 # Did we actually get new messages?
 491                 return if $uids->[0] < $l_uid;
 492
 493                 $l_uid = $uids->[-1] + 1; # for next search
 494                 my $last_uid;
 495                 my $n = $self->{max_batch};
 496
 497                 while (scalar @$uids) {
 498                         if (--$n < 0) {
 499                                 _done_for_now($self);
 500                                 $itrk->update_last($r_uidval, $last_uid);
 501                                 $n = $self->{max_batch};
 502                         }
 503                         my @batch = splice(@$uids, 0, $bs);
 504                         $batch = join(',', @batch);
 505                         local $0 = "UID:$batch $mbx $sec";
 506                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 507                         unless ($r) { # network error?
 508                                 $err = "E: $url UID FETCH $batch error: $!";
 509                                 last;
 510                         }
 511                         for my $uid (@batch) {
 512                                 # messages get deleted, so holes appear
 513                                 my $per_uid = delete $r->{$uid} // next;
 514                                 my $raw = delete($per_uid->{$key}) // next;
 515                                 my $fl = $per_uid->{FLAGS} // '';
 516                                 imap_import_msg($self, $url, $uid, \$raw, $fl);
 517                                 $last_uid = $uid;
 518                                 last if $self->{quit};
 519                         }
 520                         last if $self->{quit};
 521                 }
 522                 _done_for_now($self);
 523                 $itrk->update_last($r_uidval, $last_uid);
 524         } until ($err || $self->{quit});
 525         $err;
 526 }
 527
 528 sub imap_idle_once ($$$$) {
 529         my ($self, $mic, $intvl, $url) = @_;
 530         my $i = $intvl //= (29 * 60);
 531         my $end = now() + $intvl;
 532         warn "I: $url idling for ${intvl}s\n";
 533         local $0 = "IDLE $0";
 534         unless ($mic->idle) {
 535                 return if $self->{quit};
 536                 return "E: IDLE failed on $url: $!";
 537         }
 538         $self->{idle_mic} = $mic; # for ->quit
 539         my @res;
 540         until ($self->{quit} || !$mic->IsConnected ||
 541                         grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 542                 @res = $mic->idle_data($i);
 543                 $i = $end - now();
 544         }
 545         delete $self->{idle_mic};
 546         unless ($self->{quit}) {
 547                 $mic->IsConnected or return "E: IDLE disconnected on $url";
 548                 $mic->done or return "E: IDLE DONE failed on $url: $!";
 549         }
 550         undef;
 551 }
 552
 553 # idles on a single URI
 554 sub watch_imap_idle_1 ($$$) {
 555         my ($self, $url, $intvl) = @_;
 556         my $uri = PublicInbox::URIimap->new($url);
 557         my $sec = uri_section($uri);
 558         my $mic_arg = $self->{mic_arg}->{$sec} or
 559                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 560         my $mic;
 561         local $0 = $uri->mailbox." $sec";
 562         until ($self->{quit}) {
 563                 $mic //= PublicInbox::IMAPClient->new(%$mic_arg);
 564                 my $err;
 565                 if ($mic && $mic->IsConnected) {
 566                         $err = imap_fetch_all($self, $mic, $url);
 567                         $err //= imap_idle_once($self, $mic, $intvl, $url);
 568                 } else {
 569                         $err = "E: not connected: $!";
 570                 }
 571                 if ($err && !$self->{quit}) {
 572                         warn $err, "\n";
 573                         $mic = undef;
 574                         sleep 60 unless $self->{quit};
 575                 }
 576         }
 577 }
 578
 579 sub watch_atfork_child ($) {
 580         my ($self) = @_;
 581         delete $self->{idle_pids};
 582         delete $self->{poll_pids};
 583         delete $self->{opendirs};
 584         PublicInbox::DS->Reset;
 585         %SIG = (%SIG, %{$self->{sig}}, CHLD => 'DEFAULT');
 586         PublicInbox::Sigfd::sig_setmask($self->{oldset});
 587 }
 588
 589 sub watch_atfork_parent ($) {
 590         my ($self) = @_;
 591         _done_for_now($self);
 592         PublicInbox::Sigfd::block_signals();
 593 }
 594
 595 sub imap_idle_requeue ($) { # DS::add_timer callback
 596         my ($self, $url_intvl) = @{$_[0]};
 597         return if $self->{quit};
 598         push @{$self->{idle_todo}}, $url_intvl;
 599         event_step($self);
 600 }
 601
 602 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 603         my ($self, $pid) = @_;
 604         my $url_intvl = delete $self->{idle_pids}->{$pid} or
 605                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 606
 607         my ($url, $intvl) = @$url_intvl;
 608         return if $self->{quit};
 609         warn "W: PID=$pid on $url died: \$?=$?\n" if $?;
 610         PublicInbox::DS::add_timer(60,
 611                                 \&imap_idle_requeue, [ $self, $url_intvl ]);
 612 }
 613
 614 sub reap { # callback for EOFpipe
 615         my ($pid, $cb, $self) = @{$_[0]};
 616         my $ret = waitpid($pid, 0);
 617         if ($ret == $pid) {
 618                 $cb->($self, $pid); # poll_fetch_reap || imap_idle_reap
 619         } else {
 620                 warn "W: waitpid($pid) => ", $ret // "($!)", "\n";
 621         }
 622 }
 623
 624 sub imap_idle_fork ($$) {
 625         my ($self, $url_intvl) = @_;
 626         my ($url, $intvl) = @$url_intvl;
 627         pipe(my ($r, $w)) or die "pipe: $!";
 628         defined(my $pid = fork) or die "fork: $!";
 629         if ($pid == 0) {
 630                 close $r;
 631                 watch_atfork_child($self);
 632                 watch_imap_idle_1($self, $url, $intvl);
 633                 close $w;
 634                 _exit(0);
 635         }
 636         $self->{idle_pids}->{$pid} = $url_intvl;
 637         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&imap_idle_reap, $self]);
 638 }
 639
 640 sub event_step {
 641         my ($self) = @_;
 642         return if $self->{quit};
 643         my $idle_todo = $self->{idle_todo};
 644         if ($idle_todo && @$idle_todo) {
 645                 my $oldset = watch_atfork_parent($self);
 646                 eval {
 647                         while (my $url_intvl = shift(@$idle_todo)) {
 648                                 imap_idle_fork($self, $url_intvl);
 649                         }
 650                 };
 651                 PublicInbox::Sigfd::sig_setmask($oldset);
 652                 die $@ if $@;
 653         }
 654         fs_scan_step($self) if $self->{mdre};
 655 }
 656
 657 sub watch_imap_fetch_all ($$) {
 658         my ($self, $urls) = @_;
 659         for my $url (@$urls) {
 660                 my $uri = PublicInbox::URIimap->new($url);
 661                 my $sec = uri_section($uri);
 662                 my $mic_arg = $self->{mic_arg}->{$sec} or
 663                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 664                 my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or next;
 665                 my $err = imap_fetch_all($self, $mic, $url);
 666                 last if $self->{quit};
 667                 warn $err, "\n" if $err;
 668         }
 669 }
 670
 671 sub watch_nntp_fetch_all ($$) {
 672         my ($self, $urls) = @_;
 673         for my $url (@$urls) {
 674                 my $uri = uri_new($url);
 675                 my $sec = uri_section($uri);
 676                 my $nn_arg = $self->{nn_arg}->{$sec} or
 677                         die "BUG: no Net::NNTP->new arg for $sec";
 678                 my $nntp_opt = $self->{nntp_opt}->{$sec};
 679                 my $nn = nn_new($nn_arg, $nntp_opt, $url);
 680                 unless ($nn) {
 681                         warn "E: $url: \$!=$!\n";
 682                         next;
 683                 }
 684                 last if $self->{quit};
 685                 if (my $postconn = $nntp_opt->{-postconn}) {
 686                         for my $m_arg (@$postconn) {
 687                                 my ($method, @args) = @$m_arg;
 688                                 $nn->$method(@args) and next;
 689                                 warn "E: <$url> $method failed\n";
 690                                 $nn = undef;
 691                                 last;
 692                         }
 693                 }
 694                 last if $self->{quit};
 695                 if ($nn) {
 696                         my $err = nntp_fetch_all($self, $nn, $url);
 697                         warn $err, "\n" if $err;
 698                 }
 699         }
 700 }
 701
 702 sub poll_fetch_fork ($) { # DS::add_timer callback
 703         my ($self, $intvl, $urls) = @{$_[0]};
 704         return if $self->{quit};
 705         pipe(my ($r, $w)) or die "pipe: $!";
 706         my $oldset = watch_atfork_parent($self);
 707         my $pid = fork;
 708         if (defined($pid) && $pid == 0) {
 709                 close $r;
 710                 watch_atfork_child($self);
 711                 if ($urls->[0] =~ m!\Aimaps?://!i) {
 712                         watch_imap_fetch_all($self, $urls);
 713                 } else {
 714                         watch_nntp_fetch_all($self, $urls);
 715                 }
 716                 close $w;
 717                 _exit(0);
 718         }
 719         PublicInbox::Sigfd::sig_setmask($oldset);
 720         die "fork: $!"  unless defined $pid;
 721         $self->{poll_pids}->{$pid} = [ $intvl, $urls ];
 722         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&poll_fetch_reap, $self]);
 723 }
 724
 725 sub poll_fetch_reap {
 726         my ($self, $pid) = @_;
 727         my $intvl_urls = delete $self->{poll_pids}->{$pid} or
 728                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 729         return if $self->{quit};
 730         my ($intvl, $urls) = @$intvl_urls;
 731         if ($?) {
 732                 warn "W: PID=$pid died: \$?=$?\n", map { "$_\n" } @$urls;
 733         }
 734         warn("I: will check $_ in ${intvl}s\n") for @$urls;
 735         PublicInbox::DS::add_timer($intvl, \&poll_fetch_fork,
 736                                         [$self, $intvl, $urls]);
 737 }
 738
 739 sub watch_imap_init ($$) {
 740         my ($self, $poll) = @_;
 741         eval { require PublicInbox::IMAPClient } or
 742                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 743         eval { require PublicInbox::IMAPTracker } or
 744                 die "DBD::SQLite is required for IMAP\n:$@\n";
 745
 746         my $mic_args = imap_common_init($self); # read args from config
 747
 748         # make sure we can connect and cache the credentials in memory
 749         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 750         my $mics = {}; # schema://authority => IMAPClient obj
 751         for my $url (sort keys %{$self->{imap}}) {
 752                 my $uri = PublicInbox::URIimap->new($url);
 753                 $mics->{uri_section($uri)} //= mic_for($self, $url, $mic_args);
 754         }
 755
 756         my $idle = []; # [ [ url1, intvl1 ], [url2, intvl2] ]
 757         for my $url (keys %{$self->{imap}}) {
 758                 my $uri = PublicInbox::URIimap->new($url);
 759                 my $sec = uri_section($uri);
 760                 my $mic = $mics->{$sec};
 761                 my $intvl = $self->{imap_opt}->{$sec}->{pollInterval};
 762                 if ($mic->has_capability('IDLE') && !$intvl) {
 763                         $intvl = $self->{imap_opt}->{$sec}->{idleInterval};
 764                         push @$idle, [ $url, $intvl // () ];
 765                 } else {
 766                         push @{$poll->{$intvl || 120}}, $url;
 767                 }
 768         }
 769         if (scalar @$idle) {
 770                 $self->{idle_todo} = $idle;
 771                 PublicInbox::DS::requeue($self); # ->event_step to fork
 772         }
 773 }
 774
 775 # flesh out common NNTP-specific data structures
 776 sub nntp_common_init ($) {
 777         my ($self) = @_;
 778         my $cfg = $self->{pi_cfg};
 779         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 780         for my $url (sort keys %{$self->{nntp}}) {
 781                 my $sec = uri_section(uri_new($url));
 782
 783                 # Debug and Timeout are passed to Net::NNTP->new
 784                 my $v = cfg_bool($cfg, 'nntp.Debug', $url);
 785                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 786                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $url);
 787                 $nn_args->{$sec}->{Timeout} = $to if $to;
 788
 789                 # Net::NNTP post-connect commands
 790                 for my $k (qw(starttls compress)) {
 791                         $v = cfg_bool($cfg, "nntp.$k", $url) // next;
 792                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 793                 }
 794
 795                 # internal option
 796                 for my $k (qw(pollInterval)) {
 797                         $to = cfg_intvl($cfg, "nntp.$k", $url) // next;
 798                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 799                 }
 800         }
 801         $nn_args;
 802 }
 803
 804 # Net::NNTP doesn't support CAPABILITIES, yet
 805 sub try_starttls ($) {
 806         my ($host) = @_;
 807         return if $host =~ /\.onion\z/s;
 808         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 809         return if $host eq '::1';
 810         1;
 811 }
 812
 813 sub nn_new ($$$) {
 814         my ($nn_arg, $nntp_opt, $url) = @_;
 815         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$url> new: $!\n";
 816
 817         # default to using STARTTLS if it's available, but allow
 818         # it to be disabled for localhost/VPN users
 819         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 820                 if (!defined($nntp_opt->{starttls}) &&
 821                                 try_starttls($nn_arg->{Host})) {
 822                         # soft fail by default
 823                         $nn->starttls or warn <<"";
 824 W: <$url> STARTTLS tried and failed (not requested)
 825
 826                 } elsif ($nntp_opt->{starttls}) {
 827                         # hard fail if explicitly configured
 828                         $nn->starttls or die <<"";
 829 E: <$url> STARTTLS requested and failed
 830
 831                 }
 832         } elsif ($nntp_opt->{starttls}) {
 833                 $nn->can('starttls') or
 834                         die "E: <$url> Net::NNTP too old for STARTTLS\n";
 835                 $nn->starttls or die <<"";
 836 E: <$url> STARTTLS requested and failed
 837
 838         }
 839         $nn;
 840 }
 841
 842 sub nn_for ($$$) { # nn = Net::NNTP
 843         my ($self, $url, $nn_args) = @_;
 844         my $uri = uri_new($url);
 845         my $sec = uri_section($uri);
 846         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 847         my $host = $uri->host;
 848         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 849         $host = '127.0.0.1' if $host eq '0';
 850         my $cred;
 851         my ($u, $p);
 852         if (defined(my $ui = $uri->userinfo)) {
 853                 require PublicInbox::GitCredential;
 854                 $cred = bless {
 855                         url => $sec,
 856                         protocol => uri_scheme($uri),
 857                         host => $host,
 858                 }, 'PublicInbox::GitCredential';
 859                 ($u, $p) = split(/:/, $ui, 2);
 860                 ($cred->{username}, $cred->{password}) = ($u, $p);
 861                 $cred->check_netrc unless defined $p;
 862         }
 863         my $common = $nn_args->{$sec} // {};
 864         my $nn_arg = {
 865                 Port => $uri->port,
 866                 Host => $host,
 867                 SSL => $uri->secure, # snews == nntps
 868                 %$common, # may Debug ....
 869         };
 870         my $nn = nn_new($nn_arg, $nntp_opt, $url);
 871
 872         if ($cred) {
 873                 $cred->fill; # may prompt user here
 874                 if ($nn->authinfo($u, $p)) {
 875                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 876                 } else {
 877                         warn "E: <$url> AUTHINFO $u XXXX failed\n";
 878                         $nn = undef;
 879                 }
 880         }
 881
 882         if ($nntp_opt->{compress}) {
 883                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 884                 if ($nn->can('compress')) {
 885                         if ($nn->compress) {
 886                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 887                         } else {
 888                                 warn "W: <$url> COMPRESS failed\n";
 889                         }
 890                 } else {
 891                         delete $nntp_opt->{compress};
 892                         warn <<"";
 893 W: <$url> COMPRESS not supported by Net::NNTP
 894 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 895
 896                 }
 897         }
 898
 899         $self->{nn_arg}->{$sec} = $nn_arg;
 900         $cred->run($nn ? 'approve' : 'reject') if $cred;
 901         $nn;
 902 }
 903
 904 sub nntp_fetch_all ($$$) {
 905         my ($self, $nn, $url) = @_;
 906         my $uri = uri_new($url);
 907         my ($group, $num_a, $num_b) = $uri->group;
 908         my $sec = uri_section($uri);
 909         my ($nr, $beg, $end) = $nn->group($group);
 910         unless (defined($nr)) {
 911                 chomp(my $msg = $nn->message);
 912                 return "E: GROUP $group <$sec> $msg";
 913         }
 914
 915         # IMAPTracker is also used for tracking NNTP, UID == article number
 916         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 917         # expensive.  So we assume newsgroups don't change:
 918         my $itrk = PublicInbox::IMAPTracker->new($url);
 919         my (undef, $l_art) = $itrk->get_last;
 920         $l_art //= $beg; # initial import
 921
 922         # allow users to specify articles to refetch
 923         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 924         # nntp://example.com/inbox.foo/$num_a-$num_b
 925         $l_art = $num_a if defined($num_a) && $num_a < $l_art;
 926         $end = $num_b if defined($num_b) && $num_b < $end;
 927
 928         return if $l_art >= $end; # nothing to do
 929         $beg = $l_art + 1;
 930
 931         warn "I: $url fetching ARTICLE $beg..$end\n";
 932         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 933         my ($err, $art);
 934         local $SIG{__WARN__} = sub {
 935                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 936                 $warn_cb->("$pfx$url ", $art ? ("ARTICLE $art") : (), "\n", @_);
 937         };
 938         my $inboxes = $self->{nntp}->{$url};
 939         my $last_art;
 940         my $n = $self->{max_batch};
 941         for ($beg..$end) {
 942                 last if $self->{quit};
 943                 $art = $_;
 944                 if (--$n < 0) {
 945                         _done_for_now($self);
 946                         $itrk->update_last(0, $last_art);
 947                         $n = $self->{max_batch};
 948                 }
 949                 my $raw = $nn->article($art);
 950                 unless (defined($raw)) {
 951                         my $msg = $nn->message;
 952                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 953                                 $err = "E: $msg";
 954                                 last;
 955                         } else { # probably just a deleted message (spam)
 956                                 warn "W: $msg";
 957                                 next;
 958                         }
 959                 }
 960                 s/\r\n/\n/ for @$raw;
 961                 $raw = join('', @$raw);
 962                 if (ref($inboxes)) {
 963                         for my $ibx (@$inboxes) {
 964                                 my $eml = PublicInbox::Eml->new($raw);
 965                                 import_eml($self, $ibx, $eml);
 966                         }
 967                 } elsif ($inboxes eq 'watchspam') {
 968                         my $eml = PublicInbox::Eml->new(\$raw);
 969                         $self->{pi_cfg}->each_inbox(\&remove_eml_i,
 970                                         $self, $eml, "$url ARTICLE $art");
 971                 } else {
 972                         die "BUG: destination unknown $inboxes";
 973                 }
 974                 $last_art = $art;
 975         }
 976         _done_for_now($self);
 977         $itrk->update_last(0, $last_art);
 978         $err;
 979 }
 980
 981 sub watch_nntp_init ($$) {
 982         my ($self, $poll) = @_;
 983         eval { require Net::NNTP } or
 984                 die "Net::NNTP is required for NNTP:\n$@\n";
 985         eval { require PublicInbox::IMAPTracker } or
 986                 die "DBD::SQLite is required for NNTP\n:$@\n";
 987
 988         my $nn_args = nntp_common_init($self); # read args from config
 989
 990         # make sure we can connect and cache the credentials in memory
 991         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 992         for my $url (sort keys %{$self->{nntp}}) {
 993                 nn_for($self, $url, $nn_args);
 994         }
 995         for my $url (keys %{$self->{nntp}}) {
 996                 my $uri = uri_new($url);
 997                 my $sec = uri_section($uri);
 998                 my $intvl = $self->{nntp_opt}->{$sec}->{pollInterval};
 999                 push @{$poll->{$intvl || 120}}, $url;
1000         }
1001 }
1002
1003 sub watch { # main entry point
1004         my ($self, $sig, $oldset) = @_;
1005         $self->{oldset} = $oldset;
1006         $self->{sig} = $sig;
1007         my $poll = {}; # intvl_seconds => [ url1, url2 ]
1008         watch_imap_init($self, $poll) if $self->{imap};
1009         watch_nntp_init($self, $poll) if $self->{nntp};
1010         while (my ($intvl, $urls) = each %$poll) {
1011                 # poll all URLs for a given interval sequentially
1012                 PublicInbox::DS::add_timer(0, \&poll_fetch_fork,
1013                                                 [$self, $intvl, $urls]);
1014         }
1015         watch_fs_init($self) if $self->{mdre};
1016         PublicInbox::DS->SetPostLoopCallback(sub { !$self->quit_done });
1017         PublicInbox::DS->EventLoop; # calls ->event_step
1018         _done_for_now($self);
1019 }
1020
1021 sub trigger_scan {
1022         my ($self, $op) = @_;
1023         push @{$self->{ops}}, $op;
1024         PublicInbox::DS::requeue($self);
1025 }
1026
1027 sub fs_scan_step {
1028         my ($self) = @_;
1029         return if $self->{quit};
1030         my $op = shift @{$self->{ops}};
1031         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
1032
1033         # continue existing scan
1034         my $opendirs = $self->{opendirs};
1035         my @dirnames = keys %$opendirs;
1036         foreach my $dir (@dirnames) {
1037                 my $dh = delete $opendirs->{$dir};
1038                 my $n = $self->{max_batch};
1039                 while (my $fn = readdir($dh)) {
1040                         _try_path($self, "$dir/$fn");
1041                         last if --$n < 0;
1042                 }
1043                 $opendirs->{$dir} = $dh if $n < 0;
1044         }
1045         if ($op && $op eq 'full') {
1046                 foreach my $dir (keys %{$self->{mdmap}}) {
1047                         next if $opendirs->{$dir}; # already in progress
1048                         my $ok = opendir(my $dh, $dir);
1049                         unless ($ok) {
1050                                 warn "failed to open $dir: $!\n";
1051                                 next;
1052                         }
1053                         my $n = $self->{max_batch};
1054                         while (my $fn = readdir($dh)) {
1055                                 _try_path($self, "$dir/$fn");
1056                                 last if --$n < 0;
1057                         }
1058                         $opendirs->{$dir} = $dh if $n < 0;
1059                 }
1060         }
1061         _done_for_now($self);
1062         # do we have more work to do?
1063         PublicInbox::DS::requeue($self) if keys %$opendirs;
1064 }
1065
1066 sub scan {
1067         my ($self, $op) = @_;
1068         push @{$self->{ops}}, $op;
1069         fs_scan_step($self);
1070 }
1071
1072 sub _importer_for {
1073         my ($self, $ibx) = @_;
1074         my $importers = $self->{importers};
1075         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
1076         if (scalar(keys(%$importers)) > 2) {
1077                 delete $importers->{"$ibx"};
1078                 _done_for_now($self);
1079         }
1080
1081         $importers->{"$ibx"} = $im;
1082 }
1083
1084 # XXX consider sharing with V2Writable, this only requires read-only access
1085 sub content_exists ($$) {
1086         my ($ibx, $eml) = @_;
1087         my $over = $ibx->over or return;
1088         my $mids = mids($eml);
1089         my $chash = content_hash($eml);
1090         my ($id, $prev);
1091         for my $mid (@$mids) {
1092                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1093                         my $cmp = $ibx->smsg_eml($smsg) or return;
1094                         return 1 if $chash eq content_hash($cmp);
1095                 }
1096         }
1097         undef;
1098 }
1099
1100 sub _spamcheck_cb {
1101         my ($sc) = @_;
1102         sub { # this gets called by (V2Writable||Import)->add
1103                 my ($mime, $ibx) = @_;
1104                 return if content_exists($ibx, $mime);
1105                 my $tmp = '';
1106                 if ($sc->spamcheck($mime, \$tmp)) {
1107                         return PublicInbox::Eml->new(\$tmp);
1108                 }
1109                 warn $mime->header('Message-ID')." failed spam check\n";
1110                 undef;
1111         }
1112 }
1113
1114 sub is_maildir {
1115         $_[0] =~ s!\Amaildir:!! or return;
1116         $_[0] =~ tr!/!/!s;
1117         $_[0] =~ s!/\z!!;
1118         $_[0];
1119 }
1120
1121 sub is_watchspam {
1122         my ($cur, $ws, $ibx) = @_;
1123         if ($ws && !ref($ws) && $ws eq 'watchspam') {
1124                 warn <<EOF;
1125 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
1126 EOF
1127                 return 1;
1128         }
1129         undef;
1130 }
1131
1132 sub uri_new {
1133         my ($url) = @_;
1134
1135         # URI::snews exists, URI::nntps does not, so use URI::snews
1136         $url =~ s!\Anntps://!snews://!i;
1137         URI->new($url);
1138 }
1139
1140 sub imap_url {
1141         my ($url) = @_;
1142         require PublicInbox::URIimap;
1143         my $uri = PublicInbox::URIimap->new($url);
1144         $uri ? $uri->canonical->as_string : undef;
1145 }
1146
1147 my %IS_NNTP = (news => 1, snews => 1, nntp => 1);
1148 sub nntp_url {
1149         my ($url) = @_;
1150         require URI;
1151         my $uri = uri_new($url);
1152         return unless $uri && $IS_NNTP{$uri->scheme} && $uri->group;
1153         $url = $uri->canonical->as_string;
1154         # nntps is IANA registered, snews is deprecated
1155         $url =~ s!\Asnews://!nntps://!;
1156         $url;
1157 }
1158
1159 1;