lib/PublicInbox/WatchMaildir.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::WatchMaildir;
   7 use strict;
   8 use warnings;
   9 use Email::MIME;
  10 use Email::MIME::ContentType;
  11 $Email::MIME::ContentType::STRICT_PARAMS = 0; # user input is imperfect
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MDA;
  15 use PublicInbox::Spawn qw(spawn);
  16
  17 sub new {
  18         my ($class, $config) = @_;
  19         my (%mdmap, @mdir, $spamc);
  20
  21         # "publicinboxwatch" is the documented namespace
  22         # "publicinboxlearn" is legacy but may be supported
  23         # indefinitely...
  24         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  25                 my $k = "$pfx.watchspam";
  26                 if (my $spamdir = $config->{$k}) {
  27                         if ($spamdir =~ s/\Amaildir://) {
  28                                 $spamdir =~ s!/+\z!!;
  29                                 # skip "new", no MUA has seen it, yet.
  30                                 my $cur = "$spamdir/cur";
  31                                 push @mdir, $cur;
  32                                 $mdmap{$cur} = 'watchspam';
  33                         } else {
  34                                 warn "unsupported $k=$spamdir\n";
  35                         }
  36                 }
  37         }
  38
  39         my $k = 'publicinboxwatch.spamcheck';
  40         my $spamcheck = $config->{$k};
  41         if ($spamcheck) {
  42                 if ($spamcheck eq 'spamc') {
  43                         $spamcheck = 'PublicInbox::Spamcheck::Spamc';
  44                 }
  45                 if ($spamcheck =~ /::/) {
  46                         eval "require $spamcheck";
  47                         $spamcheck = _spamcheck_cb($spamcheck->new);
  48                 } else {
  49                         warn "unsupported $k=$spamcheck\n";
  50                         $spamcheck = undef;
  51                 }
  52         }
  53         foreach $k (keys %$config) {
  54                 $k =~ /\Apublicinbox\.([^\.]+)\.watch\z/ or next;
  55                 my $name = $1;
  56                 my $watch = $config->{$k};
  57                 if ($watch =~ s/\Amaildir://) {
  58                         $watch =~ s!/+\z!!;
  59                         my $inbox = $config->lookup_name($name);
  60                         if (my $wm = $inbox->{watchheader}) {
  61                                 my ($k, $v) = split(/:/, $wm, 2);
  62                                 $inbox->{-watchheader} = [ $k, qr/\Q$v\E/ ];
  63                         }
  64                         my $new = "$watch/new";
  65                         my $cur = "$watch/cur";
  66                         push @mdir, $new, $cur;
  67                         die "$new already in use\n" if $mdmap{$new};
  68                         die "$cur already in use\n" if $mdmap{$cur};
  69                         $mdmap{$new} = $mdmap{$cur} = $inbox;
  70                 } else {
  71                         warn "watch unsupported: $k=$watch\n";
  72                 }
  73         }
  74         return unless @mdir;
  75
  76         my $mdre = join('|', map { quotemeta($_) } @mdir);
  77         $mdre = qr!\A($mdre)/!;
  78         bless {
  79                 spamcheck => $spamcheck,
  80                 mdmap => \%mdmap,
  81                 mdir => \@mdir,
  82                 mdre => $mdre,
  83                 importers => {},
  84         }, $class;
  85 }
  86
  87 sub _done_for_now {
  88         $_->done foreach values %{$_[0]->{importers}};
  89 }
  90
  91 sub _try_fsn_paths {
  92         my ($self, $paths) = @_;
  93         _try_path($self, $_->{path}) foreach @$paths;
  94         _done_for_now($self);
  95 }
  96
  97 sub _remove_spam {
  98         my ($self, $path) = @_;
  99         $path =~ /:2,[A-R]*S[T-Z]*\z/i or return;
 100         my $mime = _path_to_mime($path) or return;
 101         _force_mid($mime);
 102         foreach my $inbox (values %{$self->{mdmap}}) {
 103                 next unless ref $inbox;
 104                 my $im = _importer_for($self, $inbox);
 105                 $im->remove($mime);
 106                 if (my $scrub = _scrubber_for($inbox)) {
 107                         my $scrubbed = $scrub->scrub($mime) or next;
 108                         $im->remove($scrubbed);
 109                 }
 110         }
 111 }
 112
 113 # used to hash the relevant portions of a message when there are conflicts
 114 sub _hash_mime2 {
 115         my ($mime) = @_;
 116         require Digest::SHA;
 117         my $dig = Digest::SHA->new('SHA-1');
 118         $dig->add($mime->header_obj->header_raw('Subject'));
 119         $dig->add($mime->body_raw);
 120         $dig->hexdigest;
 121 }
 122
 123 sub _force_mid {
 124         my ($mime) = @_;
 125         # probably a bad idea, but we inject a Message-Id if
 126         # one is missing, here..
 127         my $mid = $mime->header_obj->header_raw('Message-Id');
 128         if (!defined $mid || $mid =~ /\A\s*\z/) {
 129                 $mid = '<' . _hash_mime2($mime) . '@generated>';
 130                 $mime->header_set('Message-Id', $mid);
 131         }
 132 }
 133
 134 sub _try_path {
 135         my ($self, $path) = @_;
 136         my @p = split(m!/+!, $path);
 137         return if $p[-1] !~ /\A[a-zA-Z0-9][\w:,=\.]+\z/;
 138         if ($p[-1] =~ /:2,([A-Z]+)\z/i) {
 139                 my $flags = $1;
 140                 return if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 141         }
 142         return unless -f $path;
 143         if ($path !~ $self->{mdre}) {
 144                 warn "unrecognized path: $path\n";
 145                 return;
 146         }
 147         my $inbox = $self->{mdmap}->{$1};
 148         unless ($inbox) {
 149                 warn "unmappable dir: $1\n";
 150                 return;
 151         }
 152         if (!ref($inbox) && $inbox eq 'watchspam') {
 153                 return _remove_spam($self, $path);
 154         }
 155         my $im = _importer_for($self, $inbox);
 156         my $mime = _path_to_mime($path) or return;
 157         $mime->header_set($_) foreach @PublicInbox::MDA::BAD_HEADERS;
 158         my $wm = $inbox->{-watchheader};
 159         if ($wm) {
 160                 my $v = $mime->header_obj->header_raw($wm->[0]);
 161                 return unless ($v && $v =~ $wm->[1]);
 162         }
 163         if (my $scrub = _scrubber_for($inbox)) {
 164                 $mime = $scrub->scrub($mime) or return;
 165         }
 166
 167         _force_mid($mime);
 168         $im->add($mime, $self->{spamcheck});
 169 }
 170
 171 sub watch {
 172         my ($self) = @_;
 173         my $cb = sub { _try_fsn_paths($self, \@_) };
 174         my $mdir = $self->{mdir};
 175
 176         # lazy load here, we may support watching via IMAP IDLE
 177         # in the future...
 178         require Filesys::Notify::Simple;
 179         my $watcher = Filesys::Notify::Simple->new($mdir);
 180         $watcher->wait($cb) while (1);
 181 }
 182
 183 sub scan {
 184         my ($self) = @_;
 185         my $mdir = $self->{mdir};
 186         foreach my $dir (@$mdir) {
 187                 my $ok = opendir(my $dh, $dir);
 188                 unless ($ok) {
 189                         warn "failed to open $dir: $!\n";
 190                         next;
 191                 }
 192                 while (my $fn = readdir($dh)) {
 193                         _try_path($self, "$dir/$fn");
 194                 }
 195                 closedir $dh;
 196         }
 197         _done_for_now($self);
 198 }
 199
 200 sub _path_to_mime {
 201         my ($path) = @_;
 202         if (open my $fh, '<', $path) {
 203                 local $/;
 204                 my $str = <$fh>;
 205                 $str or return;
 206                 return Email::MIME->new(\$str);
 207         } elsif ($!{ENOENT}) {
 208                 return;
 209         } else {
 210                 warn "failed to open $path: $!\n";
 211                 return;
 212         }
 213 }
 214
 215 sub _importer_for {
 216         my ($self, $inbox) = @_;
 217         my $im = $inbox->{-import} ||= eval {
 218                 my $git = $inbox->git;
 219                 my $name = $inbox->{name};
 220                 my $addr = $inbox->{-primary_address};
 221                 PublicInbox::Import->new($git, $name, $addr, $inbox);
 222         };
 223         $self->{importers}->{"$im"} = $im;
 224 }
 225
 226 sub _scrubber_for {
 227         my ($inbox) = @_;
 228         my $f = $inbox->{filter};
 229         if ($f && $f =~ /::/) {
 230                 eval "require $f";
 231                 if ($@) {
 232                         warn $@;
 233                 } else {
 234                         return $f->new;
 235                 }
 236         }
 237         undef;
 238 }
 239
 240 sub _spamcheck_cb {
 241         my ($sc) = @_;
 242         sub {
 243                 my ($mime) = @_;
 244                 my $tmp = '';
 245                 if ($sc->spamcheck($mime, \$tmp)) {
 246                         return Email::MIME->new(\$tmp);
 247                 }
 248                 warn $mime->header('Message-ID')." failed spam check\n";
 249                 undef;
 250         }
 251 }
 252
 253 1;