lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::WatchMaildir;
   4 use strict;
   5 use warnings;
   6 use Email::MIME;
   7 use Email::MIME::ContentType;
   8 $Email::MIME::ContentType::STRICT_PARAMS = 0; # user input is imperfect
   9 use PublicInbox::Git;
  10 use PublicInbox::Import;
  11 use PublicInbox::MDA;
  12 use PublicInbox::Spawn qw(spawn);
  13
  14 sub new {
  15         my ($class, $config) = @_;
  16         my (%mdmap, @mdir, $spamc);
  17
  18         # XXX is "publicinboxlearn" really a good namespace for this?
  19         my $k = 'publicinboxlearn.watchspam';
  20         if (my $spamdir = $config->{$k}) {
  21                 if ($spamdir =~ s/\Amaildir://) {
  22                         $spamdir =~ s!/+\z!!;
  23                         # skip "new", no MUA has seen it, yet.
  24                         my $cur = "$spamdir/cur";
  25                         push @mdir, $cur;
  26                         $mdmap{$cur} = 'watchspam';
  27                 } else {
  28                         warn "unsupported $k=$spamdir\n";
  29                 }
  30         }
  31
  32         $k = 'publicinboxwatch.spamcheck';
  33         my $spamcheck = $config->{$k};
  34         if ($spamcheck) {
  35                 if ($spamcheck eq 'spamc') {
  36                         $spamcheck = 'PublicInbox::Spamcheck::Spamc';
  37                 }
  38                 if ($spamcheck =~ /::/) {
  39                         eval "require $spamcheck";
  40                         $spamcheck = _spamcheck_cb($spamcheck->new);
  41                 } else {
  42                         warn "unsupported $k=$spamcheck\n";
  43                         $spamcheck = undef;
  44                 }
  45         }
  46         foreach $k (keys %$config) {
  47                 $k =~ /\Apublicinbox\.([^\.]+)\.watch\z/ or next;
  48                 my $name = $1;
  49                 my $watch = $config->{$k};
  50                 if ($watch =~ s/\Amaildir://) {
  51                         $watch =~ s!/+\z!!;
  52                         my $inbox = $config->lookup_name($name);
  53                         if (my $wm = $inbox->{watchheader}) {
  54                                 my ($k, $v) = split(/:/, $wm, 2);
  55                                 $inbox->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  56                         }
  57                         my $new = "$watch/new";
  58                         my $cur = "$watch/cur";
  59                         push @mdir, $new, $cur;
  60                         die "$new already in use\n" if $mdmap{$new};
  61                         die "$cur already in use\n" if $mdmap{$cur};
  62                         $mdmap{$new} = $mdmap{$cur} = $inbox;
  63                 } else {
  64                         warn "watch unsupported: $k=$watch\n";
  65                 }
  66         }
  67         return unless @mdir;
  68
  69         my $mdre = join('|', map { quotemeta($_) } @mdir);
  70         $mdre = qr!\A($mdre)/!;
  71         bless {
  72                 spamcheck => $spamcheck,
  73                 mdmap => \%mdmap,
  74                 mdir => \@mdir,
  75                 mdre => $mdre,
  76                 importers => {},
  77         }, $class;
  78 }
  79
  80 sub _done_for_now {
  81         $_->done foreach values %{$_[0]->{importers}};
  82 }
  83
  84 sub _try_fsn_paths {
  85         my ($self, $paths) = @_;
  86         _try_path($self, $_->{path}) foreach @$paths;
  87         _done_for_now($self);
  88 }
  89
  90 sub _remove_spam {
  91         my ($self, $path) = @_;
  92         $path =~ /:2,[A-R]*S[T-Z]*\z/ or return;
  93         my $mime = _path_to_mime($path) or return;
  94         _force_mid($mime);
  95         foreach my $inbox (values %{$self->{mdmap}}) {
  96                 next unless ref $inbox;
  97                 my $im = _importer_for($self, $inbox);
  98                 $im->remove($mime);
  99                 if (my $scrub = _scrubber_for($inbox)) {
 100                         my $scrubbed = $scrub->scrub($mime) or next;
 101                         $im->remove($scrubbed);
 102                 }
 103         }
 104 }
 105
 106 # used to hash the relevant portions of a message when there are conflicts
 107 sub _hash_mime2 {
 108         my ($mime) = @_;
 109         require Digest::SHA;
 110         my $dig = Digest::SHA->new('SHA-1');
 111         $dig->add($mime->header_obj->header_raw('Subject'));
 112         $dig->add($mime->body_raw);
 113         $dig->hexdigest;
 114 }
 115
 116 sub _force_mid {
 117         my ($mime) = @_;
 118         # probably a bad idea, but we inject a Message-Id if
 119         # one is missing, here..
 120         my $mid = $mime->header_obj->header_raw('Message-Id');
 121         if (!defined $mid || $mid =~ /\A\s*\z/) {
 122                 $mid = '<' . _hash_mime2($mime) . '@generated>';
 123                 $mime->header_set('Message-Id', $mid);
 124         }
 125 }
 126
 127 sub _try_path {
 128         my ($self, $path) = @_;
 129         my @p = split(m!/+!, $path);
 130         return unless $p[-1] =~ /\A[a-zA-Z0-9][\w:,=\.]+\z/;
 131         return unless -f $path;
 132         if ($path !~ $self->{mdre}) {
 133                 warn "unrecognized path: $path\n";
 134                 return;
 135         }
 136         my $inbox = $self->{mdmap}->{$1};
 137         unless ($inbox) {
 138                 warn "unmappable dir: $1\n";
 139                 return;
 140         }
 141         if (!ref($inbox) && $inbox eq 'watchspam') {
 142                 return _remove_spam($self, $path);
 143         }
 144         my $im = _importer_for($self, $inbox);
 145         my $mime = _path_to_mime($path) or return;
 146         $mime->header_set($_) foreach @PublicInbox::MDA::BAD_HEADERS;
 147         my $wm = $inbox->{-watchheader};
 148         if ($wm) {
 149                 my $v = $mime->header_obj->header_raw($wm->[0]);
 150                 return unless ($v && $v =~ $wm->[1]);
 151         }
 152         if (my $scrub = _scrubber_for($inbox)) {
 153                 $mime = $scrub->scrub($mime) or return;
 154         }
 155
 156         _force_mid($mime);
 157         $im->add($mime, $self->{spamcheck});
 158 }
 159
 160 sub watch {
 161         my ($self) = @_;
 162         my $cb = sub { _try_fsn_paths($self, \@_) };
 163         my $mdir = $self->{mdir};
 164
 165         # lazy load here, we may support watching via IMAP IDLE
 166         # in the future...
 167         require Filesys::Notify::Simple;
 168         my $watcher = Filesys::Notify::Simple->new($mdir);
 169         $watcher->wait($cb) while (1);
 170 }
 171
 172 sub scan {
 173         my ($self) = @_;
 174         my $mdir = $self->{mdir};
 175         foreach my $dir (@$mdir) {
 176                 my $ok = opendir(my $dh, $dir);
 177                 unless ($ok) {
 178                         warn "failed to open $dir: $!\n";
 179                         next;
 180                 }
 181                 while (my $fn = readdir($dh)) {
 182                         _try_path($self, "$dir/$fn");
 183                 }
 184                 closedir $dh;
 185         }
 186         _done_for_now($self);
 187 }
 188
 189 sub _path_to_mime {
 190         my ($path) = @_;
 191         if (open my $fh, '<', $path) {
 192                 local $/;
 193                 my $str = <$fh>;
 194                 $str or return;
 195                 return Email::MIME->new(\$str);
 196         } elsif ($!{ENOENT}) {
 197                 return;
 198         } else {
 199                 warn "failed to open $path: $!\n";
 200                 return;
 201         }
 202 }
 203
 204 sub _importer_for {
 205         my ($self, $inbox) = @_;
 206         my $im = $inbox->{-import} ||= eval {
 207                 my $git = $inbox->git;
 208                 my $name = $inbox->{name};
 209                 my $addr = $inbox->{-primary_address};
 210                 PublicInbox::Import->new($git, $name, $addr);
 211         };
 212         $self->{importers}->{"$im"} = $im;
 213 }
 214
 215 sub _scrubber_for {
 216         my ($inbox) = @_;
 217         my $f = $inbox->{filter};
 218         if ($f && $f =~ /::/) {
 219                 eval "require $f";
 220                 if ($@) {
 221                         warn $@;
 222                 } else {
 223                         return $f->new;
 224                 }
 225         }
 226         undef;
 227 }
 228
 229 sub _spamcheck_cb {
 230         my ($sc) = @_;
 231         sub {
 232                 my ($mime) = @_;
 233                 my $tmp = '';
 234                 if ($sc->spamcheck($mime, \$tmp)) {
 235                         return Email::MIME->new(\$tmp);
 236                 }
 237                 undef;
 238         }
 239 }
 240
 241 1;