lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MIME;
  10 use PublicInbox::Spawn qw(spawn);
  11 use PublicInbox::InboxWritable;
  12 use File::Temp qw//;
  13 use PublicInbox::Filter::Base;
  14 use PublicInbox::Spamcheck;
  15 *REJECT = *PublicInbox::Filter::Base::REJECT;
  16
  17 sub new {
  18         my ($class, $config) = @_;
  19         my (%mdmap, @mdir, $spamc);
  20         my %uniq;
  21
  22         # "publicinboxwatch" is the documented namespace
  23         # "publicinboxlearn" is legacy but may be supported
  24         # indefinitely...
  25         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  26                 my $k = "$pfx.watchspam";
  27                 if (my $dir = $config->{$k}) {
  28                         if (is_maildir($dir)) {
  29                                 # skip "new", no MUA has seen it, yet.
  30                                 my $cur = "$dir/cur";
  31                                 my $old = $mdmap{$cur};
  32                                 if (ref($old)) {
  33                                         foreach my $ibx (@$old) {
  34                                                 warn <<"";
  35 "$cur already watched for `$ibx->{name}'
  36
  37                                         }
  38                                         die;
  39                                 }
  40                                 push @mdir, $cur;
  41                                 $uniq{$cur}++;
  42                                 $mdmap{$cur} = 'watchspam';
  43                         } else {
  44                                 warn "unsupported $k=$dir\n";
  45                         }
  46                 }
  47         }
  48
  49         my $k = 'publicinboxwatch.spamcheck';
  50         my $default = undef;
  51         my $spamcheck = PublicInbox::Spamcheck::get($config, $k, $default);
  52         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  53
  54         $config->each_inbox(sub {
  55                 # need to make all inboxes writable for spam removal:
  56                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  57
  58                 my $watch = $ibx->{watch} or return;
  59                 if (is_maildir($watch)) {
  60                         if (my $wm = $ibx->{watchheader}) {
  61                                 my ($k, $v) = split(/:/, $wm, 2);
  62                                 $ibx->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  63                         }
  64                         my $new = "$watch/new";
  65                         my $cur = "$watch/cur";
  66                         push @mdir, $new unless $uniq{$new}++;
  67                         push @mdir, $cur unless $uniq{$cur}++;
  68
  69                         push @{$mdmap{$new} ||= []}, $ibx;
  70                         push @{$mdmap{$cur} ||= []}, $ibx;
  71                 } else {
  72                         warn "watch unsupported: $k=$watch\n";
  73                 }
  74         });
  75         return unless @mdir;
  76
  77         my $mdre = join('|', map { quotemeta($_) } @mdir);
  78         $mdre = qr!\A($mdre)/!;
  79         bless {
  80                 spamcheck => $spamcheck,
  81                 mdmap => \%mdmap,
  82                 mdir => \@mdir,
  83                 mdre => $mdre,
  84                 config => $config,
  85                 importers => {},
  86                 opendirs => {}, # dirname => dirhandle (in progress scans)
  87         }, $class;
  88 }
  89
  90 sub _done_for_now {
  91         my ($self) = @_;
  92         my $importers = $self->{importers};
  93         foreach my $im (values %$importers) {
  94                 $im->done;
  95         }
  96 }
  97
  98 sub _try_fsn_paths {
  99         my ($self, $scan_re, $paths) = @_;
 100         foreach (@$paths) {
 101                 my $path = $_->{path};
 102                 if ($path =~ $scan_re) {
 103                         scan($self, $path);
 104                 } else {
 105                         _try_path($self, $path);
 106                 }
 107         }
 108         _done_for_now($self);
 109 }
 110
 111 sub _remove_spam {
 112         my ($self, $path) = @_;
 113         # path must be marked as (S)een
 114         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 115         my $mime = _path_to_mime($path) or return;
 116         $self->{config}->each_inbox(sub {
 117                 my ($ibx) = @_;
 118                 eval {
 119                         my $im = _importer_for($self, $ibx);
 120                         $im->remove($mime, 'spam');
 121                         if (my $scrub = $ibx->filter($im)) {
 122                                 my $scrubbed = $scrub->scrub($mime, 1);
 123                                 $scrubbed or return;
 124                                 $scrubbed == REJECT() and return;
 125                                 $im->remove($scrubbed, 'spam');
 126                         }
 127                 };
 128                 if ($@) {
 129                         warn "error removing spam at: ", $path,
 130                                 " from ", $ibx->{name}, ': ', $@, "\n";
 131                 }
 132         })
 133 }
 134
 135 sub _try_path {
 136         my ($self, $path) = @_;
 137         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 138         if ($path !~ $self->{mdre}) {
 139                 warn "unrecognized path: $path\n";
 140                 return;
 141         }
 142         my $inboxes = $self->{mdmap}->{$1};
 143         unless ($inboxes) {
 144                 warn "unmappable dir: $1\n";
 145                 return;
 146         }
 147         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 148                 return _remove_spam($self, $path);
 149         }
 150
 151         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 152         local $SIG{__WARN__} = sub {
 153                 $warn_cb->("path: $path\n");
 154                 $warn_cb->(@_);
 155         };
 156         foreach my $ibx (@$inboxes) {
 157                 my $mime = _path_to_mime($path) or next;
 158                 my $im = _importer_for($self, $ibx);
 159
 160                 my $wm = $ibx->{-watchheader};
 161                 if ($wm) {
 162                         my $v = $mime->header_obj->header_raw($wm->[0]);
 163                         next unless ($v && $v =~ $wm->[1]);
 164                 }
 165
 166                 if (my $scrub = $ibx->filter($im)) {
 167                         my $ret = $scrub->scrub($mime) or next;
 168                         $ret == REJECT() and next;
 169                         $mime = $ret;
 170                 }
 171                 $im->add($mime, $self->{spamcheck});
 172         }
 173 }
 174
 175 sub quit { trigger_scan($_[0], 'quit') }
 176
 177 sub watch {
 178         my ($self) = @_;
 179         my $scan = File::Temp->newdir("public-inbox-watch.$$.scan.XXXXXX",
 180                                         TMPDIR => 1);
 181         my $scandir = $self->{scandir} = $scan->dirname;
 182         my $re = qr!\A$scandir/!;
 183         my $cb = sub { _try_fsn_paths($self, $re, \@_) };
 184
 185         # lazy load here, we may support watching via IMAP IDLE
 186         # in the future...
 187         require Filesys::Notify::Simple;
 188         my $fsn = Filesys::Notify::Simple->new([@{$self->{mdir}}, $scandir]);
 189         $fsn->wait($cb) until $self->{quit};
 190 }
 191
 192 sub trigger_scan {
 193         my ($self, $base) = @_;
 194         my $dir = $self->{scandir} or return;
 195         open my $fh, '>', "$dir/$base" or die "open $dir/$base failed: $!\n";
 196         close $fh or die "close $dir/$base failed: $!\n";
 197 }
 198
 199 sub scan {
 200         my ($self, $path) = @_;
 201         if ($path =~ /quit\z/) {
 202                 %{$self->{opendirs}} = ();
 203                 _done_for_now($self);
 204                 delete $self->{scandir};
 205                 $self->{quit} = 1;
 206                 return;
 207         }
 208         # else: $path =~ /(cont|full)\z/
 209         return if $self->{quit};
 210         my $max = 10;
 211         my $opendirs = $self->{opendirs};
 212         my @dirnames = keys %$opendirs;
 213         foreach my $dir (@dirnames) {
 214                 my $dh = delete $opendirs->{$dir};
 215                 my $n = $max;
 216                 while (my $fn = readdir($dh)) {
 217                         _try_path($self, "$dir/$fn");
 218                         last if --$n < 0;
 219                 }
 220                 $opendirs->{$dir} = $dh if $n < 0;
 221         }
 222         if ($path =~ /full\z/) {
 223                 foreach my $dir (@{$self->{mdir}}) {
 224                         next if $opendirs->{$dir}; # already in progress
 225                         my $ok = opendir(my $dh, $dir);
 226                         unless ($ok) {
 227                                 warn "failed to open $dir: $!\n";
 228                                 next;
 229                         }
 230                         my $n = $max;
 231                         while (my $fn = readdir($dh)) {
 232                                 _try_path($self, "$dir/$fn");
 233                                 last if --$n < 0;
 234                         }
 235                         $opendirs->{$dir} = $dh if $n < 0;
 236                 }
 237         }
 238         _done_for_now($self);
 239         # do we have more work to do?
 240         trigger_scan($self, 'cont') if keys %$opendirs;
 241 }
 242
 243 sub _path_to_mime {
 244         my ($path) = @_;
 245         if (open my $fh, '<', $path) {
 246                 local $/;
 247                 my $str = <$fh>;
 248                 $str or return;
 249                 return PublicInbox::MIME->new(\$str);
 250         } elsif ($!{ENOENT}) {
 251                 return;
 252         } else {
 253                 warn "failed to open $path: $!\n";
 254                 return;
 255         }
 256 }
 257
 258 sub _importer_for {
 259         my ($self, $ibx) = @_;
 260         my $importers = $self->{importers};
 261         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 262         if (scalar(keys(%$importers)) > 2) {
 263                 delete $importers->{"$ibx"};
 264                 _done_for_now($self);
 265         }
 266
 267         $importers->{"$ibx"} = $im;
 268 }
 269
 270 sub _spamcheck_cb {
 271         my ($sc) = @_;
 272         sub {
 273                 my ($mime) = @_;
 274                 my $tmp = '';
 275                 if ($sc->spamcheck($mime, \$tmp)) {
 276                         return PublicInbox::MIME->new(\$tmp);
 277                 }
 278                 warn $mime->header('Message-ID')." failed spam check\n";
 279                 undef;
 280         }
 281 }
 282
 283 sub is_maildir {
 284         $_[0] =~ s!\Amaildir:!! or return;
 285         $_[0] =~ tr!/!/!s;
 286         $_[0] =~ s!/\z!!;
 287         $_[0];
 288 }
 289
 290 1;