lib/PublicInbox/WwwListing.pm

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Provide an HTTP-accessible listing of inboxes.
   5 # Used by PublicInbox::WWW
   6 package PublicInbox::WwwListing;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::Hval qw(ascii_html prurl);
  10 use PublicInbox::Linkify;
  11 use PublicInbox::View;
  12 use PublicInbox::Inbox;
  13 use bytes ();
  14 use HTTP::Date qw(time2str);
  15 require Digest::SHA;
  16 require File::Spec;
  17 *try_cat = \&PublicInbox::Inbox::try_cat;
  18
  19 sub list_all_i {
  20         my ($ibx, $arg) = @_;
  21         my ($list, $hide_key) = @$arg;
  22         push @$list, $ibx unless $ibx->{-hide}->{$hide_key};
  23 }
  24
  25 sub list_all ($$$) {
  26         my ($self, $env, $hide_key) = @_;
  27         my $list = [];
  28         $self->{pi_config}->each_inbox(\&list_all_i, [ $list, $hide_key ]);
  29         $list;
  30 }
  31
  32 sub list_match_domain_i {
  33         my ($ibx, $arg) = @_;
  34         my ($list, $hide_key, $re) = @$arg;
  35         if (!$ibx->{-hide}->{$hide_key} && grep($re, @{$ibx->{url}})) {
  36                 push @$list, $ibx;
  37         }
  38 }
  39
  40 sub list_match_domain ($$$) {
  41         my ($self, $env, $hide_key) = @_;
  42         my $list = [];
  43         my $host = $env->{HTTP_HOST} // $env->{SERVER_NAME};
  44         $host =~ s/:[0-9]+\z//;
  45         my $arg = [ $list, $hide_key,
  46                 qr!\A(?:https?:)?//\Q$host\E(?::[0-9]+)?/!i ];
  47         $self->{pi_config}->each_inbox(\&list_match_domain_i, $arg);
  48         $list;
  49 }
  50
  51 sub list_404 ($$) { [] }
  52
  53 # TODO: +cgit
  54 my %VALID = (
  55         all => *list_all,
  56         'match=domain' => *list_match_domain,
  57         404 => *list_404,
  58 );
  59
  60 sub set_cb ($$$) {
  61         my ($pi_config, $k, $default) = @_;
  62         my $v = $pi_config->{lc $k} // $default;
  63         $VALID{$v} || do {
  64                 warn <<"";
  65 `$v' is not a valid value for `$k'
  66 $k be one of `all', `match=domain', or `404'
  67
  68                 $VALID{$default};
  69         };
  70 }
  71
  72 sub new {
  73         my ($class, $www) = @_;
  74         my $pi_config = $www->{pi_config};
  75         bless {
  76                 pi_config => $pi_config,
  77                 style => $www->style("\0"),
  78                 www_cb => set_cb($pi_config, 'publicInbox.wwwListing', 404),
  79                 manifest_cb => set_cb($pi_config, 'publicInbox.grokManifest',
  80                                         'match=domain'),
  81         }, $class;
  82 }
  83
  84 sub ibx_entry {
  85         my ($mtime, $ibx, $env) = @_;
  86         my $ts = PublicInbox::View::fmt_ts($mtime);
  87         my $url = prurl($env, $ibx->{url});
  88         my $tmp = <<"";
  89 * $ts - $url
  90   ${\$ibx->description}
  91
  92         if (defined(my $info_url = $ibx->{infourl})) {
  93                 $tmp .= '  ' . prurl($env, $info_url) . "\n";
  94         }
  95         $tmp;
  96 }
  97
  98 sub html ($$) {
  99         my ($env, $list) = @_;
 100         my $title = 'public-inbox';
 101         my $out = '';
 102         my $code = 404;
 103         if (@$list) {
 104                 $title .= ' - listing';
 105                 $code = 200;
 106
 107                 # Schwartzian transform since Inbox->modified is expensive
 108                 @$list = sort {
 109                         $b->[0] <=> $a->[0]
 110                 } map { [ $_->modified, $_ ] } @$list;
 111
 112                 my $tmp = join("\n", map { ibx_entry(@$_, $env) } @$list);
 113                 my $l = PublicInbox::Linkify->new;
 114                 $out = '<pre>'.$l->to_html($tmp).'</pre><hr>';
 115         }
 116         $out = "<html><head><title>$title</title></head><body>" . $out;
 117         $out .= '<pre>'. PublicInbox::WwwStream::code_footer($env) .
 118                 '</pre></body></html>';
 119
 120         my $h = [ 'Content-Type', 'text/html; charset=UTF-8' ];
 121         [ $code, $h, [ $out ] ];
 122 }
 123
 124 my $json;
 125 sub _json () {
 126         for my $mod (qw(JSON::MaybeXS JSON JSON::PP)) {
 127                 eval "require $mod" or next;
 128                 # ->ascii encodes non-ASCII to "\uXXXX"
 129                 return $mod->new->ascii(1);
 130         }
 131         die;
 132 }
 133
 134 sub fingerprint ($) {
 135         my ($git) = @_;
 136         # TODO: convert to qspawn for fairness when there's
 137         # thousands of repos
 138         my ($fh, $pid) = $git->popen('show-ref');
 139         my $dig = Digest::SHA->new(1);
 140         while (read($fh, my $buf, 65536)) {
 141                 $dig->add($buf);
 142         }
 143         close $fh;
 144         waitpid($pid, 0);
 145         return if $?; # empty, uninitialized git repo
 146         $dig->hexdigest;
 147 }
 148
 149 sub manifest_add ($$;$$) {
 150         my ($manifest, $ibx, $epoch, $default_desc) = @_;
 151         my $url_path = "/$ibx->{name}";
 152         my $git_dir = $ibx->{inboxdir};
 153         if (defined $epoch) {
 154                 $git_dir .= "/git/$epoch.git";
 155                 $url_path .= "/git/$epoch.git";
 156         }
 157         return unless -d $git_dir;
 158         my $git = PublicInbox::Git->new($git_dir);
 159         my $fingerprint = fingerprint($git) or return; # no empty repos
 160
 161         chomp(my $owner = $git->qx('config', 'gitweb.owner'));
 162         chomp(my $desc = try_cat("$git_dir/description"));
 163         $owner = undef if $owner eq '';
 164         $desc = 'Unnamed repository' if $desc eq '';
 165
 166         # templates/hooks--update.sample and git-multimail in git.git
 167         # only match "Unnamed repository", not the full contents of
 168         # templates/this--description in git.git
 169         if ($desc =~ /\AUnnamed repository/) {
 170                 $desc = "$default_desc [epoch $epoch]" if defined($epoch);
 171         }
 172
 173         my $reference;
 174         chomp(my $alt = try_cat("$git_dir/objects/info/alternates"));
 175         if ($alt) {
 176                 # n.b.: GitPython doesn't seem to handle comments or C-quoted
 177                 # strings like native git does; and we don't for now, either.
 178                 my @alt = split(/\n+/, $alt);
 179
 180                 # grokmirror only supports 1 alternate for "reference",
 181                 if (scalar(@alt) == 1) {
 182                         my $objdir = "$git_dir/objects";
 183                         $reference = File::Spec->rel2abs($alt[0], $objdir);
 184                         $reference =~ s!/[^/]+/?\z!!; # basename
 185                 }
 186         }
 187         $manifest->{-abs2urlpath}->{$git_dir} = $url_path;
 188         my $modified = $git->modified;
 189         if ($modified > $manifest->{-mtime}) {
 190                 $manifest->{-mtime} = $modified;
 191         }
 192         $manifest->{$url_path} = {
 193                 owner => $owner,
 194                 reference => $reference,
 195                 description => $desc,
 196                 modified => $modified,
 197                 fingerprint => $fingerprint,
 198         };
 199 }
 200
 201 # manifest.js.gz
 202 sub js ($$) {
 203         my ($env, $list) = @_;
 204         eval { require IO::Compress::Gzip } or return [ 404, [], [] ];
 205
 206         my $manifest = { -abs2urlpath => {}, -mtime => 0 };
 207         for my $ibx (@$list) {
 208                 if (defined(my $max = $ibx->max_git_epoch)) {
 209                         my $desc = $ibx->description;
 210                         for my $epoch (0..$max) {
 211                                 manifest_add($manifest, $ibx, $epoch, $desc);
 212                         }
 213                 } else {
 214                         manifest_add($manifest, $ibx);
 215                 }
 216         }
 217         my $abs2urlpath = delete $manifest->{-abs2urlpath};
 218         my $mtime = delete $manifest->{-mtime};
 219         while (my ($url_path, $repo) = each %$manifest) {
 220                 defined(my $abs = $repo->{reference}) or next;
 221                 $repo->{reference} = $abs2urlpath->{$abs};
 222         }
 223         my $out;
 224         IO::Compress::Gzip::gzip(\(($json ||= _json())->encode($manifest)) =>
 225                                  \$out);
 226         $manifest = undef;
 227         [ 200, [ qw(Content-Type application/gzip),
 228                  'Last-Modified', time2str($mtime),
 229                  'Content-Length', bytes::length($out) ], [ $out ] ];
 230 }
 231
 232 # not really a stand-alone PSGI app, but maybe it could be...
 233 sub call {
 234         my ($self, $env) = @_;
 235
 236         if ($env->{PATH_INFO} eq '/manifest.js.gz') {
 237                 # grokmirror uses relative paths, so it's domain-dependent
 238                 my $list = $self->{manifest_cb}->($self, $env, 'manifest');
 239                 js($env, $list);
 240         } else { # /
 241                 my $list = $self->{www_cb}->($self, $env, 'www');
 242                 html($env, $list);
 243         }
 244 }
 245
 246 1;