lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable qw(eml_from_path warn_ignore_cb);
  11 use PublicInbox::Filter::Base qw(REJECT);
  12 use PublicInbox::Spamcheck;
  13 use PublicInbox::Sigfd;
  14 use PublicInbox::DS qw(now);
  15 use PublicInbox::MID qw(mids);
  16 use PublicInbox::ContentHash qw(content_hash);
  17 use POSIX qw(_exit);
  18
  19 sub compile_watchheaders ($) {
  20         my ($ibx) = @_;
  21         my $watch_hdrs = [];
  22         if (my $whs = $ibx->{watchheader}) {
  23                 for (@$whs) {
  24                         my ($k, $v) = split(/:/, $_, 2);
  25                         # XXX should this be case-insensitive?
  26                         # Or, mutt-style, case-sensitive iff
  27                         # a capital letter exists?
  28                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  29                 }
  30         }
  31         if (my $list_ids = $ibx->{listid}) {
  32                 for (@$list_ids) {
  33                         # RFC2919 section 6 stipulates
  34                         # "case insensitive equality"
  35                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  36                         push @$watch_hdrs, ['List-Id', $re ];
  37                 }
  38         }
  39         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  40 }
  41
  42 sub new {
  43         my ($class, $config) = @_;
  44         my (%mdmap, $spamc);
  45         my (%imap, %nntp); # url => [inbox objects] or 'watchspam'
  46
  47         # "publicinboxwatch" is the documented namespace
  48         # "publicinboxlearn" is legacy but may be supported
  49         # indefinitely...
  50         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  51                 my $k = "$pfx.watchspam";
  52                 defined(my $dirs = $config->{$k}) or next;
  53                 $dirs = PublicInbox::Config::_array($dirs);
  54                 for my $dir (@$dirs) {
  55                         my $url;
  56                         if (is_maildir($dir)) {
  57                                 # skip "new", no MUA has seen it, yet.
  58                                 $mdmap{"$dir/cur"} = 'watchspam';
  59                         } elsif ($url = imap_url($dir)) {
  60                                 $imap{$url} = 'watchspam';
  61                         } elsif ($url = nntp_url($dir)) {
  62                                 $nntp{$url} = 'watchspam';
  63                         } else {
  64                                 warn "unsupported $k=$dir\n";
  65                         }
  66                 }
  67         }
  68
  69         my $k = 'publicinboxwatch.spamcheck';
  70         my $default = undef;
  71         my $spamcheck = PublicInbox::Spamcheck::get($config, $k, $default);
  72         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  73
  74         $config->each_inbox(sub {
  75                 # need to make all inboxes writable for spam removal:
  76                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  77
  78                 my $watches = $ibx->{watch} or return;
  79                 $watches = PublicInbox::Config::_array($watches);
  80                 for my $watch (@$watches) {
  81                         my $url;
  82                         if (is_maildir($watch)) {
  83                                 compile_watchheaders($ibx);
  84                                 my ($new, $cur) = ("$watch/new", "$watch/cur");
  85                                 my $cur_dst = $mdmap{$cur} //= [];
  86                                 return if is_watchspam($cur, $cur_dst, $ibx);
  87                                 push @{$mdmap{$new} //= []}, $ibx;
  88                                 push @$cur_dst, $ibx;
  89                         } elsif ($url = imap_url($watch)) {
  90                                 return if is_watchspam($url, $imap{$url}, $ibx);
  91                                 compile_watchheaders($ibx);
  92                                 push @{$imap{$url} ||= []}, $ibx;
  93                         } elsif ($url = nntp_url($watch)) {
  94                                 return if is_watchspam($url, $nntp{$url}, $ibx);
  95                                 compile_watchheaders($ibx);
  96                                 push @{$nntp{$url} ||= []}, $ibx;
  97                         } else {
  98                                 warn "watch unsupported: $k=$watch\n";
  99                         }
 100                 }
 101         });
 102
 103         my $mdre;
 104         if (scalar keys %mdmap) {
 105                 $mdre = join('|', map { quotemeta($_) } keys %mdmap);
 106                 $mdre = qr!\A($mdre)/!;
 107         }
 108         return unless $mdre || scalar(keys %imap) || scalar(keys %nntp);
 109
 110         bless {
 111                 spamcheck => $spamcheck,
 112                 mdmap => \%mdmap,
 113                 mdre => $mdre,
 114                 config => $config,
 115                 imap => scalar keys %imap ? \%imap : undef,
 116                 nntp => scalar keys %nntp? \%nntp : undef,
 117                 importers => {},
 118                 opendirs => {}, # dirname => dirhandle (in progress scans)
 119                 ops => [], # 'quit', 'full'
 120         }, $class;
 121 }
 122
 123 sub _done_for_now {
 124         my ($self) = @_;
 125         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 126         for my $im (values %{$self->{importers}}) {
 127                 next if !$im; # $im may be undef during cleanup
 128                 eval { $im->done };
 129                 warn "$im->{ibx}->{name} ->done: $@\n" if $@;
 130         }
 131 }
 132
 133 sub remove_eml_i { # each_inbox callback
 134         my ($ibx, $arg) = @_;
 135         my ($self, $eml, $loc) = @$arg;
 136         eval {
 137                 my $im = _importer_for($self, $ibx);
 138                 $im->remove($eml, 'spam');
 139                 if (my $scrub = $ibx->filter($im)) {
 140                         my $scrubbed = $scrub->scrub($eml, 1);
 141                         if ($scrubbed && $scrubbed != REJECT) {
 142                                 $im->remove($scrubbed, 'spam');
 143                         }
 144                 }
 145         };
 146         if ($@) {
 147                 warn "error removing spam at: $loc from $ibx->{name}: $@\n";
 148                 _done_for_now($self);
 149         }
 150 }
 151
 152 sub _remove_spam {
 153         my ($self, $path) = @_;
 154         # path must be marked as (S)een
 155         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 156         my $eml = eml_from_path($path) or return;
 157         local $SIG{__WARN__} = warn_ignore_cb();
 158         $self->{config}->each_inbox(\&remove_eml_i, [ $self, $eml, $path ]);
 159 }
 160
 161 sub import_eml ($$$) {
 162         my ($self, $ibx, $eml) = @_;
 163
 164         # any header match means it's eligible for the inbox:
 165         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 166                 my $ok;
 167                 for my $wh (@$watch_hdrs) {
 168                         my @v = $eml->header_raw($wh->[0]);
 169                         $ok = grep(/$wh->[1]/, @v) and last;
 170                 }
 171                 return unless $ok;
 172         }
 173         eval {
 174                 my $im = _importer_for($self, $ibx);
 175                 if (my $scrub = $ibx->filter($im)) {
 176                         my $scrubbed = $scrub->scrub($eml) or return;
 177                         $scrubbed == REJECT and return;
 178                         $eml = $scrubbed;
 179                 }
 180                 $im->add($eml, $self->{spamcheck});
 181         };
 182         if ($@) {
 183                 warn "$ibx->{name} add failed: $@\n";
 184                 _done_for_now($self);
 185         }
 186 }
 187
 188 sub _try_path {
 189         my ($self, $path) = @_;
 190         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 191         if ($path !~ $self->{mdre}) {
 192                 warn "unrecognized path: $path\n";
 193                 return;
 194         }
 195         my $inboxes = $self->{mdmap}->{$1};
 196         unless ($inboxes) {
 197                 warn "unmappable dir: $1\n";
 198                 return;
 199         }
 200         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 201         local $SIG{__WARN__} = sub {
 202                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 203                 $warn_cb->($pfx, "path: $path\n", @_);
 204         };
 205         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 206                 return _remove_spam($self, $path);
 207         }
 208         foreach my $ibx (@$inboxes) {
 209                 my $eml = eml_from_path($path) or next;
 210                 import_eml($self, $ibx, $eml);
 211         }
 212 }
 213
 214 sub quit_done ($) {
 215         my ($self) = @_;
 216         return unless $self->{quit};
 217
 218         # don't have reliable wakeups, keep signalling
 219         my $done = 1;
 220         for (qw(idle_pids poll_pids)) {
 221                 my $pids = $self->{$_} or next;
 222                 for (keys %$pids) {
 223                         $done = undef if kill('QUIT', $_);
 224                 }
 225         }
 226         $done;
 227 }
 228
 229 sub quit {
 230         my ($self) = @_;
 231         $self->{quit} = 1;
 232         %{$self->{opendirs}} = ();
 233         _done_for_now($self);
 234         quit_done($self);
 235         if (my $idle_mic = $self->{idle_mic}) {
 236                 eval { $idle_mic->done };
 237                 if ($@) {
 238                         warn "IDLE DONE error: $@\n";
 239                         eval { $idle_mic->disconnect };
 240                         warn "IDLE LOGOUT error: $@\n" if $@;
 241                 }
 242         }
 243 }
 244
 245 sub watch_fs_init ($) {
 246         my ($self) = @_;
 247         my $done = sub {
 248                 delete $self->{done_timer};
 249                 _done_for_now($self);
 250         };
 251         my $cb = sub {
 252                 _try_path($self, $_[0]->fullname);
 253                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 254         };
 255         require PublicInbox::DirIdle;
 256         # inotify_create + EPOLL_CTL_ADD
 257         PublicInbox::DirIdle->new([keys %{$self->{mdmap}}], $cb);
 258 }
 259
 260 # avoid exposing deprecated "snews" to users.
 261 my %SCHEME_MAP = ('snews' => 'nntps');
 262
 263 sub uri_scheme ($) {
 264         my ($uri) = @_;
 265         my $scheme = $uri->scheme;
 266         $SCHEME_MAP{$scheme} // $scheme;
 267 }
 268
 269 # returns the git config section name, e.g [imap "imaps://user@example.com"]
 270 # without the mailbox, so we can share connections between different inboxes
 271 sub uri_section ($) {
 272         my ($uri) = @_;
 273         uri_scheme($uri) . '://' . $uri->authority;
 274 }
 275
 276 sub cfg_intvl ($$$) {
 277         my ($cfg, $key, $url) = @_;
 278         my $v = $cfg->urlmatch($key, $url) // return;
 279         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 280         if (ref($v) eq 'ARRAY') {
 281                 $v = join(', ', @$v);
 282                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 283         } else {
 284                 warn "W: $key=$v is not a numeric value in seconds\n";
 285         }
 286 }
 287
 288 sub cfg_bool ($$$) {
 289         my ($cfg, $key, $url) = @_;
 290         my $orig = $cfg->urlmatch($key, $url) // return;
 291         my $bool = $cfg->git_bool($orig);
 292         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 293         $bool;
 294 }
 295
 296 # flesh out common IMAP-specific data structures
 297 sub imap_common_init ($) {
 298         my ($self) = @_;
 299         my $cfg = $self->{config};
 300         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 301         for my $url (sort keys %{$self->{imap}}) {
 302                 my $uri = PublicInbox::URIimap->new($url);
 303                 my $sec = uri_section($uri);
 304                 for my $k (qw(Starttls Debug Compress)) {
 305                         my $bool = cfg_bool($cfg, "imap.$k", $url) // next;
 306                         $mic_args->{$sec}->{$k} = $bool;
 307                 }
 308                 my $to = cfg_intvl($cfg, 'imap.timeout', $url);
 309                 $mic_args->{$sec}->{Timeout} = $to if $to;
 310                 for my $k (qw(pollInterval idleInterval)) {
 311                         $to = cfg_intvl($cfg, "imap.$k", $url) // next;
 312                         $self->{imap_opt}->{$sec}->{$k} = $to;
 313                 }
 314                 my $k = 'imap.fetchBatchSize';
 315                 my $bs = $cfg->urlmatch($k, $url) // next;
 316                 if ($bs =~ /\A([0-9]+)\z/) {
 317                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 318                 } else {
 319                         warn "$k=$bs is not an integer\n";
 320                 }
 321         }
 322         $mic_args;
 323 }
 324
 325 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
 326
 327 sub mic_for ($$$) { # mic = Mail::IMAPClient
 328         my ($self, $url, $mic_args) = @_;
 329         my $uri = PublicInbox::URIimap->new($url);
 330         require PublicInbox::GitCredential;
 331         my $cred = bless {
 332                 url => $url,
 333                 protocol => $uri->scheme,
 334                 host => $uri->host,
 335                 username => $uri->user,
 336                 password => $uri->password,
 337         }, 'PublicInbox::GitCredential';
 338         my $common = $mic_args->{uri_section($uri)} // {};
 339         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 340         my $host = $cred->{host};
 341         $host = '127.0.0.1' if $host eq '0';
 342         my $mic_arg = {
 343                 Port => $uri->port,
 344                 Server => $host,
 345                 Ssl => $uri->scheme eq 'imaps',
 346                 Keepalive => 1, # SO_KEEPALIVE
 347                 %$common, # may set Starttls, Compress, Debug ....
 348         };
 349         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
 350                 die "E: <$url> new: $@\n";
 351
 352         # default to using STARTTLS if it's available, but allow
 353         # it to be disabled since I usually connect to localhost
 354         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 355                         $mic->has_capability('STARTTLS') &&
 356                         $mic->can('starttls')) {
 357                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
 358         }
 359
 360         # do we even need credentials?
 361         if (!defined($cred->{username}) &&
 362                         $mic->has_capability('AUTH=ANONYMOUS')) {
 363                 $cred = undef;
 364         }
 365         if ($cred) {
 366                 $cred->check_netrc unless defined $cred->{password};
 367                 $cred->fill; # may prompt user here
 368                 $mic->User($mic_arg->{User} = $cred->{username});
 369                 $mic->Password($mic_arg->{Password} = $cred->{password});
 370         } else { # AUTH=ANONYMOUS
 371                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 372                 $mic->Authcallback($mic_arg->{Authcallback} = \&auth_anon_cb);
 373         }
 374         if ($mic->login && $mic->IsAuthenticated) {
 375                 # success! keep IMAPClient->new arg in case we get disconnected
 376                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
 377         } else {
 378                 warn "E: <$url> LOGIN: $@\n";
 379                 $mic = undef;
 380         }
 381         $cred->run($mic ? 'approve' : 'reject') if $cred;
 382         $mic;
 383 }
 384
 385 sub imap_import_msg ($$$$) {
 386         my ($self, $url, $uid, $raw) = @_;
 387         # our target audience expects LF-only, save storage
 388         $$raw =~ s/\r\n/\n/sg;
 389
 390         my $inboxes = $self->{imap}->{$url};
 391         if (ref($inboxes)) {
 392                 for my $ibx (@$inboxes) {
 393                         my $eml = PublicInbox::Eml->new($$raw);
 394                         my $x = import_eml($self, $ibx, $eml);
 395                 }
 396         } elsif ($inboxes eq 'watchspam') {
 397                 local $SIG{__WARN__} = warn_ignore_cb();
 398                 my $eml = PublicInbox::Eml->new($raw);
 399                 my $arg = [ $self, $eml, "$url UID:$uid" ];
 400                 $self->{config}->each_inbox(\&remove_eml_i, $arg);
 401         } else {
 402                 die "BUG: destination unknown $inboxes";
 403         }
 404 }
 405
 406 sub imap_fetch_all ($$$) {
 407         my ($self, $mic, $url) = @_;
 408         my $uri = PublicInbox::URIimap->new($url);
 409         my $sec = uri_section($uri);
 410         my $mbx = $uri->mailbox;
 411         $mic->Clear(1); # trim results history
 412         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 413         my ($r_uidval, $r_uidnext);
 414         for ($mic->Results) {
 415                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 416                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 417                 last if $r_uidval && $r_uidnext;
 418         }
 419         $r_uidval //= $mic->uidvalidity($mbx) //
 420                 return "E: $url cannot get UIDVALIDITY";
 421         $r_uidnext //= $mic->uidnext($mbx) //
 422                 return "E: $url cannot get UIDNEXT";
 423         my $itrk = PublicInbox::IMAPTracker->new($url);
 424         my ($l_uidval, $l_uid) = $itrk->get_last;
 425         $l_uidval //= $r_uidval; # first time
 426         $l_uid //= 1;
 427         if ($l_uidval != $r_uidval) {
 428                 return "E: $url UIDVALIDITY mismatch\n".
 429                         "E: local=$l_uidval != remote=$r_uidval";
 430         }
 431         my $r_uid = $r_uidnext - 1;
 432         if ($l_uid != 1 && $l_uid > $r_uid) {
 433                 return "E: $url local UID exceeds remote ($l_uid > $r_uid)\n".
 434                         "E: $url strangely, UIDVALIDLITY matches ($l_uidval)\n";
 435         }
 436         return if $l_uid >= $r_uid; # nothing to do
 437
 438         warn "I: $url fetching UID $l_uid:$r_uid\n";
 439         $mic->Uid(1); # the default, we hope
 440         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 441         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 442
 443         # TODO: FLAGS may be useful for personal use
 444         my $key = $req;
 445         $key =~ s/\.PEEK//;
 446         my ($uids, $batch);
 447         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 448         local $SIG{__WARN__} = sub {
 449                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 450                 $batch //= '?';
 451                 $warn_cb->("$pfx$url UID:$batch\n", @_);
 452         };
 453         my $err;
 454         do {
 455                 # I wish "UID FETCH $START:*" could work, but:
 456                 # 1) servers do not need to return results in any order
 457                 # 2) Mail::IMAPClient doesn't offer a streaming API
 458                 $uids = $mic->search("UID $l_uid:*") or
 459                         return "E: $url UID SEARCH $l_uid:* error: $!";
 460                 return if scalar(@$uids) == 0;
 461
 462                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 463                 # responses, so sort it ourselves.  Order matters so
 464                 # IMAPTracker can store the newest UID.
 465                 @$uids = sort { $a <=> $b } @$uids;
 466
 467                 # Did we actually get new messages?
 468                 return if $uids->[0] < $l_uid;
 469
 470                 $l_uid = $uids->[-1] + 1; # for next search
 471                 my $last_uid;
 472
 473                 while (scalar @$uids) {
 474                         my @batch = splice(@$uids, 0, $bs);
 475                         $batch = join(',', @batch);
 476                         local $0 = "UID:$batch $mbx $sec";
 477                         my $r = $mic->fetch_hash($batch, $req);
 478                         unless ($r) { # network error?
 479                                 $err = "E: $url UID FETCH $batch error: $!";
 480                                 last;
 481                         }
 482                         for my $uid (@batch) {
 483                                 # messages get deleted, so holes appear
 484                                 my $per_uid = delete $r->{$uid} // next;
 485                                 my $raw = delete($per_uid->{$key}) // next;
 486                                 imap_import_msg($self, $url, $uid, \$raw);
 487                                 $last_uid = $uid;
 488                                 last if $self->{quit};
 489                         }
 490                         last if $self->{quit};
 491                 }
 492                 _done_for_now($self);
 493                 $itrk->update_last($r_uidval, $last_uid) if defined $last_uid;
 494         } until ($err || $self->{quit});
 495         $err;
 496 }
 497
 498 sub imap_idle_once ($$$$) {
 499         my ($self, $mic, $intvl, $url) = @_;
 500         my $i = $intvl //= (29 * 60);
 501         my $end = now() + $intvl;
 502         warn "I: $url idling for ${intvl}s\n";
 503         local $0 = "IDLE $0";
 504         unless ($mic->idle) {
 505                 return if $self->{quit};
 506                 return "E: IDLE failed on $url: $!";
 507         }
 508         $self->{idle_mic} = $mic; # for ->quit
 509         my @res;
 510         until ($self->{quit} || !$mic->IsConnected ||
 511                         grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 512                 @res = $mic->idle_data($i);
 513                 $i = $end - now();
 514         }
 515         delete $self->{idle_mic};
 516         unless ($self->{quit}) {
 517                 $mic->IsConnected or return "E: IDLE disconnected on $url";
 518                 $mic->done or return "E: IDLE DONE failed on $url: $!";
 519         }
 520         undef;
 521 }
 522
 523 # idles on a single URI
 524 sub watch_imap_idle_1 ($$$) {
 525         my ($self, $url, $intvl) = @_;
 526         my $uri = PublicInbox::URIimap->new($url);
 527         my $sec = uri_section($uri);
 528         my $mic_arg = $self->{mic_arg}->{$sec} or
 529                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 530         my $mic;
 531         local $0 = $uri->mailbox." $sec";
 532         until ($self->{quit}) {
 533                 $mic //= PublicInbox::IMAPClient->new(%$mic_arg);
 534                 my $err;
 535                 if ($mic && $mic->IsConnected) {
 536                         $err = imap_fetch_all($self, $mic, $url);
 537                         $err //= imap_idle_once($self, $mic, $intvl, $url);
 538                 } else {
 539                         $err = "not connected: $!";
 540                 }
 541                 if ($err && !$self->{quit}) {
 542                         warn $err, "\n";
 543                         $mic = undef;
 544                         sleep 60 unless $self->{quit};
 545                 }
 546         }
 547 }
 548
 549 sub watch_atfork_child ($) {
 550         my ($self) = @_;
 551         delete $self->{idle_pids};
 552         delete $self->{poll_pids};
 553         delete $self->{opendirs};
 554         PublicInbox::DS->Reset;
 555         %SIG = (%SIG, %{$self->{sig}}, CHLD => 'DEFAULT');
 556         PublicInbox::Sigfd::sig_setmask($self->{oldset});
 557 }
 558
 559 sub watch_atfork_parent ($) {
 560         my ($self) = @_;
 561         _done_for_now($self);
 562 }
 563
 564 sub imap_idle_requeue ($) { # DS::add_timer callback
 565         my ($self, $url_intvl) = @{$_[0]};
 566         return if $self->{quit};
 567         push @{$self->{idle_todo}}, $url_intvl;
 568         event_step($self);
 569 }
 570
 571 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 572         my ($self, $pid) = @_;
 573         my $url_intvl = delete $self->{idle_pids}->{$pid} or
 574                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 575
 576         my ($url, $intvl) = @$url_intvl;
 577         return if $self->{quit};
 578         warn "W: PID=$pid on $url died: \$?=$?\n" if $?;
 579         PublicInbox::DS::add_timer(60,
 580                                 \&imap_idle_requeue, [ $self, $url_intvl ]);
 581 }
 582
 583 sub imap_idle_fork ($$) {
 584         my ($self, $url_intvl) = @_;
 585         my ($url, $intvl) = @$url_intvl;
 586         defined(my $pid = fork) or die "fork: $!";
 587         if ($pid == 0) {
 588                 watch_atfork_child($self);
 589                 watch_imap_idle_1($self, $url, $intvl);
 590                 _exit(0);
 591         }
 592         $self->{idle_pids}->{$pid} = $url_intvl;
 593         PublicInbox::DS::dwaitpid($pid, \&imap_idle_reap, $self);
 594 }
 595
 596 sub event_step {
 597         my ($self) = @_;
 598         return if $self->{quit};
 599         my $idle_todo = $self->{idle_todo};
 600         if ($idle_todo && @$idle_todo) {
 601                 watch_atfork_parent($self);
 602                 while (my $url_intvl = shift(@$idle_todo)) {
 603                         imap_idle_fork($self, $url_intvl);
 604                 }
 605         }
 606         goto(&fs_scan_step) if $self->{mdre};
 607 }
 608
 609 sub watch_imap_fetch_all ($$) {
 610         my ($self, $urls) = @_;
 611         for my $url (@$urls) {
 612                 my $uri = PublicInbox::URIimap->new($url);
 613                 my $sec = uri_section($uri);
 614                 my $mic_arg = $self->{mic_arg}->{$sec} or
 615                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 616                 my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or next;
 617                 my $err = imap_fetch_all($self, $mic, $url);
 618                 last if $self->{quit};
 619                 warn $err, "\n" if $err;
 620         }
 621 }
 622
 623 sub watch_nntp_fetch_all ($$) {
 624         my ($self, $urls) = @_;
 625         for my $url (@$urls) {
 626                 my $uri = uri_new($url);
 627                 my $sec = uri_section($uri);
 628                 my $nn_arg = $self->{nn_arg}->{$sec} or
 629                         die "BUG: no Net::NNTP->new arg for $sec";
 630                 my $nntp_opt = $self->{nntp_opt}->{$sec};
 631                 my $nn = nn_new($nn_arg, $nntp_opt, $url);
 632                 unless ($nn) {
 633                         warn "E: $url: \$!=$!\n";
 634                         next;
 635                 }
 636                 last if $self->{quit};
 637                 if (my $postconn = $nntp_opt->{-postconn}) {
 638                         for my $m_arg (@$postconn) {
 639                                 my ($method, @args) = @$m_arg;
 640                                 $nn->$method(@args) and next;
 641                                 warn "E: <$url> $method failed\n";
 642                                 $nn = undef;
 643                                 last;
 644                         }
 645                 }
 646                 last if $self->{quit};
 647                 if ($nn) {
 648                         my $err = nntp_fetch_all($self, $nn, $url);
 649                         warn $err, "\n" if $err;
 650                 }
 651         }
 652 }
 653
 654 sub poll_fetch_fork ($) { # DS::add_timer callback
 655         my ($self, $intvl, $urls) = @{$_[0]};
 656         return if $self->{quit};
 657         watch_atfork_parent($self);
 658         defined(my $pid = fork) or die "fork: $!";
 659         if ($pid == 0) {
 660                 watch_atfork_child($self);
 661                 if ($urls->[0] =~ m!\Aimaps?://!i) {
 662                         watch_imap_fetch_all($self, $urls);
 663                 } else {
 664                         watch_nntp_fetch_all($self, $urls);
 665                 }
 666                 _exit(0);
 667         }
 668         $self->{poll_pids}->{$pid} = [ $intvl, $urls ];
 669         PublicInbox::DS::dwaitpid($pid, \&poll_fetch_reap, $self);
 670 }
 671
 672 sub poll_fetch_reap { # PublicInbox::DS::dwaitpid callback
 673         my ($self, $pid) = @_;
 674         my $intvl_urls = delete $self->{poll_pids}->{$pid} or
 675                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 676         return if $self->{quit};
 677         my ($intvl, $urls) = @$intvl_urls;
 678         if ($?) {
 679                 warn "W: PID=$pid died: \$?=$?\n", map { "$_\n" } @$urls;
 680         }
 681         warn("I: will check $_ in ${intvl}s\n") for @$urls;
 682         PublicInbox::DS::add_timer($intvl, \&poll_fetch_fork,
 683                                         [$self, $intvl, $urls]);
 684 }
 685
 686 sub watch_imap_init ($$) {
 687         my ($self, $poll) = @_;
 688         eval { require PublicInbox::IMAPClient } or
 689                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 690         eval { require PublicInbox::IMAPTracker } or
 691                 die "DBD::SQLite is required for IMAP\n:$@\n";
 692
 693         my $mic_args = imap_common_init($self); # read args from config
 694
 695         # make sure we can connect and cache the credentials in memory
 696         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 697         my $mics = {}; # schema://authority => IMAPClient obj
 698         for my $url (sort keys %{$self->{imap}}) {
 699                 my $uri = PublicInbox::URIimap->new($url);
 700                 $mics->{uri_section($uri)} //= mic_for($self, $url, $mic_args);
 701         }
 702
 703         my $idle = []; # [ [ url1, intvl1 ], [url2, intvl2] ]
 704         for my $url (keys %{$self->{imap}}) {
 705                 my $uri = PublicInbox::URIimap->new($url);
 706                 my $sec = uri_section($uri);
 707                 my $mic = $mics->{$sec};
 708                 my $intvl = $self->{imap_opt}->{$sec}->{pollInterval};
 709                 if ($mic->has_capability('IDLE') && !$intvl) {
 710                         $intvl = $self->{imap_opt}->{$sec}->{idleInterval};
 711                         push @$idle, [ $url, $intvl // () ];
 712                 } else {
 713                         push @{$poll->{$intvl || 120}}, $url;
 714                 }
 715         }
 716         if (scalar @$idle) {
 717                 $self->{idle_todo} = $idle;
 718                 PublicInbox::DS::requeue($self); # ->event_step to fork
 719         }
 720 }
 721
 722 # flesh out common NNTP-specific data structures
 723 sub nntp_common_init ($) {
 724         my ($self) = @_;
 725         my $cfg = $self->{config};
 726         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 727         for my $url (sort keys %{$self->{nntp}}) {
 728                 my $sec = uri_section(uri_new($url));
 729
 730                 # Debug and Timeout are passed to Net::NNTP->new
 731                 my $v = cfg_bool($cfg, 'nntp.Debug', $url);
 732                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 733                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $url);
 734                 $nn_args->{$sec}->{Timeout} = $to if $to;
 735
 736                 # Net::NNTP post-connect commands
 737                 for my $k (qw(starttls compress)) {
 738                         $v = cfg_bool($cfg, "nntp.$k", $url) // next;
 739                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 740                 }
 741
 742                 # internal option
 743                 for my $k (qw(pollInterval)) {
 744                         $to = cfg_intvl($cfg, "nntp.$k", $url) // next;
 745                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 746                 }
 747         }
 748         $nn_args;
 749 }
 750
 751 # Net::NNTP doesn't support CAPABILITIES, yet
 752 sub try_starttls ($) {
 753         my ($host) = @_;
 754         return if $host =~ /\.onion\z/s;
 755         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 756         return if $host eq '::1';
 757         1;
 758 }
 759
 760 sub nn_new ($$$) {
 761         my ($nn_arg, $nntp_opt, $url) = @_;
 762         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$url> new: $!\n";
 763
 764         # default to using STARTTLS if it's available, but allow
 765         # it to be disabled for localhost/VPN users
 766         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 767                 if (!defined($nntp_opt->{starttls}) &&
 768                                 try_starttls($nn_arg->{Host})) {
 769                         # soft fail by default
 770                         $nn->starttls or warn <<"";
 771 W: <$url> STARTTLS tried and failed (not requested)
 772
 773                 } elsif ($nntp_opt->{starttls}) {
 774                         # hard fail if explicitly configured
 775                         $nn->starttls or die <<"";
 776 E: <$url> STARTTLS requested and failed
 777
 778                 }
 779         } elsif ($nntp_opt->{starttls}) {
 780                 $nn->can('starttls') or
 781                         die "E: <$url> Net::NNTP too old for STARTTLS\n";
 782                 $nn->starttls or die <<"";
 783 E: <$url> STARTTLS requested and failed
 784
 785         }
 786         $nn;
 787 }
 788
 789 sub nn_for ($$$) { # nn = Net::NNTP
 790         my ($self, $url, $nn_args) = @_;
 791         my $uri = uri_new($url);
 792         my $sec = uri_section($uri);
 793         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 794         my $host = $uri->host;
 795         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 796         $host = '127.0.0.1' if $host eq '0';
 797         my $cred;
 798         my ($u, $p);
 799         if (defined(my $ui = $uri->userinfo)) {
 800                 require PublicInbox::GitCredential;
 801                 $cred = bless {
 802                         url => $sec,
 803                         protocol => uri_scheme($uri),
 804                         host => $host,
 805                 }, 'PublicInbox::GitCredential';
 806                 ($u, $p) = split(/:/, $ui, 2);
 807                 ($cred->{username}, $cred->{password}) = ($u, $p);
 808                 $cred->check_netrc unless defined $p;
 809         }
 810         my $common = $nn_args->{$sec} // {};
 811         my $nn_arg = {
 812                 Port => $uri->port,
 813                 Host => $host,
 814                 SSL => $uri->secure, # snews == nntps
 815                 %$common, # may Debug ....
 816         };
 817         my $nn = nn_new($nn_arg, $nntp_opt, $url);
 818
 819         if ($cred) {
 820                 $cred->fill; # may prompt user here
 821                 if ($nn->authinfo($u, $p)) {
 822                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 823                 } else {
 824                         warn "E: <$url> AUTHINFO $u XXXX failed\n";
 825                         $nn = undef;
 826                 }
 827         }
 828
 829         if ($nntp_opt->{compress}) {
 830                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 831                 if ($nn->can('compress')) {
 832                         if ($nn->compress) {
 833                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 834                         } else {
 835                                 warn "W: <$url> COMPRESS failed\n";
 836                         }
 837                 } else {
 838                         delete $nntp_opt->{compress};
 839                         warn <<"";
 840 W: <$url> COMPRESS not supported by Net::NNTP
 841 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 842
 843                 }
 844         }
 845
 846         $self->{nn_arg}->{$sec} = $nn_arg;
 847         $cred->run($nn ? 'approve' : 'reject') if $cred;
 848         $nn;
 849 }
 850
 851 sub nntp_fetch_all ($$$) {
 852         my ($self, $nn, $url) = @_;
 853         my $uri = uri_new($url);
 854         my ($group, $num_a, $num_b) = $uri->group;
 855         my $sec = uri_section($uri);
 856         my ($nr, $beg, $end) = $nn->group($group);
 857         unless (defined($nr)) {
 858                 chomp(my $msg = $nn->message);
 859                 return "E: GROUP $group <$sec> $msg";
 860         }
 861
 862         # IMAPTracker is also used for tracking NNTP, UID == article number
 863         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 864         # expensive.  So we assume newsgroups don't change:
 865         my $itrk = PublicInbox::IMAPTracker->new($url);
 866         my (undef, $l_art) = $itrk->get_last;
 867         $l_art //= $beg; # initial import
 868
 869         # allow users to specify articles to refetch
 870         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 871         # nntp://example.com/inbox.foo/$num_a-$num_b
 872         $l_art = $num_a if defined($num_a) && $num_a < $l_art;
 873         $end = $num_b if defined($num_b) && $num_b < $end;
 874
 875         return if $l_art >= $end; # nothing to do
 876         $beg = $l_art + 1;
 877
 878         warn "I: $url fetching ARTICLE $beg..$end\n";
 879         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 880         my ($err, $art);
 881         local $SIG{__WARN__} = sub {
 882                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 883                 $warn_cb->("$pfx$url ", $art ? ("ARTICLE $art") : (), "\n", @_);
 884         };
 885         my $inboxes = $self->{nntp}->{$url};
 886         my $last_art;
 887         for ($beg..$end) {
 888                 last if $self->{quit};
 889                 $art = $_;
 890                 my $raw = $nn->article($art);
 891                 unless (defined($raw)) {
 892                         my $msg = $nn->message;
 893                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 894                                 $err = "E: $msg";
 895                                 last;
 896                         } else { # probably just a deleted message (spam)
 897                                 warn "W: $msg";
 898                                 next;
 899                         }
 900                 }
 901                 s/\r\n/\n/ for @$raw;
 902                 $raw = join('', @$raw);
 903                 if (ref($inboxes)) {
 904                         for my $ibx (@$inboxes) {
 905                                 my $eml = PublicInbox::Eml->new($raw);
 906                                 import_eml($self, $ibx, $eml);
 907                         }
 908                 } elsif ($inboxes eq 'watchspam') {
 909                         my $eml = PublicInbox::Eml->new(\$raw);
 910                         my $arg = [ $self, $eml, "$url ARTICLE $art" ];
 911                         $self->{config}->each_inbox(\&remove_eml_i, $arg);
 912                 } else {
 913                         die "BUG: destination unknown $inboxes";
 914                 }
 915                 $last_art = $art;
 916         }
 917         $itrk->update_last(0, $last_art) if defined $last_art;
 918         _done_for_now($self);
 919         $err;
 920 }
 921
 922 sub watch_nntp_init ($$) {
 923         my ($self, $poll) = @_;
 924         eval { require Net::NNTP } or
 925                 die "Net::NNTP is required for NNTP:\n$@\n";
 926         eval { require PublicInbox::IMAPTracker } or
 927                 die "DBD::SQLite is required for NNTP\n:$@\n";
 928
 929         my $nn_args = nntp_common_init($self); # read args from config
 930
 931         # make sure we can connect and cache the credentials in memory
 932         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 933         for my $url (sort keys %{$self->{nntp}}) {
 934                 nn_for($self, $url, $nn_args);
 935         }
 936         for my $url (keys %{$self->{nntp}}) {
 937                 my $uri = uri_new($url);
 938                 my $sec = uri_section($uri);
 939                 my $intvl = $self->{nntp_opt}->{$sec}->{pollInterval};
 940                 push @{$poll->{$intvl || 120}}, $url;
 941         }
 942 }
 943
 944 sub watch {
 945         my ($self, $sig, $oldset) = @_;
 946         $self->{oldset} = $oldset;
 947         $self->{sig} = $sig;
 948         my $poll = {}; # intvl_seconds => [ url1, url2 ]
 949         watch_imap_init($self, $poll) if $self->{imap};
 950         watch_nntp_init($self, $poll) if $self->{nntp};
 951         while (my ($intvl, $urls) = each %$poll) {
 952                 # poll all URLs for a given interval sequentially
 953                 PublicInbox::DS::add_timer(0, \&poll_fetch_fork,
 954                                                 [$self, $intvl, $urls]);
 955         }
 956         watch_fs_init($self) if $self->{mdre};
 957         PublicInbox::DS->SetPostLoopCallback(sub { !$self->quit_done });
 958         PublicInbox::DS->EventLoop;
 959         _done_for_now($self);
 960 }
 961
 962 sub trigger_scan {
 963         my ($self, $op) = @_;
 964         push @{$self->{ops}}, $op;
 965         PublicInbox::DS::requeue($self);
 966 }
 967
 968 sub fs_scan_step {
 969         my ($self) = @_;
 970         return if $self->{quit};
 971         my $op = shift @{$self->{ops}};
 972         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 973
 974         # continue existing scan
 975         my $max = 10;
 976         my $opendirs = $self->{opendirs};
 977         my @dirnames = keys %$opendirs;
 978         foreach my $dir (@dirnames) {
 979                 my $dh = delete $opendirs->{$dir};
 980                 my $n = $max;
 981                 while (my $fn = readdir($dh)) {
 982                         _try_path($self, "$dir/$fn");
 983                         last if --$n < 0;
 984                 }
 985                 $opendirs->{$dir} = $dh if $n < 0;
 986         }
 987         if ($op && $op eq 'full') {
 988                 foreach my $dir (keys %{$self->{mdmap}}) {
 989                         next if $opendirs->{$dir}; # already in progress
 990                         my $ok = opendir(my $dh, $dir);
 991                         unless ($ok) {
 992                                 warn "failed to open $dir: $!\n";
 993                                 next;
 994                         }
 995                         my $n = $max;
 996                         while (my $fn = readdir($dh)) {
 997                                 _try_path($self, "$dir/$fn");
 998                                 last if --$n < 0;
 999                         }
1000                         $opendirs->{$dir} = $dh if $n < 0;
1001                 }
1002         }
1003         _done_for_now($self);
1004         # do we have more work to do?
1005         PublicInbox::DS::requeue($self) if keys %$opendirs;
1006 }
1007
1008 sub scan {
1009         my ($self, $op) = @_;
1010         push @{$self->{ops}}, $op;
1011         goto &fs_scan_step;
1012 }
1013
1014 sub _importer_for {
1015         my ($self, $ibx) = @_;
1016         my $importers = $self->{importers};
1017         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
1018         if (scalar(keys(%$importers)) > 2) {
1019                 delete $importers->{"$ibx"};
1020                 _done_for_now($self);
1021         }
1022
1023         $importers->{"$ibx"} = $im;
1024 }
1025
1026 # XXX consider sharing with V2Writable, this only requires read-only access
1027 sub content_exists ($$) {
1028         my ($ibx, $eml) = @_;
1029         my $over = $ibx->over or return;
1030         my $mids = mids($eml);
1031         my $chash = content_hash($eml);
1032         my ($id, $prev);
1033         for my $mid (@$mids) {
1034                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1035                         my $cmp = $ibx->smsg_eml($smsg) or return;
1036                         return 1 if $chash eq content_hash($cmp);
1037                 }
1038         }
1039         undef;
1040 }
1041
1042 sub _spamcheck_cb {
1043         my ($sc) = @_;
1044         sub {
1045                 my ($mime, $ibx) = @_;
1046                 return if content_exists($ibx, $mime);
1047                 my $tmp = '';
1048                 if ($sc->spamcheck($mime, \$tmp)) {
1049                         return PublicInbox::Eml->new(\$tmp);
1050                 }
1051                 warn $mime->header('Message-ID')." failed spam check\n";
1052                 undef;
1053         }
1054 }
1055
1056 sub is_maildir {
1057         $_[0] =~ s!\Amaildir:!! or return;
1058         $_[0] =~ tr!/!/!s;
1059         $_[0] =~ s!/\z!!;
1060         $_[0];
1061 }
1062
1063 sub is_watchspam {
1064         my ($cur, $ws, $ibx) = @_;
1065         if ($ws && !ref($ws) && $ws eq 'watchspam') {
1066                 warn <<EOF;
1067 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
1068 EOF
1069                 return 1;
1070         }
1071         undef;
1072 }
1073
1074 sub uri_new {
1075         my ($url) = @_;
1076
1077         # URI::snews exists, URI::nntps does not, so use URI::snews
1078         $url =~ s!\Anntps://!snews://!i;
1079         URI->new($url);
1080 }
1081
1082 sub imap_url {
1083         my ($url) = @_;
1084         require PublicInbox::URIimap;
1085         my $uri = PublicInbox::URIimap->new($url);
1086         $uri ? $uri->canonical->as_string : undef;
1087 }
1088
1089 my %IS_NNTP = (news => 1, snews => 1, nntp => 1);
1090 sub nntp_url {
1091         my ($url) = @_;
1092         require URI;
1093         my $uri = uri_new($url);
1094         return unless $uri && $IS_NNTP{$uri->scheme} && $uri->group;
1095         $url = $uri->canonical->as_string;
1096         # nntps is IANA registered, snews is deprecated
1097         $url =~ s!\Asnews://!nntps://!;
1098         $url;
1099 }
1100
1101 1;