lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MIME;
  10 use PublicInbox::Git;
  11 use PublicInbox::Import;
  12 use PublicInbox::MDA;
  13 use PublicInbox::Spawn qw(spawn);
  14 use PublicInbox::InboxWritable;
  15 use File::Temp qw//;
  16
  17 sub new {
  18         my ($class, $config) = @_;
  19         my (%mdmap, @mdir, $spamc, $spamdir);
  20
  21         # "publicinboxwatch" is the documented namespace
  22         # "publicinboxlearn" is legacy but may be supported
  23         # indefinitely...
  24         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  25                 my $k = "$pfx.watchspam";
  26                 if (my $dir = $config->{$k}) {
  27                         if ($dir =~ s/\Amaildir://) {
  28                                 $dir =~ s!/+\z!!;
  29                                 # skip "new", no MUA has seen it, yet.
  30                                 my $cur = "$dir/cur";
  31                                 $spamdir = $cur;
  32                                 push @mdir, $cur;
  33                                 $mdmap{$cur} = 'watchspam';
  34                         } else {
  35                                 warn "unsupported $k=$dir\n";
  36                         }
  37                 }
  38         }
  39
  40         my $k = 'publicinboxwatch.spamcheck';
  41         my $spamcheck = $config->{$k};
  42         if ($spamcheck) {
  43                 if ($spamcheck eq 'spamc') {
  44                         $spamcheck = 'PublicInbox::Spamcheck::Spamc';
  45                 }
  46                 if ($spamcheck =~ /::/) {
  47                         eval "require $spamcheck";
  48                         $spamcheck = _spamcheck_cb($spamcheck->new);
  49                 } else {
  50                         warn "unsupported $k=$spamcheck\n";
  51                         $spamcheck = undef;
  52                 }
  53         }
  54
  55         # need to make all inboxes writable for spam removal:
  56         $config->each_inbox(sub { PublicInbox::InboxWritable->new($_[0]) });
  57
  58         foreach $k (keys %$config) {
  59                 $k =~ /\Apublicinbox\.([^\.]+)\.watch\z/ or next;
  60                 my $name = $1;
  61                 my $watch = $config->{$k};
  62                 if ($watch =~ s/\Amaildir://) {
  63                         $watch =~ s!/+\z!!;
  64                         my $inbox = $config->lookup_name($name);
  65                         if (my $wm = $inbox->{watchheader}) {
  66                                 my ($k, $v) = split(/:/, $wm, 2);
  67                                 $inbox->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  68                         }
  69                         my $new = "$watch/new";
  70                         my $cur = "$watch/cur";
  71                         push @mdir, $new, $cur;
  72                         die "$new already in use\n" if $mdmap{$new};
  73                         die "$cur already in use\n" if $mdmap{$cur};
  74                         $mdmap{$new} = $mdmap{$cur} = $inbox;
  75                 } else {
  76                         warn "watch unsupported: $k=$watch\n";
  77                 }
  78         }
  79         return unless @mdir;
  80
  81         my $mdre = join('|', map { quotemeta($_) } @mdir);
  82         $mdre = qr!\A($mdre)/!;
  83         bless {
  84                 spamcheck => $spamcheck,
  85                 spamdir => $spamdir,
  86                 mdmap => \%mdmap,
  87                 mdir => \@mdir,
  88                 mdre => $mdre,
  89                 config => $config,
  90                 importers => {},
  91                 opendirs => {}, # dirname => dirhandle (in progress scans)
  92         }, $class;
  93 }
  94
  95 sub _done_for_now {
  96         my ($self) = @_;
  97         my $importers = $self->{importers};
  98         foreach my $im (values %$importers) {
  99                 $im->done;
 100         }
 101 }
 102
 103 sub _try_fsn_paths {
 104         my ($self, $scan_re, $paths) = @_;
 105         foreach (@$paths) {
 106                 my $path = $_->{path};
 107                 if ($path =~ $scan_re) {
 108                         scan($self, $path);
 109                 } else {
 110                         _try_path($self, $path);
 111                 }
 112         }
 113         _done_for_now($self);
 114 }
 115
 116 sub _remove_spam {
 117         my ($self, $path) = @_;
 118         # path must be marked as (S)een
 119         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 120         my $mime = _path_to_mime($path) or return;
 121         $self->{config}->each_inbox(sub {
 122                 my ($ibx) = @_;
 123                 eval {
 124                         my $im = _importer_for($self, $ibx);
 125                         $im->remove($mime, 'spam');
 126                         if (my $scrub = $ibx->filter) {
 127                                 my $scrubbed = $scrub->scrub($mime) or return;
 128                                 $scrubbed == 100 and return;
 129                                 $im->remove($scrubbed, 'spam');
 130                         }
 131                 };
 132                 if ($@) {
 133                         warn "error removing spam at: ", $path,
 134                                 " from ", $ibx->{name}, ': ', $@, "\n";
 135                 }
 136         })
 137 }
 138
 139 sub _try_path {
 140         my ($self, $path) = @_;
 141         my @p = split(m!/+!, $path);
 142         return if $p[-1] !~ /\A[a-zA-Z0-9][\-\w:,=\.]+\z/;
 143         if ($p[-1] =~ /:2,([A-Z]+)\z/i) {
 144                 my $flags = $1;
 145                 return if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 146         }
 147         return unless -f $path;
 148         if ($path !~ $self->{mdre}) {
 149                 warn "unrecognized path: $path\n";
 150                 return;
 151         }
 152         my $inbox = $self->{mdmap}->{$1};
 153         unless ($inbox) {
 154                 warn "unmappable dir: $1\n";
 155                 return;
 156         }
 157         if (!ref($inbox) && $inbox eq 'watchspam') {
 158                 return _remove_spam($self, $path);
 159         }
 160         my $im = _importer_for($self, $inbox);
 161         my $mime = _path_to_mime($path) or return;
 162         $mime->header_set($_) foreach @PublicInbox::MDA::BAD_HEADERS;
 163         my $wm = $inbox->{-watchheader};
 164         if ($wm) {
 165                 my $v = $mime->header_obj->header_raw($wm->[0]);
 166                 return unless ($v && $v =~ $wm->[1]);
 167         }
 168         if (my $scrub = $inbox->filter) {
 169                 my $ret = $scrub->scrub($mime) or return;
 170                 $ret == 100 and return;
 171                 $mime = $ret;
 172         }
 173
 174         $im->add($mime, $self->{spamcheck});
 175 }
 176
 177 sub quit { trigger_scan($_[0], 'quit') }
 178
 179 sub watch {
 180         my ($self) = @_;
 181         my $scan = File::Temp->newdir("public-inbox-watch.$$.scan.XXXXXX",
 182                                         TMPDIR => 1);
 183         my $scandir = $self->{scandir} = $scan->dirname;
 184         my $re = qr!\A$scandir/!;
 185         my $cb = sub { _try_fsn_paths($self, $re, \@_) };
 186
 187         # lazy load here, we may support watching via IMAP IDLE
 188         # in the future...
 189         require Filesys::Notify::Simple;
 190         my $fsn = Filesys::Notify::Simple->new([@{$self->{mdir}}, $scandir]);
 191         $fsn->wait($cb) until $self->{quit};
 192 }
 193
 194 sub trigger_scan {
 195         my ($self, $base) = @_;
 196         my $dir = $self->{scandir} or return;
 197         open my $fh, '>', "$dir/$base" or die "open $dir/$base failed: $!\n";
 198         close $fh or die "close $dir/$base failed: $!\n";
 199 }
 200
 201 sub scan {
 202         my ($self, $path) = @_;
 203         if ($path =~ /quit\z/) {
 204                 %{$self->{opendirs}} = ();
 205                 _done_for_now($self);
 206                 delete $self->{scandir};
 207                 $self->{quit} = 1;
 208                 return;
 209         }
 210         # else: $path =~ /(cont|full)\z/
 211         return if $self->{quit};
 212         my $max = 10;
 213         my $opendirs = $self->{opendirs};
 214         my @dirnames = keys %$opendirs;
 215         foreach my $dir (@dirnames) {
 216                 my $dh = delete $opendirs->{$dir};
 217                 my $n = $max;
 218                 while (my $fn = readdir($dh)) {
 219                         _try_path($self, "$dir/$fn");
 220                         last if --$n < 0;
 221                 }
 222                 $opendirs->{$dir} = $dh if $n < 0;
 223         }
 224         if ($path =~ /full\z/) {
 225                 foreach my $dir (@{$self->{mdir}}) {
 226                         next if $opendirs->{$dir}; # already in progress
 227                         my $ok = opendir(my $dh, $dir);
 228                         unless ($ok) {
 229                                 warn "failed to open $dir: $!\n";
 230                                 next;
 231                         }
 232                         my $n = $max;
 233                         while (my $fn = readdir($dh)) {
 234                                 _try_path($self, "$dir/$fn");
 235                                 last if --$n < 0;
 236                         }
 237                         $opendirs->{$dir} = $dh if $n < 0;
 238                 }
 239         }
 240         _done_for_now($self);
 241         # do we have more work to do?
 242         trigger_scan($self, 'cont') if keys %$opendirs;
 243 }
 244
 245 sub _path_to_mime {
 246         my ($path) = @_;
 247         if (open my $fh, '<', $path) {
 248                 local $/;
 249                 my $str = <$fh>;
 250                 $str or return;
 251                 return PublicInbox::MIME->new(\$str);
 252         } elsif ($!{ENOENT}) {
 253                 return;
 254         } else {
 255                 warn "failed to open $path: $!\n";
 256                 return;
 257         }
 258 }
 259
 260 sub _importer_for {
 261         my ($self, $ibx) = @_;
 262         my $im = $ibx->importer(0);
 263         my $importers = $self->{importers};
 264         if (scalar(keys(%$importers)) > 2) {
 265                 delete $importers->{"$im"};
 266                 _done_for_now($self);
 267         }
 268
 269         $importers->{"$im"} = $im;
 270 }
 271
 272 sub _spamcheck_cb {
 273         my ($sc) = @_;
 274         sub {
 275                 my ($mime) = @_;
 276                 my $tmp = '';
 277                 if ($sc->spamcheck($mime, \$tmp)) {
 278                         return PublicInbox::MIME->new(\$tmp);
 279                 }
 280                 warn $mime->header('Message-ID')." failed spam check\n";
 281                 undef;
 282         }
 283 }
 284
 285 1;