lib/PublicInbox/WwwListing.pm

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Provide an HTTP-accessible listing of inboxes.
   5 # Used by PublicInbox::WWW
   6 package PublicInbox::WwwListing;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::Hval qw(ascii_html prurl);
  10 use PublicInbox::Linkify;
  11 use PublicInbox::View;
  12 use PublicInbox::Inbox;
  13 use bytes (); # bytes::length
  14 use HTTP::Date qw(time2str);
  15 use Digest::SHA ();
  16 use File::Spec ();
  17 *try_cat = \&PublicInbox::Inbox::try_cat;
  18 our $json;
  19 if (eval { require IO::Compress::Gzip }) {
  20         for my $mod (qw(JSON::MaybeXS JSON JSON::PP)) {
  21                 eval "require $mod" or next;
  22                 # ->ascii encodes non-ASCII to "\uXXXX"
  23                 $json = $mod->new->ascii(1);
  24         }
  25 }
  26
  27 sub list_all_i {
  28         my ($ibx, $arg) = @_;
  29         my ($list, $hide_key) = @$arg;
  30         push @$list, $ibx unless $ibx->{-hide}->{$hide_key};
  31 }
  32
  33 sub list_all ($$$) {
  34         my ($self, $env, $hide_key) = @_;
  35         my $list = [];
  36         $self->{pi_config}->each_inbox(\&list_all_i, [ $list, $hide_key ]);
  37         $list;
  38 }
  39
  40 sub list_match_domain_i {
  41         my ($ibx, $arg) = @_;
  42         my ($list, $hide_key, $re) = @$arg;
  43         if (!$ibx->{-hide}->{$hide_key} && grep($re, @{$ibx->{url}})) {
  44                 push @$list, $ibx;
  45         }
  46 }
  47
  48 sub list_match_domain ($$$) {
  49         my ($self, $env, $hide_key) = @_;
  50         my $list = [];
  51         my $host = $env->{HTTP_HOST} // $env->{SERVER_NAME};
  52         $host =~ s/:[0-9]+\z//;
  53         my $arg = [ $list, $hide_key,
  54                 qr!\A(?:https?:)?//\Q$host\E(?::[0-9]+)?/!i ];
  55         $self->{pi_config}->each_inbox(\&list_match_domain_i, $arg);
  56         $list;
  57 }
  58
  59 sub list_404 ($$) { [] }
  60
  61 # TODO: +cgit
  62 my %VALID = (
  63         all => *list_all,
  64         'match=domain' => *list_match_domain,
  65         404 => *list_404,
  66 );
  67
  68 sub set_cb ($$$) {
  69         my ($pi_config, $k, $default) = @_;
  70         my $v = $pi_config->{lc $k} // $default;
  71         $VALID{$v} || do {
  72                 warn <<"";
  73 `$v' is not a valid value for `$k'
  74 $k be one of `all', `match=domain', or `404'
  75
  76                 $VALID{$default};
  77         };
  78 }
  79
  80 sub new {
  81         my ($class, $www) = @_;
  82         my $pi_config = $www->{pi_config};
  83         bless {
  84                 pi_config => $pi_config,
  85                 style => $www->style("\0"),
  86                 www_cb => set_cb($pi_config, 'publicInbox.wwwListing', 404),
  87                 manifest_cb => set_cb($pi_config, 'publicInbox.grokManifest',
  88                                         'match=domain'),
  89         }, $class;
  90 }
  91
  92 sub ibx_entry {
  93         my ($mtime, $ibx, $env) = @_;
  94         my $ts = PublicInbox::View::fmt_ts($mtime);
  95         my $url = prurl($env, $ibx->{url});
  96         my $tmp = <<"";
  97 * $ts - $url
  98   ${\$ibx->description}
  99
 100         if (defined(my $info_url = $ibx->{infourl})) {
 101                 $tmp .= '  ' . prurl($env, $info_url) . "\n";
 102         }
 103         $tmp;
 104 }
 105
 106 sub html ($$) {
 107         my ($env, $list) = @_;
 108         my $title = 'public-inbox';
 109         my $out = '';
 110         my $code = 404;
 111         if (@$list) {
 112                 $title .= ' - listing';
 113                 $code = 200;
 114
 115                 # Schwartzian transform since Inbox->modified is expensive
 116                 @$list = sort {
 117                         $b->[0] <=> $a->[0]
 118                 } map { [ $_->modified, $_ ] } @$list;
 119
 120                 my $tmp = join("\n", map { ibx_entry(@$_, $env) } @$list);
 121                 my $l = PublicInbox::Linkify->new;
 122                 $out = '<pre>'.$l->to_html($tmp).'</pre><hr>';
 123         }
 124         $out = "<html><head><title>$title</title></head><body>" . $out;
 125         $out .= '<pre>'. PublicInbox::WwwStream::code_footer($env) .
 126                 '</pre></body></html>';
 127
 128         my $h = [ 'Content-Type', 'text/html; charset=UTF-8' ];
 129         [ $code, $h, [ $out ] ];
 130 }
 131
 132 sub fingerprint ($) {
 133         my ($git) = @_;
 134         # TODO: convert to qspawn for fairness when there's
 135         # thousands of repos
 136         my ($fh, $pid) = $git->popen('show-ref');
 137         my $dig = Digest::SHA->new(1);
 138         while (read($fh, my $buf, 65536)) {
 139                 $dig->add($buf);
 140         }
 141         close $fh;
 142         waitpid($pid, 0);
 143         return if $?; # empty, uninitialized git repo
 144         $dig->hexdigest;
 145 }
 146
 147 sub manifest_add ($$;$$) {
 148         my ($manifest, $ibx, $epoch, $default_desc) = @_;
 149         my $url_path = "/$ibx->{name}";
 150         my $git_dir = $ibx->{inboxdir};
 151         if (defined $epoch) {
 152                 $git_dir .= "/git/$epoch.git";
 153                 $url_path .= "/git/$epoch.git";
 154         }
 155         return unless -d $git_dir;
 156         my $git = PublicInbox::Git->new($git_dir);
 157         my $fingerprint = fingerprint($git) or return; # no empty repos
 158
 159         chomp(my $owner = $git->qx('config', 'gitweb.owner'));
 160         chomp(my $desc = try_cat("$git_dir/description"));
 161         $owner = undef if $owner eq '';
 162         $desc = 'Unnamed repository' if $desc eq '';
 163
 164         # templates/hooks--update.sample and git-multimail in git.git
 165         # only match "Unnamed repository", not the full contents of
 166         # templates/this--description in git.git
 167         if ($desc =~ /\AUnnamed repository/) {
 168                 $desc = "$default_desc [epoch $epoch]" if defined($epoch);
 169         }
 170
 171         my $reference;
 172         chomp(my $alt = try_cat("$git_dir/objects/info/alternates"));
 173         if ($alt) {
 174                 # n.b.: GitPython doesn't seem to handle comments or C-quoted
 175                 # strings like native git does; and we don't for now, either.
 176                 my @alt = split(/\n+/, $alt);
 177
 178                 # grokmirror only supports 1 alternate for "reference",
 179                 if (scalar(@alt) == 1) {
 180                         my $objdir = "$git_dir/objects";
 181                         $reference = File::Spec->rel2abs($alt[0], $objdir);
 182                         $reference =~ s!/[^/]+/?\z!!; # basename
 183                 }
 184         }
 185         $manifest->{-abs2urlpath}->{$git_dir} = $url_path;
 186         my $modified = $git->modified;
 187         if ($modified > $manifest->{-mtime}) {
 188                 $manifest->{-mtime} = $modified;
 189         }
 190         $manifest->{$url_path} = {
 191                 owner => $owner,
 192                 reference => $reference,
 193                 description => $desc,
 194                 modified => $modified,
 195                 fingerprint => $fingerprint,
 196         };
 197 }
 198
 199 # manifest.js.gz
 200 sub js ($$) {
 201         my ($env, $list) = @_;
 202         # $json won't be defined if IO::Compress::Gzip is missing
 203         $json or return [ 404, [], [] ];
 204
 205         my $manifest = { -abs2urlpath => {}, -mtime => 0 };
 206         for my $ibx (@$list) {
 207                 if (defined(my $max = $ibx->max_git_epoch)) {
 208                         my $desc = $ibx->description;
 209                         for my $epoch (0..$max) {
 210                                 manifest_add($manifest, $ibx, $epoch, $desc);
 211                         }
 212                 } else {
 213                         manifest_add($manifest, $ibx);
 214                 }
 215         }
 216         my $abs2urlpath = delete $manifest->{-abs2urlpath};
 217         my $mtime = delete $manifest->{-mtime};
 218         while (my ($url_path, $repo) = each %$manifest) {
 219                 defined(my $abs = $repo->{reference}) or next;
 220                 $repo->{reference} = $abs2urlpath->{$abs};
 221         }
 222         my $out;
 223         IO::Compress::Gzip::gzip(\($json->encode($manifest)) => \$out);
 224         $manifest = undef;
 225         [ 200, [ qw(Content-Type application/gzip),
 226                  'Last-Modified', time2str($mtime),
 227                  'Content-Length', bytes::length($out) ], [ $out ] ];
 228 }
 229
 230 # not really a stand-alone PSGI app, but maybe it could be...
 231 sub call {
 232         my ($self, $env) = @_;
 233
 234         if ($env->{PATH_INFO} eq '/manifest.js.gz') {
 235                 # grokmirror uses relative paths, so it's domain-dependent
 236                 my $list = $self->{manifest_cb}->($self, $env, 'manifest');
 237                 js($env, $list);
 238         } else { # /
 239                 my $list = $self->{www_cb}->($self, $env, 'www');
 240                 html($env, $list);
 241         }
 242 }
 243
 244 1;