lib/PublicInbox/WwwListing.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Provide an HTTP-accessible listing of inboxes.
   5 # Used by PublicInbox::WWW
   6 package PublicInbox::WwwListing;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::Hval qw(ascii_html prurl);
  10 use PublicInbox::Linkify;
  11 use PublicInbox::View;
  12 use PublicInbox::Inbox;
  13 use bytes ();
  14 use HTTP::Date qw(time2str);
  15 require Digest::SHA;
  16 require File::Spec;
  17 *try_cat = \&PublicInbox::Inbox::try_cat;
  18
  19 sub list_all_i {
  20         my ($ibx, $arg) = @_;
  21         my ($list, $hide_key) = @$arg;
  22         push @$list, $ibx unless $ibx->{-hide}->{$hide_key};
  23 }
  24
  25 sub list_all ($$$) {
  26         my ($self, $env, $hide_key) = @_;
  27         my $list = [];
  28         $self->{pi_config}->each_inbox(\&list_all_i, [ $list, $hide_key ]);
  29         $list;
  30 }
  31
  32 sub list_match_domain_i {
  33         my ($ibx, $arg) = @_;
  34         my ($list, $hide_key, $re) = @$arg;
  35         if (!$ibx->{-hide}->{$hide_key} && grep($re, @{$ibx->{url}})) {
  36                 push @$list, $ibx;
  37         }
  38 }
  39
  40 sub list_match_domain ($$$) {
  41         my ($self, $env, $hide_key) = @_;
  42         my $list = [];
  43         my $host = $env->{HTTP_HOST} // $env->{SERVER_NAME};
  44         $host =~ s/:[0-9]+\z//;
  45         my $arg = [ $list, $hide_key,
  46                 qr!\A(?:https?:)?//\Q$host\E(?::[0-9]+)?/!i ];
  47         $self->{pi_config}->each_inbox(\&list_match_domain_i, $arg);
  48         $list;
  49 }
  50
  51 sub list_404 ($$) { [] }
  52
  53 # TODO: +cgit
  54 my %VALID = (
  55         all => *list_all,
  56         'match=domain' => *list_match_domain,
  57         404 => *list_404,
  58 );
  59
  60 sub set_cb ($$$) {
  61         my ($pi_config, $k, $default) = @_;
  62         my $v = $pi_config->{lc $k} // $default;
  63         $VALID{$v} || do {
  64                 warn <<"";
  65 `$v' is not a valid value for `$k'
  66 $k be one of `all', `match=domain', or `404'
  67
  68                 $VALID{$default};
  69         };
  70 }
  71
  72 sub new {
  73         my ($class, $www) = @_;
  74         my $pi_config = $www->{pi_config};
  75         bless {
  76                 pi_config => $pi_config,
  77                 style => $www->style("\0"),
  78                 www_cb => set_cb($pi_config, 'publicInbox.wwwListing', 404),
  79                 manifest_cb => set_cb($pi_config, 'publicInbox.grokManifest',
  80                                         'match=domain'),
  81         }, $class;
  82 }
  83
  84 sub ibx_entry {
  85         my ($mtime, $ibx, $env) = @_;
  86         my $ts = PublicInbox::View::fmt_ts($mtime);
  87         my $url = prurl($env, $ibx->{url});
  88         my $tmp = <<"";
  89 * $ts - $url
  90   ${\$ibx->description}
  91
  92         if (defined(my $info_url = $ibx->{infourl})) {
  93                 $tmp .= '  ' . prurl($env, $info_url) . "\n";
  94         }
  95         $tmp;
  96 }
  97
  98 sub html ($$) {
  99         my ($env, $list) = @_;
 100         my $title = 'public-inbox';
 101         my $out = '';
 102         my $code = 404;
 103         if (@$list) {
 104                 $title .= ' - listing';
 105                 $code = 200;
 106
 107                 # Schwartzian transform since Inbox->modified is expensive
 108                 @$list = sort {
 109                         $b->[0] <=> $a->[0]
 110                 } map { [ $_->modified, $_ ] } @$list;
 111
 112                 my $tmp = join("\n", map { ibx_entry(@$_, $env) } @$list);
 113                 my $l = PublicInbox::Linkify->new;
 114                 $l->linkify_1($tmp);
 115                 $out = '<pre>'.$l->linkify_2(ascii_html($tmp)).'</pre><hr>';
 116         }
 117         $out = "<html><head><title>$title</title></head><body>" . $out;
 118         $out .= '<pre>'. PublicInbox::WwwStream::code_footer($env) .
 119                 '</pre></body></html>';
 120
 121         my $h = [ 'Content-Type', 'text/html; charset=UTF-8' ];
 122         [ $code, $h, [ $out ] ];
 123 }
 124
 125 my $json;
 126 sub _json () {
 127         for my $mod (qw(JSON::MaybeXS JSON JSON::PP)) {
 128                 eval "require $mod" or next;
 129                 # ->ascii encodes non-ASCII to "\uXXXX"
 130                 return $mod->new->ascii(1);
 131         }
 132         die;
 133 }
 134
 135 sub fingerprint ($) {
 136         my ($git) = @_;
 137         # TODO: convert to qspawn for fairness when there's
 138         # thousands of repos
 139         my ($fh, $pid) = $git->popen('show-ref') or
 140                 die "popen($git->{git_dir} show-ref) failed: $!";
 141
 142         my $dig = Digest::SHA->new(1);
 143         while (read($fh, my $buf, 65536)) {
 144                 $dig->add($buf);
 145         }
 146         close $fh;
 147         waitpid($pid, 0);
 148         return if $?; # empty, uninitialized git repo
 149         $dig->hexdigest;
 150 }
 151
 152 sub manifest_add ($$;$$) {
 153         my ($manifest, $ibx, $epoch, $default_desc) = @_;
 154         my $url_path = "/$ibx->{name}";
 155         my $git_dir = $ibx->{inboxdir};
 156         if (defined $epoch) {
 157                 $git_dir .= "/git/$epoch.git";
 158                 $url_path .= "/git/$epoch.git";
 159         }
 160         return unless -d $git_dir;
 161         my $git = PublicInbox::Git->new($git_dir);
 162         my $fingerprint = fingerprint($git) or return; # no empty repos
 163
 164         chomp(my $owner = $git->qx('config', 'gitweb.owner'));
 165         chomp(my $desc = try_cat("$git_dir/description"));
 166         $owner = undef if $owner eq '';
 167         $desc = 'Unnamed repository' if $desc eq '';
 168
 169         # templates/hooks--update.sample and git-multimail in git.git
 170         # only match "Unnamed repository", not the full contents of
 171         # templates/this--description in git.git
 172         if ($desc =~ /\AUnnamed repository/) {
 173                 $desc = "$default_desc [epoch $epoch]" if defined($epoch);
 174         }
 175
 176         my $reference;
 177         chomp(my $alt = try_cat("$git_dir/objects/info/alternates"));
 178         if ($alt) {
 179                 # n.b.: GitPython doesn't seem to handle comments or C-quoted
 180                 # strings like native git does; and we don't for now, either.
 181                 my @alt = split(/\n+/, $alt);
 182
 183                 # grokmirror only supports 1 alternate for "reference",
 184                 if (scalar(@alt) == 1) {
 185                         my $objdir = "$git_dir/objects";
 186                         $reference = File::Spec->rel2abs($alt[0], $objdir);
 187                         $reference =~ s!/[^/]+/?\z!!; # basename
 188                 }
 189         }
 190         $manifest->{-abs2urlpath}->{$git_dir} = $url_path;
 191         my $modified = $git->modified;
 192         if ($modified > $manifest->{-mtime}) {
 193                 $manifest->{-mtime} = $modified;
 194         }
 195         $manifest->{$url_path} = {
 196                 owner => $owner,
 197                 reference => $reference,
 198                 description => $desc,
 199                 modified => $modified,
 200                 fingerprint => $fingerprint,
 201         };
 202 }
 203
 204 # manifest.js.gz
 205 sub js ($$) {
 206         my ($env, $list) = @_;
 207         eval { require IO::Compress::Gzip } or return [ 404, [], [] ];
 208
 209         my $manifest = { -abs2urlpath => {}, -mtime => 0 };
 210         for my $ibx (@$list) {
 211                 if (defined(my $max = $ibx->max_git_epoch)) {
 212                         my $desc = $ibx->description;
 213                         for my $epoch (0..$max) {
 214                                 manifest_add($manifest, $ibx, $epoch, $desc);
 215                         }
 216                 } else {
 217                         manifest_add($manifest, $ibx);
 218                 }
 219         }
 220         my $abs2urlpath = delete $manifest->{-abs2urlpath};
 221         my $mtime = delete $manifest->{-mtime};
 222         while (my ($url_path, $repo) = each %$manifest) {
 223                 defined(my $abs = $repo->{reference}) or next;
 224                 $repo->{reference} = $abs2urlpath->{$abs};
 225         }
 226         my $out;
 227         IO::Compress::Gzip::gzip(\(($json ||= _json())->encode($manifest)) =>
 228                                  \$out);
 229         $manifest = undef;
 230         [ 200, [ qw(Content-Type application/gzip),
 231                  'Last-Modified', time2str($mtime),
 232                  'Content-Length', bytes::length($out) ], [ $out ] ];
 233 }
 234
 235 # not really a stand-alone PSGI app, but maybe it could be...
 236 sub call {
 237         my ($self, $env) = @_;
 238
 239         if ($env->{PATH_INFO} eq '/manifest.js.gz') {
 240                 # grokmirror uses relative paths, so it's domain-dependent
 241                 my $list = $self->{manifest_cb}->($self, $env, 'manifest');
 242                 js($env, $list);
 243         } else { # /
 244                 my $list = $self->{www_cb}->($self, $env, 'www');
 245                 html($env, $list);
 246         }
 247 }
 248
 249 1;