lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MIME;
  10 use Email::MIME::ContentType;
  11 $Email::MIME::ContentType::STRICT_PARAMS = 0; # user input is imperfect
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MDA;
  15 use PublicInbox::Spawn qw(spawn);
  16
  17 sub new {
  18         my ($class, $config) = @_;
  19         my (%mdmap, @mdir, $spamc);
  20
  21         # "publicinboxwatch" is the documented namespace
  22         # "publicinboxlearn" is legacy but may be supported
  23         # indefinitely...
  24         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  25                 my $k = "$pfx.watchspam";
  26                 if (my $spamdir = $config->{$k}) {
  27                         if ($spamdir =~ s/\Amaildir://) {
  28                                 $spamdir =~ s!/+\z!!;
  29                                 # skip "new", no MUA has seen it, yet.
  30                                 my $cur = "$spamdir/cur";
  31                                 push @mdir, $cur;
  32                                 $mdmap{$cur} = 'watchspam';
  33                         } else {
  34                                 warn "unsupported $k=$spamdir\n";
  35                         }
  36                 }
  37         }
  38
  39         my $k = 'publicinboxwatch.spamcheck';
  40         my $spamcheck = $config->{$k};
  41         if ($spamcheck) {
  42                 if ($spamcheck eq 'spamc') {
  43                         $spamcheck = 'PublicInbox::Spamcheck::Spamc';
  44                 }
  45                 if ($spamcheck =~ /::/) {
  46                         eval "require $spamcheck";
  47                         $spamcheck = _spamcheck_cb($spamcheck->new);
  48                 } else {
  49                         warn "unsupported $k=$spamcheck\n";
  50                         $spamcheck = undef;
  51                 }
  52         }
  53         foreach $k (keys %$config) {
  54                 $k =~ /\Apublicinbox\.([^\.]+)\.watch\z/ or next;
  55                 my $name = $1;
  56                 my $watch = $config->{$k};
  57                 if ($watch =~ s/\Amaildir://) {
  58                         $watch =~ s!/+\z!!;
  59                         my $inbox = $config->lookup_name($name);
  60                         if (my $wm = $inbox->{watchheader}) {
  61                                 my ($k, $v) = split(/:/, $wm, 2);
  62                                 $inbox->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  63                         }
  64                         my $new = "$watch/new";
  65                         my $cur = "$watch/cur";
  66                         push @mdir, $new, $cur;
  67                         die "$new already in use\n" if $mdmap{$new};
  68                         die "$cur already in use\n" if $mdmap{$cur};
  69                         $mdmap{$new} = $mdmap{$cur} = $inbox;
  70                 } else {
  71                         warn "watch unsupported: $k=$watch\n";
  72                 }
  73         }
  74         return unless @mdir;
  75
  76         my $mdre = join('|', map { quotemeta($_) } @mdir);
  77         $mdre = qr!\A($mdre)/!;
  78         bless {
  79                 spamcheck => $spamcheck,
  80                 mdmap => \%mdmap,
  81                 mdir => \@mdir,
  82                 mdre => $mdre,
  83                 config => $config,
  84                 importers => {},
  85         }, $class;
  86 }
  87
  88 sub _done_for_now {
  89         $_->done foreach values %{$_[0]->{importers}};
  90 }
  91
  92 sub _try_fsn_paths {
  93         my ($self, $paths) = @_;
  94         _try_path($self, $_->{path}) foreach @$paths;
  95         _done_for_now($self);
  96 }
  97
  98 sub _remove_spam {
  99         my ($self, $path) = @_;
 100         # path must be marked as (S)een
 101         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 102         my $mime = _path_to_mime($path) or return;
 103         _force_mid($mime);
 104         $self->{config}->each_inbox(sub {
 105                 my ($ibx) = @_;
 106                 eval {
 107                         my $im = _importer_for($self, $ibx);
 108                         $im->remove($mime);
 109                         if (my $scrub = _scrubber_for($ibx)) {
 110                                 my $scrubbed = $scrub->scrub($mime) or return;
 111                                 $im->remove($scrubbed);
 112                         }
 113                 };
 114                 warn "error removing spam at $path from $ibx->{name}\n" if $@;
 115         })
 116 }
 117
 118 # used to hash the relevant portions of a message when there are conflicts
 119 sub _hash_mime2 {
 120         my ($mime) = @_;
 121         require Digest::SHA;
 122         my $dig = Digest::SHA->new('SHA-1');
 123         $dig->add($mime->header_obj->header_raw('Subject'));
 124         $dig->add($mime->body_raw);
 125         $dig->hexdigest;
 126 }
 127
 128 sub _force_mid {
 129         my ($mime) = @_;
 130         # probably a bad idea, but we inject a Message-Id if
 131         # one is missing, here..
 132         my $mid = $mime->header_obj->header_raw('Message-Id');
 133         if (!defined $mid || $mid =~ /\A\s*\z/) {
 134                 $mid = '<' . _hash_mime2($mime) . '@generated>';
 135                 $mime->header_set('Message-Id', $mid);
 136         }
 137 }
 138
 139 sub _try_path {
 140         my ($self, $path) = @_;
 141         my @p = split(m!/+!, $path);
 142         return if $p[-1] !~ /\A[a-zA-Z0-9][\w:,=\.]+\z/;
 143         if ($p[-1] =~ /:2,([A-Z]+)\z/i) {
 144                 my $flags = $1;
 145                 return if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 146         }
 147         return unless -f $path;
 148         if ($path !~ $self->{mdre}) {
 149                 warn "unrecognized path: $path\n";
 150                 return;
 151         }
 152         my $inbox = $self->{mdmap}->{$1};
 153         unless ($inbox) {
 154                 warn "unmappable dir: $1\n";
 155                 return;
 156         }
 157         if (!ref($inbox) && $inbox eq 'watchspam') {
 158                 return _remove_spam($self, $path);
 159         }
 160         my $im = _importer_for($self, $inbox);
 161         my $mime = _path_to_mime($path) or return;
 162         $mime->header_set($_) foreach @PublicInbox::MDA::BAD_HEADERS;
 163         my $wm = $inbox->{-watchheader};
 164         if ($wm) {
 165                 my $v = $mime->header_obj->header_raw($wm->[0]);
 166                 return unless ($v && $v =~ $wm->[1]);
 167         }
 168         if (my $scrub = _scrubber_for($inbox)) {
 169                 $mime = $scrub->scrub($mime) or return;
 170         }
 171
 172         _force_mid($mime);
 173         $im->add($mime, $self->{spamcheck});
 174 }
 175
 176 sub watch {
 177         my ($self) = @_;
 178         my $cb = sub { _try_fsn_paths($self, \@_) };
 179         my $mdir = $self->{mdir};
 180
 181         # lazy load here, we may support watching via IMAP IDLE
 182         # in the future...
 183         require Filesys::Notify::Simple;
 184         my $watcher = Filesys::Notify::Simple->new($mdir);
 185         $watcher->wait($cb) while (1);
 186 }
 187
 188 sub scan {
 189         my ($self) = @_;
 190         my $mdir = $self->{mdir};
 191         foreach my $dir (@$mdir) {
 192                 my $ok = opendir(my $dh, $dir);
 193                 unless ($ok) {
 194                         warn "failed to open $dir: $!\n";
 195                         next;
 196                 }
 197                 while (my $fn = readdir($dh)) {
 198                         _try_path($self, "$dir/$fn");
 199                 }
 200                 closedir $dh;
 201         }
 202         _done_for_now($self);
 203 }
 204
 205 sub _path_to_mime {
 206         my ($path) = @_;
 207         if (open my $fh, '<', $path) {
 208                 local $/;
 209                 my $str = <$fh>;
 210                 $str or return;
 211                 return PublicInbox::MIME->new(\$str);
 212         } elsif ($!{ENOENT}) {
 213                 return;
 214         } else {
 215                 warn "failed to open $path: $!\n";
 216                 return;
 217         }
 218 }
 219
 220 sub _importer_for {
 221         my ($self, $inbox) = @_;
 222         my $im = $inbox->{-import} ||= eval {
 223                 my $git = $inbox->git;
 224                 my $name = $inbox->{name};
 225                 my $addr = $inbox->{-primary_address};
 226                 PublicInbox::Import->new($git, $name, $addr, $inbox);
 227         };
 228
 229         my $importers = $self->{importers};
 230         if (scalar(keys(%$importers)) > 2) {
 231                 delete $importers->{"$im"};
 232                 _done_for_now($self);
 233         }
 234
 235         $importers->{"$im"} = $im;
 236 }
 237
 238 sub _scrubber_for {
 239         my ($inbox) = @_;
 240         my $f = $inbox->{filter};
 241         if ($f && $f =~ /::/) {
 242                 my @args;
 243                 # basic line splitting, only
 244                 # Perhaps we can have proper quote splitting one day...
 245                 ($f, @args) = split(/\s+/, $f) if $f =~ /\s+/;
 246
 247                 eval "require $f";
 248                 if ($@) {
 249                         warn $@;
 250                 } else {
 251                         # e.g: PublicInbox::Filter::Vger->new(@args)
 252                         return $f->new(@args);
 253                 }
 254         }
 255         undef;
 256 }
 257
 258 sub _spamcheck_cb {
 259         my ($sc) = @_;
 260         sub {
 261                 my ($mime) = @_;
 262                 my $tmp = '';
 263                 if ($sc->spamcheck($mime, \$tmp)) {
 264                         return PublicInbox::MIME->new(\$tmp);
 265                 }
 266                 warn $mime->header('Message-ID')." failed spam check\n";
 267                 undef;
 268         }
 269 }
 270
 271 1;