lib/PublicInbox/WwwHighlight.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Standalone PSGI app to provide syntax highlighting as-a-service
   5 # via "highlight" Perl module ("libhighlight-perl" in Debian).
   6 #
   7 # This allows exposing highlight as a persistent HTTP service for
   8 # other scripts via HTTP PUT requests.  PATH_INFO will be used
   9 # as a hint for detecting the language for highlight.
  10 #
  11 # The following example using curl(1) will do the right thing
  12 # regarding the file extension:
  13 #
  14 #   curl -HExpect: -T /path/to/file http://example.com/
  15 #
  16 # You can also force a file extension by giving a path
  17 # (in this case, "c") via:
  18 #
  19 #   curl -HExpect: -T /path/to/file http://example.com/x.c
  20
  21 package PublicInbox::WwwHighlight;
  22 use strict;
  23 use warnings;
  24 use bytes (); # only for bytes::length
  25 use HTTP::Status qw(status_message);
  26 use parent qw(PublicInbox::HlMod);
  27
  28 # TODO: support highlight(1) for distros which don't package the
  29 # SWIG extension.  Also, there may be admins who don't want to
  30 # have ugly SWIG-generated code in a long-lived Perl process.
  31
  32 sub r ($) {
  33         my ($code) = @_;
  34         my $msg = status_message($code);
  35         my $len = length($msg);
  36         [ $code, [qw(Content-Type text/plain Content-Length), $len], [$msg] ]
  37 }
  38
  39 # another slurp API hogging up all my memory :<
  40 # This is capped by whatever the PSGI server allows,
  41 # $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} for PublicInbox::HTTP (10 MB)
  42 sub read_in_full ($) {
  43         my ($env) = @_;
  44
  45         my $in = $env->{'psgi.input'};
  46         my $off = 0;
  47         my $buf = '';
  48         my $len = $env->{CONTENT_LENGTH} || 8192;
  49         while (1) {
  50                 my $r = $in->read($buf, $len, $off);
  51                 last unless defined $r;
  52                 return \$buf if $r == 0;
  53                 $off += $r;
  54         }
  55         $env->{'psgi.errors'}->print("input read error: $!\n");
  56         undef;
  57 }
  58
  59 # entry point for PSGI
  60 sub call {
  61         my ($self, $env) = @_;
  62         my $req_method = $env->{REQUEST_METHOD};
  63
  64         return r(405) if $req_method ne 'PUT';
  65
  66         my $bref = read_in_full($env) or return r(500);
  67         $bref = $self->do_hl($bref, $env->{PATH_INFO});
  68
  69         my $h = [ 'Content-Type', 'text/html; charset=UTF-8' ];
  70         push @$h, 'Content-Length', bytes::length($$bref);
  71
  72         [ 200, $h, [ $$bref ] ]
  73 }
  74
  75 1;