lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use Email::MIME;
  10 use Email::MIME::ContentType;
  11 $Email::MIME::ContentType::STRICT_PARAMS = 0; # user input is imperfect
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MDA;
  15 use PublicInbox::Spawn qw(spawn);
  16
  17 sub new {
  18         my ($class, $config) = @_;
  19         my (%mdmap, @mdir, $spamc);
  20
  21         # XXX is "publicinboxlearn" really a good namespace for this?
  22         my $k = 'publicinboxlearn.watchspam';
  23         if (my $spamdir = $config->{$k}) {
  24                 if ($spamdir =~ s/\Amaildir://) {
  25                         $spamdir =~ s!/+\z!!;
  26                         # skip "new", no MUA has seen it, yet.
  27                         my $cur = "$spamdir/cur";
  28                         push @mdir, $cur;
  29                         $mdmap{$cur} = 'watchspam';
  30                 } else {
  31                         warn "unsupported $k=$spamdir\n";
  32                 }
  33         }
  34
  35         $k = 'publicinboxwatch.spamcheck';
  36         my $spamcheck = $config->{$k};
  37         if ($spamcheck) {
  38                 if ($spamcheck eq 'spamc') {
  39                         $spamcheck = 'PublicInbox::Spamcheck::Spamc';
  40                 }
  41                 if ($spamcheck =~ /::/) {
  42                         eval "require $spamcheck";
  43                         $spamcheck = _spamcheck_cb($spamcheck->new);
  44                 } else {
  45                         warn "unsupported $k=$spamcheck\n";
  46                         $spamcheck = undef;
  47                 }
  48         }
  49         foreach $k (keys %$config) {
  50                 $k =~ /\Apublicinbox\.([^\.]+)\.watch\z/ or next;
  51                 my $name = $1;
  52                 my $watch = $config->{$k};
  53                 if ($watch =~ s/\Amaildir://) {
  54                         $watch =~ s!/+\z!!;
  55                         my $inbox = $config->lookup_name($name);
  56                         if (my $wm = $inbox->{watchheader}) {
  57                                 my ($k, $v) = split(/:/, $wm, 2);
  58                                 $inbox->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  59                         }
  60                         my $new = "$watch/new";
  61                         my $cur = "$watch/cur";
  62                         push @mdir, $new, $cur;
  63                         die "$new already in use\n" if $mdmap{$new};
  64                         die "$cur already in use\n" if $mdmap{$cur};
  65                         $mdmap{$new} = $mdmap{$cur} = $inbox;
  66                 } else {
  67                         warn "watch unsupported: $k=$watch\n";
  68                 }
  69         }
  70         return unless @mdir;
  71
  72         my $mdre = join('|', map { quotemeta($_) } @mdir);
  73         $mdre = qr!\A($mdre)/!;
  74         bless {
  75                 spamcheck => $spamcheck,
  76                 mdmap => \%mdmap,
  77                 mdir => \@mdir,
  78                 mdre => $mdre,
  79                 importers => {},
  80         }, $class;
  81 }
  82
  83 sub _done_for_now {
  84         $_->done foreach values %{$_[0]->{importers}};
  85 }
  86
  87 sub _try_fsn_paths {
  88         my ($self, $paths) = @_;
  89         _try_path($self, $_->{path}) foreach @$paths;
  90         _done_for_now($self);
  91 }
  92
  93 sub _remove_spam {
  94         my ($self, $path) = @_;
  95         $path =~ /:2,[A-R]*S[T-Z]*\z/i or return;
  96         my $mime = _path_to_mime($path) or return;
  97         _force_mid($mime);
  98         foreach my $inbox (values %{$self->{mdmap}}) {
  99                 next unless ref $inbox;
 100                 my $im = _importer_for($self, $inbox);
 101                 $im->remove($mime);
 102                 if (my $scrub = _scrubber_for($inbox)) {
 103                         my $scrubbed = $scrub->scrub($mime) or next;
 104                         $im->remove($scrubbed);
 105                 }
 106         }
 107 }
 108
 109 # used to hash the relevant portions of a message when there are conflicts
 110 sub _hash_mime2 {
 111         my ($mime) = @_;
 112         require Digest::SHA;
 113         my $dig = Digest::SHA->new('SHA-1');
 114         $dig->add($mime->header_obj->header_raw('Subject'));
 115         $dig->add($mime->body_raw);
 116         $dig->hexdigest;
 117 }
 118
 119 sub _force_mid {
 120         my ($mime) = @_;
 121         # probably a bad idea, but we inject a Message-Id if
 122         # one is missing, here..
 123         my $mid = $mime->header_obj->header_raw('Message-Id');
 124         if (!defined $mid || $mid =~ /\A\s*\z/) {
 125                 $mid = '<' . _hash_mime2($mime) . '@generated>';
 126                 $mime->header_set('Message-Id', $mid);
 127         }
 128 }
 129
 130 sub _try_path {
 131         my ($self, $path) = @_;
 132         my @p = split(m!/+!, $path);
 133         return if $p[-1] !~ /\A[a-zA-Z0-9][\w:,=\.]+\z/;
 134         if ($p[-1] =~ /:2,([A-Z]+)\z/i) {
 135                 my $flags = $1;
 136                 return if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 137         }
 138         return unless -f $path;
 139         if ($path !~ $self->{mdre}) {
 140                 warn "unrecognized path: $path\n";
 141                 return;
 142         }
 143         my $inbox = $self->{mdmap}->{$1};
 144         unless ($inbox) {
 145                 warn "unmappable dir: $1\n";
 146                 return;
 147         }
 148         if (!ref($inbox) && $inbox eq 'watchspam') {
 149                 return _remove_spam($self, $path);
 150         }
 151         my $im = _importer_for($self, $inbox);
 152         my $mime = _path_to_mime($path) or return;
 153         $mime->header_set($_) foreach @PublicInbox::MDA::BAD_HEADERS;
 154         my $wm = $inbox->{-watchheader};
 155         if ($wm) {
 156                 my $v = $mime->header_obj->header_raw($wm->[0]);
 157                 return unless ($v && $v =~ $wm->[1]);
 158         }
 159         if (my $scrub = _scrubber_for($inbox)) {
 160                 $mime = $scrub->scrub($mime) or return;
 161         }
 162
 163         _force_mid($mime);
 164         $im->add($mime, $self->{spamcheck});
 165 }
 166
 167 sub watch {
 168         my ($self) = @_;
 169         my $cb = sub { _try_fsn_paths($self, \@_) };
 170         my $mdir = $self->{mdir};
 171
 172         # lazy load here, we may support watching via IMAP IDLE
 173         # in the future...
 174         require Filesys::Notify::Simple;
 175         my $watcher = Filesys::Notify::Simple->new($mdir);
 176         $watcher->wait($cb) while (1);
 177 }
 178
 179 sub scan {
 180         my ($self) = @_;
 181         my $mdir = $self->{mdir};
 182         foreach my $dir (@$mdir) {
 183                 my $ok = opendir(my $dh, $dir);
 184                 unless ($ok) {
 185                         warn "failed to open $dir: $!\n";
 186                         next;
 187                 }
 188                 while (my $fn = readdir($dh)) {
 189                         _try_path($self, "$dir/$fn");
 190                 }
 191                 closedir $dh;
 192         }
 193         _done_for_now($self);
 194 }
 195
 196 sub _path_to_mime {
 197         my ($path) = @_;
 198         if (open my $fh, '<', $path) {
 199                 local $/;
 200                 my $str = <$fh>;
 201                 $str or return;
 202                 return Email::MIME->new(\$str);
 203         } elsif ($!{ENOENT}) {
 204                 return;
 205         } else {
 206                 warn "failed to open $path: $!\n";
 207                 return;
 208         }
 209 }
 210
 211 sub _importer_for {
 212         my ($self, $inbox) = @_;
 213         my $im = $inbox->{-import} ||= eval {
 214                 my $git = $inbox->git;
 215                 my $name = $inbox->{name};
 216                 my $addr = $inbox->{-primary_address};
 217                 PublicInbox::Import->new($git, $name, $addr);
 218         };
 219         $self->{importers}->{"$im"} = $im;
 220 }
 221
 222 sub _scrubber_for {
 223         my ($inbox) = @_;
 224         my $f = $inbox->{filter};
 225         if ($f && $f =~ /::/) {
 226                 eval "require $f";
 227                 if ($@) {
 228                         warn $@;
 229                 } else {
 230                         return $f->new;
 231                 }
 232         }
 233         undef;
 234 }
 235
 236 sub _spamcheck_cb {
 237         my ($sc) = @_;
 238         sub {
 239                 my ($mime) = @_;
 240                 my $tmp = '';
 241                 if ($sc->spamcheck($mime, \$tmp)) {
 242                         return Email::MIME->new(\$tmp);
 243                 }
 244                 warn $mime->header('Message-ID')." failed spam check\n";
 245                 undef;
 246         }
 247 }
 248
 249 1;