lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MIME;
  10 use PublicInbox::Git;
  11 use PublicInbox::Import;
  12 use PublicInbox::MDA;
  13 use PublicInbox::Spawn qw(spawn);
  14 use PublicInbox::InboxWritable;
  15 use File::Temp qw//;
  16 use PublicInbox::Filter::Base;
  17 use PublicInbox::Spamcheck;
  18 *REJECT = *PublicInbox::Filter::Base::REJECT;
  19
  20 sub new {
  21         my ($class, $config) = @_;
  22         my (%mdmap, @mdir, $spamc, $spamdir);
  23
  24         # "publicinboxwatch" is the documented namespace
  25         # "publicinboxlearn" is legacy but may be supported
  26         # indefinitely...
  27         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  28                 my $k = "$pfx.watchspam";
  29                 if (my $dir = $config->{$k}) {
  30                         if ($dir =~ s/\Amaildir://) {
  31                                 $dir =~ s!/+\z!!;
  32                                 # skip "new", no MUA has seen it, yet.
  33                                 my $cur = "$dir/cur";
  34                                 $spamdir = $cur;
  35                                 push @mdir, $cur;
  36                                 $mdmap{$cur} = 'watchspam';
  37                         } else {
  38                                 warn "unsupported $k=$dir\n";
  39                         }
  40                 }
  41         }
  42
  43         my $k = 'publicinboxwatch.spamcheck';
  44         my $default = undef;
  45         my $spamcheck = PublicInbox::Spamcheck::get($config, $k, $default);
  46         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  47
  48         # need to make all inboxes writable for spam removal:
  49         $config->each_inbox(sub { PublicInbox::InboxWritable->new($_[0]) });
  50
  51         foreach $k (keys %$config) {
  52                 $k =~ /\Apublicinbox\.([^\.]+)\.watch\z/ or next;
  53                 my $name = $1;
  54                 my $watch = $config->{$k};
  55                 if ($watch =~ s/\Amaildir://) {
  56                         $watch =~ s!/+\z!!;
  57                         my $inbox = $config->lookup_name($name);
  58                         if (my $wm = $inbox->{watchheader}) {
  59                                 my ($k, $v) = split(/:/, $wm, 2);
  60                                 $inbox->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  61                         }
  62                         my $new = "$watch/new";
  63                         my $cur = "$watch/cur";
  64                         push @mdir, $new, $cur;
  65                         die "$new already in use\n" if $mdmap{$new};
  66                         die "$cur already in use\n" if $mdmap{$cur};
  67                         $mdmap{$new} = $mdmap{$cur} = $inbox;
  68                 } else {
  69                         warn "watch unsupported: $k=$watch\n";
  70                 }
  71         }
  72         return unless @mdir;
  73
  74         my $mdre = join('|', map { quotemeta($_) } @mdir);
  75         $mdre = qr!\A($mdre)/!;
  76         bless {
  77                 spamcheck => $spamcheck,
  78                 spamdir => $spamdir,
  79                 mdmap => \%mdmap,
  80                 mdir => \@mdir,
  81                 mdre => $mdre,
  82                 config => $config,
  83                 importers => {},
  84                 opendirs => {}, # dirname => dirhandle (in progress scans)
  85         }, $class;
  86 }
  87
  88 sub _done_for_now {
  89         my ($self) = @_;
  90         my $importers = $self->{importers};
  91         foreach my $im (values %$importers) {
  92                 $im->done;
  93         }
  94 }
  95
  96 sub _try_fsn_paths {
  97         my ($self, $scan_re, $paths) = @_;
  98         foreach (@$paths) {
  99                 my $path = $_->{path};
 100                 if ($path =~ $scan_re) {
 101                         scan($self, $path);
 102                 } else {
 103                         _try_path($self, $path);
 104                 }
 105         }
 106         _done_for_now($self);
 107 }
 108
 109 sub _remove_spam {
 110         my ($self, $path) = @_;
 111         # path must be marked as (S)een
 112         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 113         my $mime = _path_to_mime($path) or return;
 114         $self->{config}->each_inbox(sub {
 115                 my ($ibx) = @_;
 116                 eval {
 117                         my $im = _importer_for($self, $ibx);
 118                         $im->remove($mime, 'spam');
 119                         if (my $scrub = $ibx->filter) {
 120                                 my $scrubbed = $scrub->scrub($mime, 1);
 121                                 $scrubbed or return;
 122                                 $scrubbed == REJECT() and return;
 123                                 $im->remove($scrubbed, 'spam');
 124                         }
 125                 };
 126                 if ($@) {
 127                         warn "error removing spam at: ", $path,
 128                                 " from ", $ibx->{name}, ': ', $@, "\n";
 129                 }
 130         })
 131 }
 132
 133 sub _try_path {
 134         my ($self, $path) = @_;
 135         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 136         if ($path !~ $self->{mdre}) {
 137                 warn "unrecognized path: $path\n";
 138                 return;
 139         }
 140         my $inbox = $self->{mdmap}->{$1};
 141         unless ($inbox) {
 142                 warn "unmappable dir: $1\n";
 143                 return;
 144         }
 145         if (!ref($inbox) && $inbox eq 'watchspam') {
 146                 return _remove_spam($self, $path);
 147         }
 148         my $im = _importer_for($self, $inbox);
 149         my $mime = _path_to_mime($path) or return;
 150         my $wm = $inbox->{-watchheader};
 151         if ($wm) {
 152                 my $v = $mime->header_obj->header_raw($wm->[0]);
 153                 return unless ($v && $v =~ $wm->[1]);
 154         }
 155         if (my $scrub = $inbox->filter) {
 156                 my $ret = $scrub->scrub($mime) or return;
 157                 $ret == REJECT() and return;
 158                 $mime = $ret;
 159         }
 160
 161         $im->add($mime, $self->{spamcheck});
 162 }
 163
 164 sub quit { trigger_scan($_[0], 'quit') }
 165
 166 sub watch {
 167         my ($self) = @_;
 168         my $scan = File::Temp->newdir("public-inbox-watch.$$.scan.XXXXXX",
 169                                         TMPDIR => 1);
 170         my $scandir = $self->{scandir} = $scan->dirname;
 171         my $re = qr!\A$scandir/!;
 172         my $cb = sub { _try_fsn_paths($self, $re, \@_) };
 173
 174         # lazy load here, we may support watching via IMAP IDLE
 175         # in the future...
 176         require Filesys::Notify::Simple;
 177         my $fsn = Filesys::Notify::Simple->new([@{$self->{mdir}}, $scandir]);
 178         $fsn->wait($cb) until $self->{quit};
 179 }
 180
 181 sub trigger_scan {
 182         my ($self, $base) = @_;
 183         my $dir = $self->{scandir} or return;
 184         open my $fh, '>', "$dir/$base" or die "open $dir/$base failed: $!\n";
 185         close $fh or die "close $dir/$base failed: $!\n";
 186 }
 187
 188 sub scan {
 189         my ($self, $path) = @_;
 190         if ($path =~ /quit\z/) {
 191                 %{$self->{opendirs}} = ();
 192                 _done_for_now($self);
 193                 delete $self->{scandir};
 194                 $self->{quit} = 1;
 195                 return;
 196         }
 197         # else: $path =~ /(cont|full)\z/
 198         return if $self->{quit};
 199         my $max = 10;
 200         my $opendirs = $self->{opendirs};
 201         my @dirnames = keys %$opendirs;
 202         foreach my $dir (@dirnames) {
 203                 my $dh = delete $opendirs->{$dir};
 204                 my $n = $max;
 205                 while (my $fn = readdir($dh)) {
 206                         _try_path($self, "$dir/$fn");
 207                         last if --$n < 0;
 208                 }
 209                 $opendirs->{$dir} = $dh if $n < 0;
 210         }
 211         if ($path =~ /full\z/) {
 212                 foreach my $dir (@{$self->{mdir}}) {
 213                         next if $opendirs->{$dir}; # already in progress
 214                         my $ok = opendir(my $dh, $dir);
 215                         unless ($ok) {
 216                                 warn "failed to open $dir: $!\n";
 217                                 next;
 218                         }
 219                         my $n = $max;
 220                         while (my $fn = readdir($dh)) {
 221                                 _try_path($self, "$dir/$fn");
 222                                 last if --$n < 0;
 223                         }
 224                         $opendirs->{$dir} = $dh if $n < 0;
 225                 }
 226         }
 227         _done_for_now($self);
 228         # do we have more work to do?
 229         trigger_scan($self, 'cont') if keys %$opendirs;
 230 }
 231
 232 sub _path_to_mime {
 233         my ($path) = @_;
 234         if (open my $fh, '<', $path) {
 235                 local $/;
 236                 my $str = <$fh>;
 237                 $str or return;
 238                 return PublicInbox::MIME->new(\$str);
 239         } elsif ($!{ENOENT}) {
 240                 return;
 241         } else {
 242                 warn "failed to open $path: $!\n";
 243                 return;
 244         }
 245 }
 246
 247 sub _importer_for {
 248         my ($self, $ibx) = @_;
 249         my $importers = $self->{importers};
 250         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 251         if (scalar(keys(%$importers)) > 2) {
 252                 delete $importers->{"$ibx"};
 253                 _done_for_now($self);
 254         }
 255
 256         $importers->{"$ibx"} = $im;
 257 }
 258
 259 sub _spamcheck_cb {
 260         my ($sc) = @_;
 261         sub {
 262                 my ($mime) = @_;
 263                 my $tmp = '';
 264                 if ($sc->spamcheck($mime, \$tmp)) {
 265                         return PublicInbox::MIME->new(\$tmp);
 266                 }
 267                 warn $mime->header('Message-ID')." failed spam check\n";
 268                 undef;
 269         }
 270 }
 271
 272 1;