lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable;
  11 use PublicInbox::Filter::Base qw(REJECT);
  12 use PublicInbox::Spamcheck;
  13 use PublicInbox::Sigfd;
  14 use PublicInbox::DS qw(now);
  15 use POSIX qw(_exit);
  16 *mime_from_path = \&PublicInbox::InboxWritable::mime_from_path;
  17
  18 sub compile_watchheaders ($) {
  19         my ($ibx) = @_;
  20         my $watch_hdrs = [];
  21         if (my $whs = $ibx->{watchheader}) {
  22                 for (@$whs) {
  23                         my ($k, $v) = split(/:/, $_, 2);
  24                         # XXX should this be case-insensitive?
  25                         # Or, mutt-style, case-sensitive iff
  26                         # a capital letter exists?
  27                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  28                 }
  29         }
  30         if (my $list_ids = $ibx->{listid}) {
  31                 for (@$list_ids) {
  32                         # RFC2919 section 6 stipulates
  33                         # "case insensitive equality"
  34                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  35                         push @$watch_hdrs, ['List-Id', $re ];
  36                 }
  37         }
  38         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  39 }
  40
  41 sub new {
  42         my ($class, $config) = @_;
  43         my (%mdmap, @mdir, $spamc);
  44         my %uniq; # directory => count
  45         my %imap; # url => [inbox objects] or 'watchspam'
  46
  47         # "publicinboxwatch" is the documented namespace
  48         # "publicinboxlearn" is legacy but may be supported
  49         # indefinitely...
  50         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  51                 my $k = "$pfx.watchspam";
  52                 defined(my $dirs = $config->{$k}) or next;
  53                 $dirs = [ $dirs ] if !ref($dirs);
  54                 for my $dir (@$dirs) {
  55                         if (is_maildir($dir)) {
  56                                 # skip "new", no MUA has seen it, yet.
  57                                 my $cur = "$dir/cur";
  58                                 push @mdir, $cur;
  59                                 $uniq{$cur}++;
  60                                 $mdmap{$cur} = 'watchspam';
  61                         } elsif (my $url = imap_url($dir)) {
  62                                 $imap{$url} = 'watchspam';
  63                         } else {
  64                                 warn "unsupported $k=$dir\n";
  65                         }
  66                 }
  67         }
  68
  69         my $k = 'publicinboxwatch.spamcheck';
  70         my $default = undef;
  71         my $spamcheck = PublicInbox::Spamcheck::get($config, $k, $default);
  72         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  73
  74         $config->each_inbox(sub {
  75                 # need to make all inboxes writable for spam removal:
  76                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  77
  78                 my $watch = $ibx->{watch} or return;
  79                 if (is_maildir($watch)) {
  80                         compile_watchheaders($ibx);
  81                         my ($new, $cur) = ("$watch/new", "$watch/cur");
  82                         return if is_watchspam($cur, $mdmap{$cur}, $ibx);
  83                         push @mdir, $new unless $uniq{$new}++;
  84                         push @mdir, $cur unless $uniq{$cur}++;
  85                         push @{$mdmap{$new} ||= []}, $ibx;
  86                         push @{$mdmap{$cur} ||= []}, $ibx;
  87                 } elsif (my $url = imap_url($watch)) {
  88                         return if is_watchspam($url, $imap{$url}, $ibx);
  89                         compile_watchheaders($ibx);
  90                         push @{$imap{$url} ||= []}, $ibx;
  91                 } else {
  92                         warn "watch unsupported: $k=$watch\n";
  93                 }
  94         });
  95         return unless scalar(@mdir) || scalar(keys %imap);
  96
  97         my $mdre;
  98         if (@mdir) {
  99                 $mdre = join('|', map { quotemeta($_) } @mdir);
 100                 $mdre = qr!\A($mdre)/!;
 101         }
 102         bless {
 103                 spamcheck => $spamcheck,
 104                 mdmap => \%mdmap,
 105                 mdir => \@mdir,
 106                 mdre => $mdre,
 107                 config => $config,
 108                 imap => scalar keys %imap ? \%imap : undef,
 109                 importers => {},
 110                 opendirs => {}, # dirname => dirhandle (in progress scans)
 111                 ops => [], # 'quit', 'full'
 112         }, $class;
 113 }
 114
 115 sub _done_for_now {
 116         my ($self) = @_;
 117         my $importers = $self->{importers};
 118         foreach my $im (values %$importers) {
 119                 $im->done;
 120         }
 121 }
 122
 123 sub remove_eml_i { # each_inbox callback
 124         my ($ibx, $arg) = @_;
 125         my ($self, $eml, $loc) = @$arg;
 126         eval {
 127                 my $im = _importer_for($self, $ibx);
 128                 $im->remove($eml, 'spam');
 129                 if (my $scrub = $ibx->filter($im)) {
 130                         my $scrubbed = $scrub->scrub($eml, 1);
 131                         $scrubbed or return;
 132                         $scrubbed == REJECT() and return;
 133                         $im->remove($scrubbed, 'spam');
 134                 }
 135         };
 136         warn "error removing spam at: $loc from $ibx->{name}: $@\n" if $@;
 137 }
 138
 139 sub _remove_spam {
 140         my ($self, $path) = @_;
 141         # path must be marked as (S)een
 142         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 143         my $eml = mime_from_path($path) or return;
 144         $self->{config}->each_inbox(\&remove_eml_i, [ $self, $eml, $path ]);
 145 }
 146
 147 sub import_eml ($$$) {
 148         my ($self, $ibx, $eml) = @_;
 149         my $im = _importer_for($self, $ibx);
 150
 151         # any header match means it's eligible for the inbox:
 152         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 153                 my $ok;
 154                 my $hdr = $eml->header_obj;
 155                 for my $wh (@$watch_hdrs) {
 156                         my @v = $hdr->header_raw($wh->[0]);
 157                         $ok = grep(/$wh->[1]/, @v) and last;
 158                 }
 159                 return unless $ok;
 160         }
 161
 162         if (my $scrub = $ibx->filter($im)) {
 163                 my $ret = $scrub->scrub($eml) or return;
 164                 $ret == REJECT() and return;
 165                 $eml = $ret;
 166         }
 167         $im->add($eml, $self->{spamcheck});
 168 }
 169
 170 sub _try_path {
 171         my ($self, $path) = @_;
 172         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 173         if ($path !~ $self->{mdre}) {
 174                 warn "unrecognized path: $path\n";
 175                 return;
 176         }
 177         my $inboxes = $self->{mdmap}->{$1};
 178         unless ($inboxes) {
 179                 warn "unmappable dir: $1\n";
 180                 return;
 181         }
 182         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 183                 return _remove_spam($self, $path);
 184         }
 185
 186         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 187         local $SIG{__WARN__} = sub {
 188                 $warn_cb->("path: $path\n");
 189                 $warn_cb->(@_);
 190         };
 191         foreach my $ibx (@$inboxes) {
 192                 my $eml = mime_from_path($path) or next;
 193                 import_eml($self, $ibx, $eml);
 194         }
 195 }
 196
 197 sub quit {
 198         my ($self) = @_;
 199         $self->{quit} = 1;
 200         %{$self->{opendirs}} = ();
 201         _done_for_now($self);
 202         if (my $imap_pid = $self->{-imap_pid}) {
 203                 kill('QUIT', $imap_pid);
 204         }
 205         for (qw(idle_pids poll_pids)) {
 206                 my $pids = $self->{$_} or next;
 207                 kill('QUIT', $_) for (keys %$pids);
 208         }
 209         if (my $idle_mic = $self->{idle_mic}) {
 210                 eval { $idle_mic->done };
 211                 warn "IDLE DONE error: $@\n" if $@;
 212                 eval { $idle_mic->disconnect };
 213                 warn "IDLE LOGOUT error: $@\n" if $@;
 214         }
 215 }
 216
 217 sub watch_fs_init ($) {
 218         my ($self) = @_;
 219         my $done = sub {
 220                 delete $self->{done_timer};
 221                 _done_for_now($self);
 222         };
 223         my $cb = sub {
 224                 _try_path($self, $_[0]->fullname);
 225                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 226         };
 227         require PublicInbox::DirIdle;
 228         PublicInbox::DirIdle->new($self->{mdir}, $cb); # EPOLL_CTL_ADD
 229 }
 230
 231 # returns the git config section name, e.g [imap "imaps://user@example.com"]
 232 # without the mailbox, so we can share connections between different inboxes
 233 sub imap_section ($) {
 234         my ($uri) = @_;
 235         $uri->scheme . '://' . $uri->authority;
 236 }
 237
 238 sub cfg_intvl ($$$$$) {
 239         my ($cfg, $cfg_section, $cfg_key, $imap_section, $url) = @_;
 240         my $key = "$cfg_section.$imap_section.$cfg_key";
 241         my $v = $cfg->{lc($key)} //
 242                 $cfg->urlmatch("$cfg_section.$cfg_key", $url) // return;
 243         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 244         if (ref($v) eq 'ARRAY') {
 245                 $v = join(', ', @$v);
 246                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 247         } else {
 248                 warn "W: $key=$v is not a numeric value in seconds\n";
 249         }
 250 }
 251
 252 # flesh out common IMAP-specific data structures
 253 sub imap_common_init ($) {
 254         my ($self) = @_;
 255         my $cfg = $self->{config};
 256         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 257         for my $url (sort keys %{$self->{imap}}) {
 258                 my $uri = PublicInbox::URIimap->new($url);
 259                 my $sec = imap_section($uri);
 260                 for my $k (qw(Starttls Debug Compress)) {
 261                         my $key = lc("imap.$sec.$k");
 262                         my $orig = $cfg->{$key} //
 263                                 $cfg->urlmatch("imap.$k", $url) // next;
 264                         my $v = PublicInbox::Config::_git_config_bool($orig);
 265                         if (defined($v)) {
 266                                 $mic_args->{$sec}->{$k} = $v;
 267                         } else {
 268                                 warn "W: $key=$orig is not boolean\n";
 269                         }
 270                 }
 271                 my $to = cfg_intvl($cfg, 'imap', 'Timeout', $sec, $url);
 272                 $mic_args->{$sec}->{Timeout} = $to if $to;
 273                 $to = cfg_intvl($cfg, 'imap', 'PollInterval', $sec, $url);
 274                 $self->{imap_opt}->{$sec}->{poll_intvl} = $to if $to;
 275                 $to = cfg_intvl($cfg, 'imap', 'IdleInterval', $sec, $url);
 276                 $self->{imap_opt}->{$sec}->{idle_intvl} = $to if $to;
 277         }
 278         $mic_args;
 279 }
 280
 281 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
 282
 283 sub mic_for ($$$) { # mic = Mail::IMAPClient
 284         my ($self, $uri, $mic_args) = @_;
 285         my $url = $uri->as_string;
 286         my $cred = {
 287                 url => $url,
 288                 protocol => $uri->scheme,
 289                 host => $uri->host,
 290                 username => $uri->user,
 291                 password => $uri->password,
 292         };
 293         my $common = $mic_args->{imap_section($uri)} // {};
 294         my $host = $cred->{host};
 295         my $mic_arg = {
 296                 Port => $uri->port,
 297                 # IMAPClient mishandles `0', so we pass `127.0.0.1'
 298                 Server => $host eq '0' ? '127.0.0.1' : $host,
 299                 Ssl => $uri->scheme eq 'imaps',
 300                 Keepalive => 1, # SO_KEEPALIVE
 301                 %$common, # may set Starttls, Compress, Debug ....
 302         };
 303         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
 304                 die "E: <$url> new: $@\n";
 305
 306         # default to using STARTTLS if it's available, but allow
 307         # it to be disabled since I usually connect to localhost
 308         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 309                         $mic->has_capability('STARTTLS') &&
 310                         $mic->can('starttls')) {
 311                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
 312         }
 313
 314         # do we even need credentials?
 315         if (!defined($cred->{username}) &&
 316                         $mic->has_capability('AUTH=ANONYMOUS')) {
 317                 $cred = undef;
 318         }
 319         if ($cred) {
 320                 Git::credential($cred, 'fill'); # may prompt user here
 321                 $mic->User($mic_arg->{User} = $cred->{username});
 322                 $mic->Password($mic_arg->{Password} = $cred->{password});
 323         } else { # AUTH=ANONYMOUS
 324                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 325                 $mic->Authcallback($mic_arg->{Authcallback} = \&auth_anon_cb);
 326         }
 327         if ($mic->login && $mic->IsAuthenticated) {
 328                 # success! keep IMAPClient->new arg in case we get disconnected
 329                 $self->{mic_arg}->{imap_section($uri)} = $mic_arg;
 330         } else {
 331                 warn "E: <$url> LOGIN: $@\n";
 332                 $mic = undef;
 333         }
 334         Git::credential($cred, $mic ? 'approve' : 'reject') if $cred;
 335         $mic;
 336 }
 337
 338 sub imap_fetch_all ($$$) {
 339         my ($self, $mic, $uri) = @_;
 340         my $sec = imap_section($uri);
 341         my $mbx = $uri->mailbox;
 342         my $url = $uri->as_string;
 343         $mic->Clear(1); # trim results history
 344         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 345         my ($r_uidval, $r_uidnext);
 346         for ($mic->Results) {
 347                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 348                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 349                 last if $r_uidval && $r_uidnext;
 350         }
 351         $r_uidval //= $mic->uidvalidity($mbx) //
 352                 return "E: $url cannot get UIDVALIDITY";
 353         $r_uidnext //= $mic->uidnext($mbx) //
 354                 return "E: $url cannot get UIDNEXT";
 355         my $itrk = PublicInbox::IMAPTracker->new;
 356         my ($l_uidval, $l_uid) = $itrk->get_last($url);
 357         $l_uidval //= $r_uidval; # first time
 358         $l_uid //= 1;
 359         if ($l_uidval != $r_uidval) {
 360                 return "E: $url UIDVALIDITY mismatch\n".
 361                         "E: local=$l_uidval != remote=$r_uidval";
 362         }
 363         my $r_uid = $r_uidnext - 1;
 364         if ($l_uid != 1 && $l_uid > $r_uid) {
 365                 return "E: $url local UID exceeds remote ($l_uid > $r_uid)\n".
 366                         "E: $url strangely, UIDVALIDLITY matches ($l_uidval)\n";
 367         }
 368         return if $l_uid >= $r_uid; # nothing to do
 369
 370         $mic->Uid(1); # the default, we hope
 371         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 372         my $key = $req;
 373         $key =~ s/\.PEEK//;
 374         my $inboxes = $self->{imap}->{$url};
 375         warn "I: $url fetching $l_uid..$r_uid\n";
 376         my $uid = -1;
 377         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 378         local $SIG{__WARN__} = sub {
 379                 $warn_cb->("$url UID:$uid\n");
 380                 $warn_cb->(@_);
 381         };
 382         my $err;
 383         $itrk->{dbh}->begin_work;
 384         for my $u ($l_uid..$r_uid) {
 385                 $uid = $u;
 386                 local $0 = "UID:$uid $mbx $sec";
 387                 my $r = $mic->fetch_hash($uid, $req);
 388                 unless ($r) { # network error?
 389                         $err = "E: $url UID FETCH $uid error: $!\n";
 390                         last;
 391                 }
 392
 393                 # messages get deleted, so holes appear
 394                 defined(my $raw = delete $r->{$uid}->{$key}) or next;
 395
 396                 # our target audience expects LF-only, save storage
 397                 $raw =~ s/\r\n/\n/sg;
 398
 399                 if (ref($inboxes)) {
 400                         for my $ibx (@$inboxes) {
 401                                 my $eml = PublicInbox::Eml->new($raw);
 402                                 my $x = import_eml($self, $ibx, $eml);
 403                         }
 404                 } elsif ($inboxes eq 'watchspam') {
 405                         my $eml = PublicInbox::Eml->new($raw);
 406                         my $arg = [ $self, $eml, "$uri UID:$uid" ];
 407                         $self->{config}->each_inbox(\&remove_eml_i, $arg);
 408                 } else {
 409                         die "BUG: destination unknown $inboxes";
 410                 }
 411                 $itrk->update_last($url, $r_uidval, $uid);
 412                 last if $self->{quit};
 413         }
 414         _done_for_now($self);
 415         $itrk->{dbh}->commit;
 416         $err;
 417 }
 418
 419 sub imap_idle_once ($$$$) {
 420         my ($self, $mic, $intvl, $url) = @_;
 421         my $i = $intvl //= (29 * 60);
 422         my $end = now() + $intvl;
 423         warn "I: $url idling for ${intvl}s\n";
 424         local $0 = "IDLE $0";
 425         unless ($mic->idle) {
 426                 return if $self->{quit};
 427                 return "E: IDLE failed on $url: $!";
 428         }
 429         $self->{idle_mic} = $mic; # for ->quit
 430         my @res;
 431         until ($self->{quit} || grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 432                 @res = $mic->idle_data($i);
 433                 $i = $end - now();
 434         }
 435         delete $self->{idle_mic};
 436         unless ($self->{quit}) {
 437                 $mic->IsConnected or return "E: IDLE disconnected on $url";
 438                 $mic->done or return "E: IDLE DONE failed on $url: $!";
 439         }
 440         undef;
 441 }
 442
 443 # idles on a single URI
 444 sub watch_imap_idle_1 ($$$) {
 445         my ($self, $uri, $intvl) = @_;
 446         my $sec = imap_section($uri);
 447         my $mic_arg = $self->{mic_arg}->{$sec} or
 448                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 449         my $mic;
 450         local $0 = $uri->mailbox." $sec";
 451         until ($self->{quit}) {
 452                 $mic //= delete($self->{mics}->{$sec}) //
 453                                 PublicInbox::IMAPClient->new(%$mic_arg);
 454                 my $err = imap_fetch_all($self, $mic, $uri);
 455                 $err //= imap_idle_once($self, $mic, $intvl, $uri->as_string);
 456                 if ($err && !$self->{quit}) {
 457                         warn $err, "\n";
 458                         $mic = undef;
 459                         sleep 60 unless $self->{quit};
 460                 }
 461         }
 462 }
 463
 464 sub watch_atfork_child ($) {
 465         my ($self) = @_;
 466         delete $self->{idle_pids};
 467         delete $self->{poll_pids};
 468         delete $self->{opendirs};
 469         PublicInbox::DS->Reset;
 470         PublicInbox::Sigfd::sig_setmask($self->{oldset});
 471         %SIG = (%SIG, %{$self->{sig}});
 472 }
 473
 474 sub watch_atfork_parent ($) {
 475         my ($self) = @_;
 476         _done_for_now($self);
 477         $self->{mics} = {}; # going to be forking, so disconnect
 478 }
 479
 480 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 481         my ($self, $pid) = @_;
 482         my $uri_intvl = delete $self->{idle_pids}->{$pid} or
 483                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 484
 485         my ($uri, $intvl) = @$uri_intvl;
 486         my $url = $uri->as_string;
 487         return if $self->{quit};
 488         warn "W: PID=$pid on $url died: \$?=$?\n" if $?;
 489         push @{$self->{idle_todo}}, $uri_intvl;
 490         PubicInbox::DS::requeue($self); # call ->event_step to respawn
 491 }
 492
 493 sub imap_idle_fork ($$) {
 494         my ($self, $uri_intvl) = @_;
 495         my ($uri, $intvl) = @$uri_intvl;
 496         defined(my $pid = fork) or die "fork: $!";
 497         if ($pid == 0) {
 498                 watch_atfork_child($self);
 499                 watch_imap_idle_1($self, $uri, $intvl);
 500                 _exit(0);
 501         }
 502         $self->{idle_pids}->{$pid} = $uri_intvl;
 503         PublicInbox::DS::dwaitpid($pid, \&imap_idle_reap, $self);
 504 }
 505
 506 sub event_step {
 507         my ($self) = @_;
 508         return if $self->{quit};
 509         my $idle_todo = $self->{idle_todo};
 510         if ($idle_todo && @$idle_todo) {
 511                 watch_atfork_parent($self);
 512                 while (my $uri_intvl = shift(@$idle_todo)) {
 513                         imap_idle_fork($self, $uri_intvl);
 514                 }
 515         }
 516         goto(&fs_scan_step) if $self->{mdre};
 517 }
 518
 519 sub watch_imap_fetch_all ($$) {
 520         my ($self, $uris) = @_;
 521         for my $uri (@$uris) {
 522                 my $sec = imap_section($uri);
 523                 my $mic_arg = $self->{mic_arg}->{$sec} or
 524                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 525                 my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or next;
 526                 my $err = imap_fetch_all($self, $mic, $uri);
 527                 last if $self->{quit};
 528                 warn $err, "\n" if $err;
 529         }
 530 }
 531
 532 sub imap_fetch_fork ($$$) {
 533         my ($self, $intvl, $uris) = @_;
 534         return if $self->{quit};
 535         watch_atfork_parent($self);
 536         defined(my $pid = fork) or die "fork: $!";
 537         if ($pid == 0) {
 538                 watch_atfork_child($self);
 539                 watch_imap_fetch_all($self, $uris);
 540                 _exit(0);
 541         }
 542         $self->{poll_pids}->{$pid} = [ $intvl, $uris ];
 543         PublicInbox::DS::dwaitpid($pid, \&imap_fetch_reap, $self);
 544 }
 545
 546 sub imap_fetch_cb ($$$) {
 547         my ($self, $intvl, $uris) = @_;
 548         sub { imap_fetch_fork($self, $intvl, $uris) };
 549 }
 550
 551 sub imap_fetch_reap { # PublicInbox::DS::dwaitpid callback
 552         my ($self, $pid) = @_;
 553         my $intvl_uris = delete $self->{poll_pids}->{$pid} or
 554                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 555         return if $self->{quit};
 556         my ($intvl, $uris) = @$intvl_uris;
 557         if ($?) {
 558                 warn "W: PID=$pid died: \$?=$?\n",
 559                         map { $_->as_string."\n" } @$uris;
 560         }
 561         warn('I: will check ', $_->as_string, " in ${intvl}s\n") for @$uris;
 562         PublicInbox::DS::add_timer($intvl, imap_fetch_cb($self, $intvl, $uris));
 563 }
 564
 565 sub watch_imap_init ($) {
 566         my ($self) = @_;
 567         eval { require PublicInbox::IMAPClient } or
 568                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 569         eval { require Git } or
 570                 die "Git (Perl module) is required for IMAP:\n$@\n";
 571         eval { require PublicInbox::IMAPTracker } or
 572                 die "DBD::SQLite is required for IMAP\n:$@\n";
 573
 574         my $mic_args = imap_common_init($self); # read args from config
 575
 576         # make sure we can connect and cache the credentials in memory
 577         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 578         my $mics = $self->{mics} = {}; # schema://authority => IMAPClient obj
 579         for my $url (sort keys %{$self->{imap}}) {
 580                 my $uri = PublicInbox::URIimap->new($url);
 581                 $mics->{imap_section($uri)} //= mic_for($self, $uri, $mic_args);
 582         }
 583
 584         my $idle = []; # [ [ uri1, intvl1 ], [uri2, intvl2] ]
 585         my $poll = {}; # intvl_seconds => [ uri1, uri2 ]
 586         for my $url (keys %{$self->{imap}}) {
 587                 my $uri = PublicInbox::URIimap->new($url);
 588                 my $sec = imap_section($uri);
 589                 my $mic = $mics->{$sec};
 590                 my $intvl = $self->{imap_opt}->{$sec}->{poll_intvl};
 591                 if ($mic->has_capability('IDLE') && !$intvl) {
 592                         $intvl = $self->{imap_opt}->{$sec}->{idle_intvl};
 593                         push @$idle, [ $uri, $intvl // () ];
 594                 } else {
 595                         push @{$poll->{$intvl || 120}}, $uri;
 596                 }
 597         }
 598         if (scalar @$idle) {
 599                 $self->{idle_pids} = {};
 600                 $self->{idle_todo} = $idle;
 601                 PublicInbox::DS::requeue($self); # ->event_step to fork
 602         }
 603         return unless scalar keys %$poll;
 604         $self->{poll_pids} = {};
 605
 606         # poll all URIs for a given interval sequentially
 607         while (my ($intvl, $uris) = each %$poll) {
 608                 PublicInbox::DS::requeue(imap_fetch_cb($self, $intvl, $uris));
 609         }
 610 }
 611
 612 sub watch {
 613         my ($self, $sig, $oldset) = @_;
 614         $self->{oldset} = $oldset;
 615         $self->{sig} = $sig;
 616         watch_imap_init($self) if $self->{imap};
 617         watch_fs_init($self) if $self->{mdre};
 618         PublicInbox::DS->SetPostLoopCallback(sub {});
 619         PublicInbox::DS->EventLoop until $self->{quit};
 620         _done_for_now($self);
 621 }
 622
 623 sub trigger_scan {
 624         my ($self, $op) = @_;
 625         push @{$self->{ops}}, $op;
 626         PublicInbox::DS::requeue($self);
 627 }
 628
 629 sub fs_scan_step {
 630         my ($self) = @_;
 631         return if $self->{quit};
 632         my $op = shift @{$self->{ops}};
 633
 634         # continue existing scan
 635         my $max = 10;
 636         my $opendirs = $self->{opendirs};
 637         my @dirnames = keys %$opendirs;
 638         foreach my $dir (@dirnames) {
 639                 my $dh = delete $opendirs->{$dir};
 640                 my $n = $max;
 641                 while (my $fn = readdir($dh)) {
 642                         _try_path($self, "$dir/$fn");
 643                         last if --$n < 0;
 644                 }
 645                 $opendirs->{$dir} = $dh if $n < 0;
 646         }
 647         if ($op && $op eq 'full') {
 648                 foreach my $dir (@{$self->{mdir}}) {
 649                         next if $opendirs->{$dir}; # already in progress
 650                         my $ok = opendir(my $dh, $dir);
 651                         unless ($ok) {
 652                                 warn "failed to open $dir: $!\n";
 653                                 next;
 654                         }
 655                         my $n = $max;
 656                         while (my $fn = readdir($dh)) {
 657                                 _try_path($self, "$dir/$fn");
 658                                 last if --$n < 0;
 659                         }
 660                         $opendirs->{$dir} = $dh if $n < 0;
 661                 }
 662         }
 663         _done_for_now($self);
 664         # do we have more work to do?
 665         PublicInbox::DS::requeue($self) if keys %$opendirs;
 666 }
 667
 668 sub scan {
 669         my ($self, $op) = @_;
 670         push @{$self->{ops}}, $op;
 671         goto &fs_scan_step;
 672 }
 673
 674 sub _importer_for {
 675         my ($self, $ibx) = @_;
 676         my $importers = $self->{importers};
 677         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 678         if (scalar(keys(%$importers)) > 2) {
 679                 delete $importers->{"$ibx"};
 680                 _done_for_now($self);
 681         }
 682
 683         $importers->{"$ibx"} = $im;
 684 }
 685
 686 sub _spamcheck_cb {
 687         my ($sc) = @_;
 688         sub {
 689                 my ($mime) = @_;
 690                 my $tmp = '';
 691                 if ($sc->spamcheck($mime, \$tmp)) {
 692                         return PublicInbox::Eml->new(\$tmp);
 693                 }
 694                 warn $mime->header('Message-ID')." failed spam check\n";
 695                 undef;
 696         }
 697 }
 698
 699 sub is_maildir {
 700         $_[0] =~ s!\Amaildir:!! or return;
 701         $_[0] =~ tr!/!/!s;
 702         $_[0] =~ s!/\z!!;
 703         $_[0];
 704 }
 705
 706 sub is_watchspam {
 707         my ($cur, $ws, $ibx) = @_;
 708         if ($ws && !ref($ws) && $ws eq 'watchspam') {
 709                 warn <<EOF;
 710 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
 711 EOF
 712                 return 1;
 713         }
 714         undef;
 715 }
 716
 717 sub imap_url {
 718         my ($url) = @_;
 719         require PublicInbox::URIimap;
 720         my $uri = PublicInbox::URIimap->new($url);
 721         $uri ? $uri->canonical->as_string : undef;
 722 }
 723
 724 1;