lib/PublicInbox/WwwCoderepo.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Standalone code repository viewer for users w/o cgit.
   5 # This isn't intended to replicate all of cgit, but merely to be a
   6 # "good enough" viewer with search support and some UI hints to encourage
   7 # cloning + command-line usage.
   8 package PublicInbox::WwwCoderepo;
   9 use v5.12;
  10 use File::Temp 0.19 (); # newdir
  11 use PublicInbox::ViewVCS;
  12 use PublicInbox::WwwStatic qw(r);
  13 use PublicInbox::GitHTTPBackend;
  14 use PublicInbox::Git;
  15 use PublicInbox::GitAsyncCat;
  16 use PublicInbox::WwwStream;
  17 use PublicInbox::Hval qw(ascii_html);
  18 use PublicInbox::ViewDiff qw(uri_escape_path);
  19 use PublicInbox::RepoSnapshot;
  20 use PublicInbox::RepoAtom;
  21
  22 my $EACH_REF = "git for-each-ref --sort=-creatordate --format='%(HEAD)%00".
  23         join('%00', map { "%($_)" }
  24         qw(objectname refname:short subject creatordate:short))."'";
  25
  26 # shared with PublicInbox::Cgit
  27 sub prepare_coderepos {
  28         my ($self) = @_;
  29         my $pi_cfg = $self->{pi_cfg};
  30
  31         # TODO: support gitweb and other repository viewers?
  32         $pi_cfg->parse_cgitrc(undef, 0);
  33
  34         my $code_repos = $pi_cfg->{-code_repos};
  35         for my $k (grep(/\Acoderepo\.(?:.+)\.dir\z/, keys %$pi_cfg)) {
  36                 $k = substr($k, length('coderepo.'), -length('.dir'));
  37                 $code_repos->{$k} //= $pi_cfg->fill_code_repo($k);
  38         }
  39
  40         # associate inboxes and extindices with coderepos for search:
  41         for my $k (grep(/\Apublicinbox\.(?:.+)\.coderepo\z/, keys %$pi_cfg)) {
  42                 $k = substr($k, length('publicinbox.'), -length('.coderepo'));
  43                 my $ibx = $pi_cfg->lookup_name($k) // next;
  44                 $pi_cfg->repo_objs($ibx);
  45         }
  46         for my $k (grep(/\Aextindex\.(?:.+)\.coderepo\z/, keys %$pi_cfg)) {
  47                 $k = substr($k, length('extindex.'), -length('.coderepo'));
  48                 my $eidx = $pi_cfg->lookup_ei($k) // next;
  49                 $pi_cfg->repo_objs($eidx);
  50         }
  51 }
  52
  53 sub new {
  54         my ($cls, $pi_cfg) = @_;
  55         my $self = bless { pi_cfg => $pi_cfg }, $cls;
  56         prepare_coderepos($self);
  57         $self->{snapshots} = do {
  58                 my $s = $pi_cfg->{'coderepo.snapshots'} // '';
  59                 $s eq 'all' ? \%PublicInbox::RepoSnapshot::FMT_TYPES :
  60                         +{ map { $_ => 1 } split(/\s+/, $s) };
  61         };
  62         $self->{$_} = 10 for qw(summary_branches summary_tags);
  63         $self->{$_} = 10 for qw(summary_log);
  64         $self;
  65 }
  66
  67 sub summary_finish {
  68         my ($ctx) = @_;
  69         my $wcb = delete($ctx->{env}->{'qspawn.wcb'}) or return; # already done
  70         my @x = split(/\n\n/sm, delete($ctx->{-each_refs}));
  71         PublicInbox::WwwStream::html_init($ctx);
  72         my $zfh = $ctx->zfh;
  73
  74         # git log
  75         my @r = split(/\n/s, pop(@x) // '');
  76         my $last = pop(@r) if scalar(@r) > $ctx->{wcr}->{summary_log};
  77         my $tip_html = '';
  78         if (defined(my $tip = $ctx->{qp}->{h})) {
  79                 $tip_html .= ' '.ascii_html($tip).' --';
  80         }
  81         print $zfh <<EOM;
  82 <pre><a id=log>\$</a> git log --pretty=format:'%h %s (%cs)%d'$tip_html
  83 EOM
  84         for (@r) {
  85                 my $d; # decorations
  86                 s/^ \(([^\)]+)\)// and $d = $1;
  87                 substr($_, 0, 1, '');
  88                 my ($H, $h, $cs, $s) = split(/ /, $_, 4);
  89                 print $zfh "<a\nhref=./$H/s/>$h</a> ", ascii_html($s),
  90                         " (", $cs, ")\n";
  91                 print $zfh "\t(", ascii_html($d), ")\n" if $d;
  92         }
  93         print $zfh "# no commits, yet\n" if !@r;
  94         print $zfh "...\n" if $last;
  95
  96         # README
  97         my ($bref, $oid, $ref_path) = @{delete $ctx->{-readme}};
  98         if ($bref) {
  99                 my $l = PublicInbox::Linkify->new;
 100                 $$bref =~ s/\s*\z//sm;
 101                 my (undef, $path) = split(/:/, $ref_path, 2); # HEAD:README
 102                 print $zfh "\n<a id=readme>\$</a> " .
 103                         qq(git cat-file blob <a href="./$oid/s/?b=) .
 104                         ascii_html(uri_escape_path($path)) . q(">).
 105                         ascii_html($ref_path), "</a>\n",
 106                         $l->to_html($$bref), '</pre><hr><pre>';
 107         }
 108
 109         # refs/heads
 110         print $zfh "<a id=heads># heads (aka `branches'):</a>\n\$ " .
 111                 "git for-each-ref --sort=-creatordate refs/heads" .
 112                 " \\\n\t--format='%(HEAD) ". # no space for %(align:) hint
 113                 "%(refname:short) %(subject) (%(creatordate:short))'\n";
 114         @r = split(/^/sm, shift(@x) // '');
 115         $last = pop(@r) if scalar(@r) > $ctx->{wcr}->{summary_branches};
 116         for (@r) {
 117                 my ($pfx, $oid, $ref, $s, $cd) = split(/\0/);
 118                 utf8::decode($_) for ($ref, $s);
 119                 chomp $cd;
 120                 my $align = length($ref) < 12 ? ' ' x (12 - length($ref)) : '';
 121                 print $zfh "$pfx <a\nhref=./$oid/s/>", ascii_html($ref),
 122                         "</a>$align ", ascii_html($s), " ($cd)\n";
 123         }
 124         print $zfh "# no heads (branches) yet...\n" if !@r;
 125         print $zfh "...\n" if $last;
 126         print $zfh "\n<a id=tags># tags:</a>\n\$ " .
 127                 "git for-each-ref --sort=-creatordate refs/tags" .
 128                 " \\\n\t--format='". # no space for %(align:) hint
 129                 "%(refname:short) %(subject) (%(creatordate:short))'\n";
 130         @r = split(/^/sm, shift(@x) // '');
 131         $last = pop(@r) if scalar(@r) > $ctx->{wcr}->{summary_tags};
 132         my @s = sort keys %{$ctx->{wcr}->{snapshots}};
 133         my $n;
 134         if (@s) {
 135                 $n = $ctx->{git}->local_nick // die "BUG: $ctx->{git_dir} nick";
 136                 $n =~ s/\.git\z/-/;
 137                 ($n) = ($n =~ m!([^/]+)\z!);
 138                 $n = ascii_html($n);
 139         }
 140         for (@r) {
 141                 my (undef, $oid, $ref, $s, $cd) = split(/\0/);
 142                 utf8::decode($_) for ($ref, $s);
 143                 chomp $cd;
 144                 my $align = length($ref) < 12 ? ' ' x (12 - length($ref)) : '';
 145                 print $zfh "<a\nhref=./$oid/s/>", ascii_html($ref),
 146                         "</a>$align ", ascii_html($s), " ($cd)";
 147                 if (@s) {
 148                         my $v = $ref;
 149                         $v =~ s/\A[vV]//;
 150                         print $zfh "\t",  join(' ', map {
 151                                 qq{<a href="snapshot/$n$v.$_">$_</a>} } @s);
 152                 }
 153                 print $zfh "\n";
 154         }
 155         print $zfh "# no tags yet...\n" if !@r;
 156         print $zfh "...\n" if $last;
 157         $wcb->($ctx->html_done('</pre>'));
 158 }
 159
 160 sub capture_refs ($$) { # psgi_qx callback to capture git-for-each-ref + git-log
 161         my ($bref, $ctx) = @_;
 162         my $qsp_err = delete $ctx->{-qsp_err};
 163         $ctx->{-each_refs} = $$bref;
 164         summary_finish($ctx) if $ctx->{-readme};
 165 }
 166
 167 sub set_readme { # git->cat_async callback
 168         my ($bref, $oid, $type, $size, $ctx) = @_;
 169         my $ref_path = shift @{$ctx->{-nr_readme_tries}}; # e.g. HEAD:README
 170         if ($type eq 'blob' && !$ctx->{-readme}) {
 171                 $ctx->{-readme} = [ $bref, $oid, $ref_path ];
 172         } elsif (scalar @{$ctx->{-nr_readme_tries}} == 0) {
 173                 $ctx->{-readme} //= []; # nothing left to try
 174         } # or try another README...
 175         summary_finish($ctx) if $ctx->{-each_refs} && $ctx->{-readme};
 176 }
 177
 178 sub summary {
 179         my ($self, $ctx) = @_;
 180         $ctx->{wcr} = $self;
 181         my $tip = $ctx->{qp}->{h}; # same as cgit
 182         if (defined $tip && $tip eq '') {
 183                 delete $ctx->{qp}->{h};
 184                 undef($tip);
 185         }
 186         my $nb = $self->{summary_branches} + 1;
 187         my $nt = $self->{summary_tags} + 1;
 188         my $nl = $self->{summary_log} + 1;
 189
 190         my @cmd = (qw(/bin/sh -c),
 191                 "$EACH_REF --count=$nb refs/heads; echo && " .
 192                 "$EACH_REF --count=$nt refs/tags; echo && " .
 193                 qq(git log -$nl --pretty=format:'%d %H %h %cs %s' "\$@" --));
 194         push @cmd, '--', $tip if defined($tip);
 195         my $qsp = PublicInbox::Qspawn->new(\@cmd,
 196                 { GIT_DIR => $ctx->{git}->{git_dir} });
 197         $qsp->{qsp_err} = \($ctx->{-qsp_err} = '');
 198         $tip //= 'HEAD';
 199         my @try = ("$tip:README", "$tip:README.md"); # TODO: configurable
 200         $ctx->{-nr_readme_tries} = [ @try ];
 201         $ctx->{git}->cat_async($_, \&set_readme, $ctx) for @try;
 202         if ($ctx->{env}->{'pi-httpd.async'}) {
 203                 PublicInbox::GitAsyncCat::watch_cat($ctx->{git});
 204         } else { # synchronous
 205                 $ctx->{git}->cat_async_wait;
 206         }
 207         sub { # $_[0] => PublicInbox::HTTP::{Identity,Chunked}
 208                 $ctx->{env}->{'qspawn.wcb'} = $_[0];
 209                 $qsp->psgi_qx($ctx->{env}, undef, \&capture_refs, $ctx);
 210         }
 211 }
 212
 213 sub srv { # endpoint called by PublicInbox::WWW
 214         my ($self, $ctx) = @_;
 215         my $path_info = $ctx->{env}->{PATH_INFO};
 216         my $git;
 217         # handle clone requests
 218         my $cr = $self->{pi_cfg}->{-code_repos};
 219         if ($path_info =~ m!\A/(.+?)/($PublicInbox::GitHTTPBackend::ANY)\z!x) {
 220                 $git = $cr->{$1} and return
 221                         PublicInbox::GitHTTPBackend::serve($ctx->{env},$git,$2);
 222         }
 223         $path_info =~ m!\A/(.+?)/\z! and
 224                 ($ctx->{git} = $cr->{$1}) and return summary($self, $ctx);
 225         $path_info =~ m!\A/(.+?)/([a-f0-9]+)/s/\z! and
 226                         ($ctx->{git} = $cr->{$1}) and
 227                 return PublicInbox::ViewVCS::show($ctx, $2);
 228
 229         # snapshots:
 230         if ($path_info =~ m!\A/(.+?)/snapshot/([^/]+)\z! and
 231                         ($ctx->{git} = $cr->{$1})) {
 232                 $ctx->{wcr} = $self;
 233                 return PublicInbox::RepoSnapshot::srv($ctx, $2) // r(404);
 234         }
 235
 236         if ($path_info =~ m!\A/(.+?)/atom/(.*)\z! and
 237                         ($ctx->{git} = $cr->{$1})) {
 238                 return PublicInbox::RepoAtom::srv_atom($ctx, $2) // r(404);
 239         }
 240
 241         # enforce trailing slash:
 242         if ($path_info =~ m!\A/(.+?)\z! and ($git = $cr->{$1})) {
 243                 my $qs = $ctx->{env}->{QUERY_STRING};
 244                 my $url = $git->base_url($ctx->{env});
 245                 $url .= "?$qs" if $qs ne '';
 246                 [ 301, [ Location => $url, 'Content-Type' => 'text/plain' ],
 247                         [ "Redirecting to $url\n" ] ];
 248         } else {
 249                 r(404);
 250         }
 251 }
 252
 253 1;