lib/PublicInbox/WwwHighlight.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Standalone PSGI app to provide syntax highlighting as-a-service
   5 # via "highlight" Perl module ("libhighlight-perl" in Debian).
   6 #
   7 # This allows exposing highlight as a persistent HTTP service for
   8 # other scripts via HTTP PUT requests.  PATH_INFO will be used
   9 # as a hint for detecting the language for highlight.
  10 #
  11 # The following example using curl(1) will do the right thing
  12 # regarding the file extension:
  13 #
  14 #   curl -HExpect: -T /path/to/file http://example.com/
  15 #
  16 # You can also force a file extension by giving a path
  17 # (in this case, "c") via:
  18 #
  19 #   curl -HExpect: -T /path/to/file http://example.com/x.c
  20
  21 package PublicInbox::WwwHighlight;
  22 use strict;
  23 use warnings;
  24 use HTTP::Status qw(status_message);
  25 use parent qw(PublicInbox::HlMod);
  26
  27 # TODO: support highlight(1) for distros which don't package the
  28 # SWIG extension.  Also, there may be admins who don't want to
  29 # have ugly SWIG-generated code in a long-lived Perl process.
  30
  31 sub r ($) {
  32         my ($code) = @_;
  33         my $msg = status_message($code);
  34         my $len = length($msg);
  35         [ $code, [qw(Content-Type text/plain Content-Length), $len], [$msg] ]
  36 }
  37
  38 # another slurp API hogging up all my memory :<
  39 # This is capped by whatever the PSGI server allows,
  40 # $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} for PublicInbox::HTTP (10 MB)
  41 sub read_in_full ($) {
  42         my ($env) = @_;
  43
  44         my $in = $env->{'psgi.input'};
  45         my $off = 0;
  46         my $buf = '';
  47         my $len = $env->{CONTENT_LENGTH} || 8192;
  48         while (1) {
  49                 my $r = $in->read($buf, $len, $off);
  50                 last unless defined $r;
  51                 return \$buf if $r == 0;
  52                 $off += $r;
  53         }
  54         $env->{'psgi.errors'}->print("input read error: $!\n");
  55 }
  56
  57 # entry point for PSGI
  58 sub call {
  59         my ($self, $env) = @_;
  60         my $req_method = $env->{REQUEST_METHOD};
  61
  62         return r(405) if $req_method ne 'PUT';
  63
  64         my $bref = read_in_full($env) or return r(500);
  65         $bref = $self->do_hl($bref, $env->{PATH_INFO});
  66
  67         my $h = [ 'Content-Type', 'text/html; charset=UTF-8' ];
  68         push @$h, 'Content-Length', bytes::length($$bref);
  69
  70         [ 200, $h, [ $$bref ] ]
  71 }
  72
  73 1;