lib/PublicInbox/Watch.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       https://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::Watch;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable qw(eml_from_path);
  11 use PublicInbox::MdirReader;
  12 use PublicInbox::NetReader;
  13 use PublicInbox::Filter::Base qw(REJECT);
  14 use PublicInbox::Spamcheck;
  15 use PublicInbox::DS qw(now add_timer);
  16 use PublicInbox::MID qw(mids);
  17 use PublicInbox::ContentHash qw(content_hash);
  18 use PublicInbox::EOFpipe;
  19 use POSIX qw(_exit WNOHANG);
  20
  21 sub compile_watchheaders ($) {
  22         my ($ibx) = @_;
  23         my $watch_hdrs = [];
  24         if (my $whs = $ibx->{watchheader}) {
  25                 for (@$whs) {
  26                         my ($k, $v) = split(/:/, $_, 2);
  27                         # XXX should this be case-insensitive?
  28                         # Or, mutt-style, case-sensitive iff
  29                         # a capital letter exists?
  30                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  31                 }
  32         }
  33         if (my $list_ids = $ibx->{listid}) {
  34                 for (@$list_ids) {
  35                         # RFC2919 section 6 stipulates
  36                         # "case insensitive equality"
  37                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  38                         push @$watch_hdrs, ['List-Id', $re ];
  39                 }
  40         }
  41         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  42 }
  43
  44 sub new {
  45         my ($class, $cfg) = @_;
  46         my (%mdmap, $spamc);
  47         my (%imap, %nntp); # url => [inbox objects] or 'watchspam'
  48         my (@imap, @nntp);
  49
  50         # "publicinboxwatch" is the documented namespace
  51         # "publicinboxlearn" is legacy but may be supported
  52         # indefinitely...
  53         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  54                 my $k = "$pfx.watchspam";
  55                 my $dirs = $cfg->get_all($k) // next;
  56                 for my $dir (@$dirs) {
  57                         my $uri;
  58                         if (is_maildir($dir)) {
  59                                 # skip "new", no MUA has seen it, yet.
  60                                 $mdmap{"$dir/cur"} = 'watchspam';
  61                         } elsif ($uri = imap_uri($dir)) {
  62                                 $imap{$$uri} = 'watchspam';
  63                                 push @imap, $uri;
  64                         } elsif ($uri = nntp_uri($dir)) {
  65                                 $nntp{$$uri} = 'watchspam';
  66                                 push @nntp, $uri;
  67                         } else {
  68                                 warn "unsupported $k=$dir\n";
  69                         }
  70                 }
  71         }
  72
  73         my $k = 'publicinboxwatch.spamcheck';
  74         my $default = undef;
  75         my $spamcheck = PublicInbox::Spamcheck::get($cfg, $k, $default);
  76         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  77
  78         $cfg->each_inbox(sub {
  79                 # need to make all inboxes writable for spam removal:
  80                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  81
  82                 my $watches = $ibx->{watch} or return;
  83                 $watches = PublicInbox::Config::_array($watches);
  84                 for my $watch (@$watches) {
  85                         my $uri;
  86                         if (is_maildir($watch)) {
  87                                 compile_watchheaders($ibx);
  88                                 my ($new, $cur) = ("$watch/new", "$watch/cur");
  89                                 my $cur_dst = $mdmap{$cur} //= [];
  90                                 return if is_watchspam($cur, $cur_dst, $ibx);
  91                                 push @{$mdmap{$new} //= []}, $ibx;
  92                                 push @$cur_dst, $ibx;
  93                         } elsif ($uri = imap_uri($watch)) {
  94                                 my $cur_dst = $imap{$$uri} //= [];
  95                                 return if is_watchspam($uri, $cur_dst, $ibx);
  96                                 compile_watchheaders($ibx);
  97                                 push(@imap, $uri) if 1 == push(@$cur_dst, $ibx);
  98                         } elsif ($uri = nntp_uri($watch)) {
  99                                 my $cur_dst = $nntp{$$uri} //= [];
 100                                 return if is_watchspam($uri, $cur_dst, $ibx);
 101                                 compile_watchheaders($ibx);
 102                                 push(@nntp, $uri) if 1 == push(@$cur_dst, $ibx);
 103                         } else {
 104                                 warn "watch unsupported: $k=$watch\n";
 105                         }
 106                 }
 107         });
 108
 109         my $mdre;
 110         if (scalar keys %mdmap) {
 111                 $mdre = join('|', map { quotemeta($_) } keys %mdmap);
 112                 $mdre = qr!\A($mdre)/!;
 113         }
 114         return unless $mdre || scalar(keys %imap) || scalar(keys %nntp);
 115
 116         bless {
 117                 max_batch => 10, # avoid hogging locks for too long
 118                 spamcheck => $spamcheck,
 119                 mdmap => \%mdmap,
 120                 mdre => $mdre,
 121                 pi_cfg => $cfg,
 122                 imap => scalar keys %imap ? \%imap : undef,
 123                 nntp => scalar keys %nntp? \%nntp : undef,
 124                 imap_order => scalar(@imap) ? \@imap : undef,
 125                 nntp_order => scalar(@nntp) ? \@nntp: undef,
 126                 importers => {},
 127                 opendirs => {}, # dirname => dirhandle (in progress scans)
 128                 ops => [], # 'quit', 'full'
 129         }, $class;
 130 }
 131
 132 sub _done_for_now {
 133         my ($self) = @_;
 134         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 135         for my $im (values %{$self->{importers}}) {
 136                 next if !$im; # $im may be undef during cleanup
 137                 eval { $im->done };
 138                 warn "$im->{ibx}->{name} ->done: $@\n" if $@;
 139         }
 140 }
 141
 142 sub remove_eml_i { # each_inbox callback
 143         my ($ibx, $self, $eml, $loc) = @_;
 144
 145         eval {
 146                 # try to avoid taking a lock or unnecessary spawning
 147                 my $im = $self->{importers}->{"$ibx"};
 148                 my $scrubbed;
 149                 if ((!$im || !$im->active) && $ibx->over) {
 150                         if (content_exists($ibx, $eml)) {
 151                                 # continue
 152                         } elsif (my $scrub = $ibx->filter($im)) {
 153                                 $scrubbed = $scrub->scrub($eml, 1);
 154                                 if ($scrubbed && $scrubbed != REJECT &&
 155                                           !content_exists($ibx, $scrubbed)) {
 156                                         return;
 157                                 }
 158                         } else {
 159                                 return;
 160                         }
 161                 }
 162
 163                 $im //= _importer_for($self, $ibx); # may spawn fast-import
 164                 $im->remove($eml, 'spam');
 165                 $scrubbed //= do {
 166                         my $scrub = $ibx->filter($im);
 167                         $scrub ? $scrub->scrub($eml, 1) : undef;
 168                 };
 169                 if ($scrubbed && $scrubbed != REJECT) {
 170                         $im->remove($scrubbed, 'spam');
 171                 }
 172         };
 173         if ($@) {
 174                 warn "error removing spam at: $loc from $ibx->{name}: $@\n";
 175                 _done_for_now($self);
 176         }
 177 }
 178
 179 sub _remove_spam {
 180         my ($self, $path) = @_;
 181         # path must be marked as (S)een
 182         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 183         my $eml = eml_from_path($path) or return;
 184         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 185         $self->{pi_cfg}->each_inbox(\&remove_eml_i, $self, $eml, $path);
 186 }
 187
 188 sub import_eml ($$$) {
 189         my ($self, $ibx, $eml) = @_;
 190
 191         # any header match means it's eligible for the inbox:
 192         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 193                 my $ok;
 194                 for my $wh (@$watch_hdrs) {
 195                         my @v = $eml->header_raw($wh->[0]);
 196                         $ok = grep(/$wh->[1]/, @v) and last;
 197                 }
 198                 return unless $ok;
 199         }
 200         eval {
 201                 my $im = _importer_for($self, $ibx);
 202                 if (my $scrub = $ibx->filter($im)) {
 203                         my $scrubbed = $scrub->scrub($eml) or return;
 204                         $scrubbed == REJECT and return;
 205                         $eml = $scrubbed;
 206                 }
 207                 $im->add($eml, $self->{spamcheck});
 208         };
 209         if ($@) {
 210                 warn "$ibx->{name} add failed: $@\n";
 211                 _done_for_now($self);
 212         }
 213 }
 214
 215 sub _try_path {
 216         my ($self, $path) = @_;
 217         my $fl = PublicInbox::MdirReader::maildir_path_flags($path) // return;
 218         return if $fl =~ /[DT]/; # no Drafts or Trash
 219         if ($path !~ $self->{mdre}) {
 220                 warn "unrecognized path: $path\n";
 221                 return;
 222         }
 223         my $inboxes = $self->{mdmap}->{$1};
 224         unless ($inboxes) {
 225                 warn "unmappable dir: $1\n";
 226                 return;
 227         }
 228         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 229         local $SIG{__WARN__} = sub {
 230                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 231                 $warn_cb->($pfx, "path: $path\n", @_);
 232         };
 233         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 234                 return _remove_spam($self, $path);
 235         }
 236         foreach my $ibx (@$inboxes) {
 237                 my $eml = eml_from_path($path) or next;
 238                 import_eml($self, $ibx, $eml);
 239         }
 240 }
 241
 242 sub quit_done ($) {
 243         my ($self) = @_;
 244         return unless $self->{quit};
 245
 246         # don't have reliable wakeups, keep signalling
 247         my $done = 1;
 248         for (qw(idle_pids poll_pids)) {
 249                 my $pids = $self->{$_} or next;
 250                 for (keys %$pids) {
 251                         $done = undef if kill('QUIT', $_);
 252                 }
 253         }
 254         $done;
 255 }
 256
 257 sub quit {
 258         my ($self) = @_;
 259         $self->{quit} = 1;
 260         %{$self->{opendirs}} = ();
 261         _done_for_now($self);
 262         quit_done($self);
 263         if (my $idle_mic = $self->{idle_mic}) {
 264                 eval { $idle_mic->done };
 265                 if ($@) {
 266                         warn "IDLE DONE error: $@\n";
 267                         eval { $idle_mic->disconnect };
 268                         warn "IDLE LOGOUT error: $@\n" if $@;
 269                 }
 270         }
 271 }
 272
 273 sub watch_fs_init ($) {
 274         my ($self) = @_;
 275         my $done = sub {
 276                 delete $self->{done_timer};
 277                 _done_for_now($self);
 278         };
 279         my $cb = sub { # called by PublicInbox::DirIdle::event_step
 280                 _try_path($self, $_[0]->fullname);
 281                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 282         };
 283         require PublicInbox::DirIdle;
 284         # inotify_create + EPOLL_CTL_ADD
 285         my $dir_idle = PublicInbox::DirIdle->new($cb);
 286         $dir_idle->add_watches([keys %{$self->{mdmap}}]);
 287 }
 288
 289 sub net_cb { # NetReader::(nntp|imap)_each callback
 290         my ($uri, $art, $kw, $eml, $self, $inboxes) = @_;
 291         return if grep(/\Adraft\z/, @$kw);
 292         local $self->{cur_uid} = $art; # IMAP UID or NNTP article
 293         if (ref($inboxes)) {
 294                 my @ibx = @$inboxes;
 295                 my $last = pop @ibx;
 296                 for my $ibx (@ibx) {
 297                         my $tmp = PublicInbox::Eml->new(\($eml->as_string));
 298                         import_eml($self, $ibx, $tmp);
 299                 }
 300                 import_eml($self, $last, $eml);
 301         } elsif ($inboxes eq 'watchspam') {
 302                 if ($uri->scheme =~ /\Aimaps?\z/ && !grep(/\Aseen\z/, @$kw)) {
 303                         return;
 304                 }
 305                 $self->{pi_cfg}->each_inbox(\&remove_eml_i,
 306                                 $self, $eml, "$uri #$art");
 307         } else {
 308                 die "BUG: destination unknown $inboxes";
 309         }
 310 }
 311
 312 sub imap_fetch_all ($$) {
 313         my ($self, $uri) = @_;
 314         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 315         $self->{incremental} = 1;
 316         $self->{on_commit} = [ \&_done_for_now, $self ];
 317         local $self->{cur_uid};
 318         local $SIG{__WARN__} = sub {
 319                 my $pfx = ($_[0] // '') =~ /^([A-Z]: |# )/g ? $1 : '';
 320                 my $uid = $self->{cur_uid};
 321                 $warn_cb->("$pfx$uri", $uid ? ("UID:$uid") : (), "\n", @_);
 322         };
 323         PublicInbox::NetReader::imap_each($self, $uri, \&net_cb, $self,
 324                                         $self->{imap}->{$$uri});
 325 }
 326
 327 sub imap_idle_once ($$$$) {
 328         my ($self, $mic, $intvl, $uri) = @_;
 329         my $i = $intvl //= (29 * 60);
 330         my $end = now() + $intvl;
 331         warn "I: $uri idling for ${intvl}s\n";
 332         local $0 = "IDLE $0";
 333         return if $self->{quit};
 334         unless ($mic->idle) {
 335                 return if $self->{quit};
 336                 return "E: IDLE failed on $uri: $!";
 337         }
 338         $self->{idle_mic} = $mic; # for ->quit
 339         my @res;
 340         until ($self->{quit} || !$mic->IsConnected ||
 341                         grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 342                 @res = $mic->idle_data($i);
 343                 $i = $end - now();
 344         }
 345         delete $self->{idle_mic};
 346         unless ($self->{quit}) {
 347                 $mic->IsConnected or return "E: IDLE disconnected on $uri";
 348                 $mic->done or return "E: IDLE DONE failed on $uri: $!";
 349         }
 350         undef;
 351 }
 352
 353 # idles on a single URI
 354 sub watch_imap_idle_1 ($$$) {
 355         my ($self, $uri, $intvl) = @_;
 356         my $sec = uri_section($uri);
 357         my $mic_arg = $self->{net_arg}->{$sec} or
 358                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 359         my $mic;
 360         local $0 = $uri->mailbox." $sec";
 361         until ($self->{quit}) {
 362                 $mic //= PublicInbox::NetReader::mic_new(
 363                                         $self, $mic_arg, $sec, $uri);
 364                 my $err;
 365                 if ($mic && $mic->IsConnected) {
 366                         local $self->{mics_cached}->{$sec} = $mic;
 367                         my $m = imap_fetch_all($self, $uri);
 368                         $m == $mic or die "BUG: wrong mic";
 369                         $mic->IsConnected and
 370                                 $err = imap_idle_once($self, $mic, $intvl, $uri)
 371                 } else {
 372                         $err = "E: not connected: $!";
 373                 }
 374                 if ($err && !$self->{quit}) {
 375                         warn $err, "\n";
 376                         $mic = undef;
 377                         sleep 60 unless $self->{quit};
 378                 }
 379         }
 380 }
 381
 382 sub watch_atfork_child ($) {
 383         my ($self) = @_;
 384         delete $self->{idle_pids};
 385         delete $self->{poll_pids};
 386         delete $self->{opendirs};
 387         PublicInbox::DS->Reset;
 388         my $sig = delete $self->{sig};
 389         $sig->{CHLD} = 'DEFAULT';
 390         @SIG{keys %$sig} = values %$sig;
 391         PublicInbox::DS::sig_setmask($self->{oldset});
 392 }
 393
 394 sub watch_atfork_parent ($) {
 395         my ($self) = @_;
 396         _done_for_now($self);
 397         PublicInbox::DS::block_signals();
 398 }
 399
 400 sub imap_idle_requeue { # DS::add_timer callback
 401         my ($self, $uri_intvl) = @_;
 402         return if $self->{quit};
 403         push @{$self->{idle_todo}}, $uri_intvl;
 404         event_step($self);
 405 }
 406
 407 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 408         my ($self, $pid) = @_;
 409         my $uri_intvl = delete $self->{idle_pids}->{$pid} or
 410                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 411
 412         my ($uri, $intvl) = @$uri_intvl;
 413         return if $self->{quit};
 414         warn "W: PID=$pid on $uri died: \$?=$?\n" if $?;
 415         add_timer(60, \&imap_idle_requeue, $self, $uri_intvl);
 416 }
 417
 418 sub reap { # callback for EOFpipe
 419         my ($pid, $cb, $self) = @{$_[0]};
 420         my $ret = waitpid($pid, 0);
 421         if ($ret == $pid) {
 422                 $cb->($self, $pid); # poll_fetch_reap || imap_idle_reap
 423         } else {
 424                 warn "W: waitpid($pid) => ", $ret // "($!)", "\n";
 425         }
 426 }
 427
 428 sub imap_idle_fork ($$) {
 429         my ($self, $uri_intvl) = @_;
 430         my ($uri, $intvl) = @$uri_intvl;
 431         pipe(my ($r, $w)) or die "pipe: $!";
 432         my $seed = rand(0xffffffff);
 433         my $pid = fork // die "fork: $!";
 434         if ($pid == 0) {
 435                 srand($seed);
 436                 eval { Net::SSLeay::randomize() };
 437                 close $r;
 438                 watch_atfork_child($self);
 439                 watch_imap_idle_1($self, $uri, $intvl);
 440                 close $w;
 441                 _exit(0);
 442         }
 443         $self->{idle_pids}->{$pid} = $uri_intvl;
 444         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&imap_idle_reap, $self]);
 445 }
 446
 447 sub event_step {
 448         my ($self) = @_;
 449         return if $self->{quit};
 450         my $idle_todo = $self->{idle_todo};
 451         if ($idle_todo && @$idle_todo) {
 452                 my $oldset = watch_atfork_parent($self);
 453                 eval {
 454                         while (my $uri_intvl = shift(@$idle_todo)) {
 455                                 imap_idle_fork($self, $uri_intvl);
 456                         }
 457                 };
 458                 PublicInbox::DS::sig_setmask($oldset);
 459                 die $@ if $@;
 460         }
 461         fs_scan_step($self) if $self->{mdre};
 462 }
 463
 464 sub watch_imap_fetch_all ($$) {
 465         my ($self, $uris) = @_;
 466         for my $uri (@$uris) {
 467                 imap_fetch_all($self, $uri);
 468                 last if $self->{quit};
 469         }
 470 }
 471
 472 sub watch_nntp_fetch_all ($$) {
 473         my ($self, $uris) = @_;
 474         $self->{incremental} = 1;
 475         $self->{on_commit} = [ \&_done_for_now, $self ];
 476         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 477         local $self->{cur_uid};
 478         my $uri = '';
 479         local $SIG{__WARN__} = sub {
 480                 my $pfx = ($_[0] // '') =~ /^([A-Z]: |# )/g ? $1 : '';
 481                 my $art = $self->{cur_uid};
 482                 $warn_cb->("$pfx$uri", $art ? ("ARTICLE $art") : (), "\n", @_);
 483         };
 484         for $uri (@$uris) {
 485                 PublicInbox::NetReader::nntp_each($self, $uri, \&net_cb, $self,
 486                                         $self->{nntp}->{$$uri});
 487                 last if $self->{quit};
 488         }
 489 }
 490
 491 sub poll_fetch_fork { # DS::add_timer callback
 492         my ($self, $intvl, $uris) = @_;
 493         return if $self->{quit};
 494         pipe(my ($r, $w)) or die "pipe: $!";
 495         my $oldset = watch_atfork_parent($self);
 496         my $seed = rand(0xffffffff);
 497         my $pid = fork;
 498         if (defined($pid) && $pid == 0) {
 499                 srand($seed);
 500                 eval { Net::SSLeay::randomize() };
 501                 close $r;
 502                 watch_atfork_child($self);
 503                 if ($uris->[0]->scheme =~ m!\Aimaps?!i) {
 504                         watch_imap_fetch_all($self, $uris);
 505                 } else {
 506                         watch_nntp_fetch_all($self, $uris);
 507                 }
 508                 close $w;
 509                 _exit(0);
 510         }
 511         PublicInbox::DS::sig_setmask($oldset);
 512         die "fork: $!"  unless defined $pid;
 513         $self->{poll_pids}->{$pid} = [ $intvl, $uris ];
 514         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&poll_fetch_reap, $self]);
 515 }
 516
 517 sub poll_fetch_reap {
 518         my ($self, $pid) = @_;
 519         my $intvl_uris = delete $self->{poll_pids}->{$pid} or
 520                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 521         return if $self->{quit};
 522         my ($intvl, $uris) = @$intvl_uris;
 523         if ($?) {
 524                 warn "W: PID=$pid died: \$?=$?\n", map { "$_\n" } @$uris;
 525         }
 526         warn("I: will check $_ in ${intvl}s\n") for @$uris;
 527         add_timer($intvl, \&poll_fetch_fork, $self, $intvl, $uris);
 528 }
 529
 530 sub watch_imap_init ($$) {
 531         my ($self, $poll) = @_;
 532         my $mics = PublicInbox::NetReader::imap_common_init($self);
 533         my $idle = []; # [ [ uri1, intvl1 ], [uri2, intvl2] ]
 534         for my $uri (@{$self->{imap_order}}) {
 535                 my $sec = uri_section($uri);
 536                 my $mic = $mics->{$sec};
 537                 my $intvl = $self->{cfg_opt}->{$sec}->{pollInterval};
 538                 if ($mic->has_capability('IDLE') && !$intvl) {
 539                         $intvl = $self->{cfg_opt}->{$sec}->{idleInterval};
 540                         push @$idle, [ $uri, $intvl // () ];
 541                 } else {
 542                         push @{$poll->{$intvl || 120}}, $uri;
 543                 }
 544         }
 545         if (scalar @$idle) {
 546                 $self->{idle_todo} = $idle;
 547                 PublicInbox::DS::requeue($self); # ->event_step to fork
 548         }
 549 }
 550
 551 sub watch_nntp_init ($$) {
 552         my ($self, $poll) = @_;
 553         PublicInbox::NetReader::nntp_common_init($self);
 554         for my $uri (@{$self->{nntp_order}}) {
 555                 my $sec = uri_section($uri);
 556                 my $intvl = $self->{cfg_opt}->{$sec}->{pollInterval};
 557                 push @{$poll->{$intvl || 120}}, $uri;
 558         }
 559 }
 560
 561 sub watch { # main entry point
 562         my ($self, $sig, $oldset) = @_;
 563         $self->{oldset} = $oldset;
 564         $self->{sig} = $sig;
 565         my $poll = {}; # intvl_seconds => [ uri1, uri2 ]
 566         watch_imap_init($self, $poll) if $self->{imap};
 567         watch_nntp_init($self, $poll) if $self->{nntp};
 568         while (my ($intvl, $uris) = each %$poll) {
 569                 # poll all URIs for a given interval sequentially
 570                 add_timer(0, \&poll_fetch_fork, $self, $intvl, $uris);
 571         }
 572         watch_fs_init($self) if $self->{mdre};
 573         PublicInbox::DS->SetPostLoopCallback(sub { !$self->quit_done });
 574         PublicInbox::DS::event_loop($sig, $oldset); # calls ->event_step
 575         _done_for_now($self);
 576 }
 577
 578 sub trigger_scan {
 579         my ($self, $op) = @_;
 580         push @{$self->{ops}}, $op;
 581         PublicInbox::DS::requeue($self);
 582 }
 583
 584 sub fs_scan_step {
 585         my ($self) = @_;
 586         return if $self->{quit};
 587         my $op = shift @{$self->{ops}};
 588         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 589
 590         # continue existing scan
 591         my $opendirs = $self->{opendirs};
 592         my @dirnames = keys %$opendirs;
 593         foreach my $dir (@dirnames) {
 594                 my $dh = delete $opendirs->{$dir};
 595                 my $n = $self->{max_batch};
 596                 while (my $fn = readdir($dh)) {
 597                         _try_path($self, "$dir/$fn");
 598                         last if --$n < 0;
 599                 }
 600                 $opendirs->{$dir} = $dh if $n < 0;
 601         }
 602         if ($op && $op eq 'full') {
 603                 foreach my $dir (keys %{$self->{mdmap}}) {
 604                         next if $opendirs->{$dir}; # already in progress
 605                         my $ok = opendir(my $dh, $dir);
 606                         unless ($ok) {
 607                                 warn "failed to open $dir: $!\n";
 608                                 next;
 609                         }
 610                         my $n = $self->{max_batch};
 611                         while (my $fn = readdir($dh)) {
 612                                 _try_path($self, "$dir/$fn");
 613                                 last if --$n < 0;
 614                         }
 615                         $opendirs->{$dir} = $dh if $n < 0;
 616                 }
 617         }
 618         _done_for_now($self);
 619         # do we have more work to do?
 620         PublicInbox::DS::requeue($self) if keys %$opendirs;
 621 }
 622
 623 sub scan {
 624         my ($self, $op) = @_;
 625         push @{$self->{ops}}, $op;
 626         fs_scan_step($self);
 627 }
 628
 629 sub _importer_for {
 630         my ($self, $ibx) = @_;
 631         my $importers = $self->{importers};
 632         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 633         if (scalar(keys(%$importers)) > 2) {
 634                 delete $importers->{"$ibx"};
 635                 _done_for_now($self);
 636         }
 637
 638         $importers->{"$ibx"} = $im;
 639 }
 640
 641 # XXX consider sharing with V2Writable, this only requires read-only access
 642 sub content_exists ($$) {
 643         my ($ibx, $eml) = @_;
 644         my $over = $ibx->over or return;
 645         my $mids = mids($eml);
 646         my $chash = content_hash($eml);
 647         my ($id, $prev);
 648         for my $mid (@$mids) {
 649                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 650                         my $cmp = $ibx->smsg_eml($smsg) or return;
 651                         return 1 if $chash eq content_hash($cmp);
 652                 }
 653         }
 654         undef;
 655 }
 656
 657 sub _spamcheck_cb {
 658         my ($sc) = @_;
 659         sub { # this gets called by (V2Writable||Import)->add
 660                 my ($mime, $ibx) = @_;
 661                 return if content_exists($ibx, $mime);
 662                 my $tmp = '';
 663                 if ($sc->spamcheck($mime, \$tmp)) {
 664                         return PublicInbox::Eml->new(\$tmp);
 665                 }
 666                 warn $mime->header('Message-ID')." failed spam check\n";
 667                 undef;
 668         }
 669 }
 670
 671 sub is_maildir {
 672         $_[0] =~ s!\Amaildir:!! or return;
 673         $_[0] =~ tr!/!/!s;
 674         $_[0] =~ s!/\z!!;
 675         $_[0];
 676 }
 677
 678 sub is_watchspam {
 679         my ($cur, $ws, $ibx) = @_;
 680         if ($ws && !ref($ws) && $ws eq 'watchspam') {
 681                 warn <<EOF;
 682 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
 683 EOF
 684                 return 1;
 685         }
 686         undef;
 687 }
 688
 689 sub folder_select { 'select' } # for PublicInbox::NetReader
 690
 691 1;