lib/PublicInbox/WwwHighlight.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Standalone PSGI app to provide syntax highlighting as-a-service
   5 # via "highlight" Perl module ("libhighlight-perl" in Debian).
   6 #
   7 # This allows exposing highlight as a persistent HTTP service for
   8 # other scripts via HTTP PUT requests.  PATH_INFO will be used
   9 # as a hint for detecting the language for highlight.
  10 #
  11 # The following example using curl(1) will do the right thing
  12 # regarding the file extension:
  13 #
  14 #   curl -HExpect: -T /path/to/file http://example.com/
  15 #
  16 # You can also force a file extension by giving a path
  17 # (in this case, "c") via:
  18 #
  19 #   curl -HExpect: -T /path/to/file http://example.com/x.c
  20
  21 package PublicInbox::WwwHighlight;
  22 use strict;
  23 use warnings;
  24 use bytes (); # only for bytes::length
  25 use HTTP::Status qw(status_message);
  26 use parent qw(PublicInbox::HlMod);
  27 use PublicInbox::Linkify qw();
  28
  29 # TODO: support highlight(1) for distros which don't package the
  30 # SWIG extension.  Also, there may be admins who don't want to
  31 # have ugly SWIG-generated code in a long-lived Perl process.
  32
  33 sub r ($) {
  34         my ($code) = @_;
  35         my $msg = status_message($code);
  36         my $len = length($msg);
  37         [ $code, [qw(Content-Type text/plain Content-Length), $len], [$msg] ]
  38 }
  39
  40 # another slurp API hogging up all my memory :<
  41 # This is capped by whatever the PSGI server allows,
  42 # $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} for PublicInbox::HTTP (10 MB)
  43 sub read_in_full ($) {
  44         my ($env) = @_;
  45
  46         my $in = $env->{'psgi.input'};
  47         my $off = 0;
  48         my $buf = '';
  49         my $len = $env->{CONTENT_LENGTH} || 8192;
  50         while (1) {
  51                 my $r = $in->read($buf, $len, $off);
  52                 last unless defined $r;
  53                 return \$buf if $r == 0;
  54                 $off += $r;
  55         }
  56         $env->{'psgi.errors'}->print("input read error: $!\n");
  57         undef;
  58 }
  59
  60 # entry point for PSGI
  61 sub call {
  62         my ($self, $env) = @_;
  63         my $req_method = $env->{REQUEST_METHOD};
  64
  65         return r(405) if $req_method ne 'PUT';
  66
  67         my $bref = read_in_full($env) or return r(500);
  68         my $l = PublicInbox::Linkify->new;
  69         $l->linkify_1($$bref);
  70         $bref = $self->do_hl($bref, $env->{PATH_INFO});
  71         $l->linkify_2($$bref);
  72
  73         my $h = [ 'Content-Type', 'text/html; charset=UTF-8' ];
  74         push @$h, 'Content-Length', bytes::length($$bref);
  75
  76         [ 200, $h, [ $$bref ] ]
  77 }
  78
  79 1;