lib/PublicInbox/WwwStatic.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This package can either be a PSGI response body for a static file
   5 # OR a standalone PSGI app which returns the above PSGI response body
   6 # (or an HTML directory listing).
   7 #
   8 # It encapsulates the "autoindex", "index", and "gzip_static"
   9 # functionality of nginx.
  10 package PublicInbox::WwwStatic;
  11 use strict;
  12 use parent qw(Exporter);
  13 use bytes ();
  14 use Fcntl qw(SEEK_SET O_RDONLY O_NONBLOCK);
  15 use POSIX qw(strftime);
  16 use HTTP::Date qw(time2str);
  17 use HTTP::Status qw(status_message);
  18 use Errno qw(EACCES ENOTDIR ENOENT);
  19 use URI::Escape qw(uri_escape_utf8);
  20 use PublicInbox::Hval qw(ascii_html);
  21 use Plack::MIME;
  22 our @EXPORT_OK = qw(@NO_CACHE r path_info_raw);
  23
  24 our @NO_CACHE = ('Expires', 'Fri, 01 Jan 1980 00:00:00 GMT',
  25                 'Pragma', 'no-cache',
  26                 'Cache-Control', 'no-cache, max-age=0, must-revalidate');
  27
  28 our $STYLE = <<'EOF';
  29 <style>
  30 @media screen {
  31         *{background:#000;color:#ccc}
  32         a{color:#69f;text-decoration:none}
  33         a:visited{color:#96f}
  34 }
  35 @media screen AND (prefers-color-scheme:light) {
  36         *{background:#fff;color:#333}
  37         a{color:#00f;text-decoration:none}
  38         a:visited{color:#808}
  39 }
  40 </style>
  41 EOF
  42
  43 $STYLE =~ s/^\s*//gm;
  44 $STYLE =~ tr/\n//d;
  45
  46 sub r ($;$) {
  47         my ($code, $msg) = @_;
  48         $msg ||= status_message($code);
  49         [ $code, [ qw(Content-Type text/plain), 'Content-Length', length($msg),
  50                 @NO_CACHE ],
  51           [ $msg ] ]
  52 }
  53
  54 sub getline_response ($$$$$) {
  55         my ($env, $in, $off, $len, $path) = @_;
  56         my $r = bless {}, __PACKAGE__;
  57         if ($env->{'pi-httpd.async'}) { # public-inbox-httpd-only mode
  58                 $env->{'psgix.no-compress'} = 1; # do not chunk response
  59                 %$r = ( bypass => [$in, $off, $len, $env->{'psgix.io'}] );
  60         } else {
  61                 %$r = ( in => $in, off => $off, len => $len, path => $path );
  62         }
  63         $r;
  64 }
  65
  66 sub setup_range {
  67         my ($env, $in, $h, $beg, $end, $size) = @_;
  68         my $code = 200;
  69         my $len = $size;
  70         if ($beg eq '') {
  71                 if ($end ne '') { # "bytes=-$end" => last N bytes
  72                         $beg = $size - $end;
  73                         $beg = 0 if $beg < 0;
  74                         $end = $size - 1;
  75                         $code = 206;
  76                 } else {
  77                         $code = 416;
  78                 }
  79         } else {
  80                 if ($beg > $size) {
  81                         $code = 416;
  82                 } elsif ($end eq '' || $end >= $size) {
  83                         $end = $size - 1;
  84                         $code = 206;
  85                 } elsif ($end < $size) {
  86                         $code = 206;
  87                 } else {
  88                         $code = 416;
  89                 }
  90         }
  91         if ($code == 206) {
  92                 $len = $end - $beg + 1;
  93                 if ($len <= 0) {
  94                         $code = 416;
  95                 } else {
  96                         push @$h, qw(Accept-Ranges bytes Content-Range);
  97                         push @$h, "bytes $beg-$end/$size";
  98
  99                         # FIXME: Plack::Middleware::Deflater bug?
 100                         $env->{'psgix.no-compress'} = 1;
 101                 }
 102         }
 103         if ($code == 416) {
 104                 push @$h, 'Content-Range', "bytes */$size";
 105                 return [ 416, $h, [] ];
 106         }
 107         ($code, $beg, $len);
 108 }
 109
 110 # returns a PSGI arrayref response iff .gz and non-.gz mtimes match
 111 sub try_gzip_static ($$$$) {
 112         my ($env, $h, $path, $type) = @_;
 113         return unless ($env->{HTTP_ACCEPT_ENCODING} // '') =~ /\bgzip\b/i;
 114         my $mtime;
 115         return unless -f $path && defined(($mtime = (stat(_))[9]));
 116         my $gz = "$path.gz";
 117         return unless -f $gz && (stat(_))[9] == $mtime;
 118         my $res = response($env, $h, $gz, $type);
 119         return if ($res->[0] > 300 || $res->[0] < 200);
 120         push @{$res->[1]}, qw(Cache-Control no-transform Content-Encoding gzip);
 121         $res;
 122 }
 123
 124 sub response ($$$;$) {
 125         my ($env, $h, $path, $type) = @_;
 126         $type //= Plack::MIME->mime_type($path) // 'application/octet-stream';
 127         if ($path !~ /\.gz\z/i) {
 128                 if (my $res = try_gzip_static($env, $h, $path, $type)) {
 129                         return $res;
 130                 }
 131         }
 132
 133         my $in;
 134         if ($env->{REQUEST_METHOD} eq 'HEAD') {
 135                 return r(404) unless -f $path && -r _; # in case it's a FIFO :P
 136         } else { # GET, callers should've already filtered out other methods
 137                 if (!sysopen($in, $path, O_RDONLY|O_NONBLOCK)) {
 138                         return r(404) if $! == ENOENT || $! == ENOTDIR;
 139                         return r(403) if $! == EACCES;
 140                         return r(500);
 141                 }
 142                 return r(404) unless -f $in;
 143         }
 144         my $size = -s _; # bare "_" reuses "struct stat" from "-f" above
 145         my $mtime = time2str((stat(_))[9]);
 146
 147         if (my $ims = $env->{HTTP_IF_MODIFIED_SINCE}) {
 148                 return [ 304, [], [] ] if $mtime eq $ims;
 149         }
 150
 151         my $len = $size;
 152         my $code = 200;
 153         push @$h, 'Content-Type', $type;
 154         my $off = 0;
 155         if (($env->{HTTP_RANGE} || '') =~ /\bbytes=([0-9]*)-([0-9]*)\z/) {
 156                 ($code, $off, $len) = setup_range($env, $in, $h, $1, $2, $size);
 157                 return $code if ref($code);
 158         }
 159         push @$h, 'Content-Length', $len, 'Last-Modified', $mtime;
 160         [ $code, $h, $in ? getline_response($env, $in, $off, $len, $path) : [] ]
 161 }
 162
 163 # called by PSGI servers on each response chunk:
 164 sub getline {
 165         my ($self) = @_;
 166
 167         # avoid buffering, by becoming the buffer! (public-inbox-httpd)
 168         if (my $tmpio = delete $self->{bypass}) {
 169                 my $http = pop @$tmpio; # PublicInbox::HTTP
 170                 push @{$http->{wbuf}}, $tmpio; # [ $in, $off, $len ]
 171                 $http->flush_write;
 172                 return; # undef, EOF
 173         }
 174
 175         # generic PSGI runs this:
 176         my $len = $self->{len} or return; # undef, tells server we're done
 177         my $n = 8192;
 178         $n = $len if $len < $n;
 179         sysseek($self->{in}, $self->{off}, SEEK_SET) or
 180                         die "sysseek ($self->{path}): $!";
 181         my $r = sysread($self->{in}, my $buf, $n);
 182         if (defined $r && $r > 0) { # success!
 183                 $self->{len} = $len - $r;
 184                 $self->{off} += $r;
 185                 return $buf;
 186         }
 187         my $m = defined $r ? "EOF with $len bytes left" : "read error: $!";
 188         die "$self->{path} $m, dropping client socket\n";
 189 }
 190
 191 sub close {} # noop, called by PSGI server, just let everything go out-of-scope
 192
 193 # OO interface for use as a Plack app
 194 sub new {
 195         my ($class, %opt) = @_;
 196         my $index = $opt{'index'} // [ 'index.html' ];
 197         $index = [ $index ] if defined($index) && ref($index) ne 'ARRAY';
 198         $index = undef if scalar(@$index) == 0;
 199         my $style = $opt{style};
 200         if (defined $style) {
 201                 $style = \$style unless ref($style);
 202         }
 203         my $docroot = $opt{docroot};
 204         die "`docroot' not set" unless defined($docroot) && $docroot ne '';
 205         bless {
 206                 docroot => $docroot,
 207                 index => $index,
 208                 autoindex => $opt{autoindex},
 209                 style => $style // \$STYLE,
 210         }, $class;
 211 }
 212
 213 # PATH_INFO is decoded, and we want the undecoded original
 214 my %path_re_cache;
 215 sub path_info_raw ($) {
 216         my ($env) = @_;
 217         my $sn = $env->{SCRIPT_NAME};
 218         my $re = $path_re_cache{$sn} ||= do {
 219                 $sn = '/'.$sn unless index($sn, '/') == 0;
 220                 $sn =~ s!/\z!!;
 221                 qr!\A(?:https?://[^/]+)?\Q$sn\E(/[^\?\#]+)!;
 222         };
 223         $env->{REQUEST_URI} =~ $re ? $1 : $env->{PATH_INFO};
 224 }
 225
 226 sub redirect_slash ($) {
 227         my ($env) = @_;
 228         my $url = $env->{'psgi.url_scheme'} . '://';
 229         my $host_port = $env->{HTTP_HOST} //
 230                 "$env->{SERVER_NAME}:$env->{SERVER_PORT}";
 231         $url .= $host_port . path_info_raw($env) . '/';
 232         my $body = "Redirecting to $url\n";
 233         [ 302, [ qw(Content-Type text/plain), 'Location', $url,
 234                 'Content-Length', length($body) ], [ $body ] ]
 235 }
 236
 237 sub human_size ($) {
 238         my ($size) = @_;
 239         my $suffix = '';
 240         for my $s (qw(K M G T P)) {
 241                 last if $size < 1024;
 242                 $size /= 1024;
 243                 if ($size <= 1024) {
 244                         $suffix = $s;
 245                         last;
 246                 }
 247         }
 248         sprintf('%lu', $size).$suffix;
 249 }
 250
 251 # by default, this returns "index.html" if it exists for a given directory
 252 # It'll generate a directory listing, (autoindex).
 253 # May be disabled by setting autoindex => 0
 254 sub dir_response ($$$) {
 255         my ($self, $env, $fs_path) = @_;
 256         if (my $index = $self->{'index'}) { # serve index.html or similar
 257                 for my $html (@$index) {
 258                         my $p = $fs_path . $html;
 259                         my $res = response($env, [], $p);
 260                         return $res if $res->[0] != 404;
 261                 }
 262         }
 263         return r(404) unless $self->{autoindex};
 264         opendir(my $dh, $fs_path) or do {
 265                 return r(404) if ($! == ENOENT || $! == ENOTDIR);
 266                 return r(403) if $! == EACCES;
 267                 return r(500);
 268         };
 269         my @entries = grep(!/\A\./, readdir($dh));
 270         $dh = undef;
 271         my (%dirs, %other, %want_gz);
 272         my $path_info = $env->{PATH_INFO};
 273         push @entries, '..' if $path_info ne '/';
 274         for my $base (@entries) {
 275                 my $href = ascii_html(uri_escape_utf8($base));
 276                 my $name = ascii_html($base);
 277                 my @st = stat($fs_path . $base) or next; # unlikely
 278                 my ($gzipped, $uncompressed, $hsize);
 279                 my $entry = '';
 280                 my $mtime = $st[9];
 281                 if (-d _) {
 282                         $href .= '/';
 283                         $name .= '/';
 284                         $hsize = '-';
 285                         $dirs{"$base\0$mtime"} = \$entry;
 286                 } elsif (-f _) {
 287                         $other{"$base\0$mtime"} = \$entry;
 288                         if ($base !~ /\.gz\z/i) {
 289                                 $want_gz{"$base.gz\0$mtime"} = undef;
 290                         }
 291                         $hsize = human_size($st[7]);
 292                 } else {
 293                         next;
 294                 }
 295                 # 54 = 80 - (SP length(strftime(%Y-%m-%d %k:%M)) SP human_size)
 296                 $hsize = sprintf('% 8s', $hsize);
 297                 my $pad = 54 - length($name);
 298                 $pad = 1 if $pad <= 0;
 299                 $entry .= qq(<a\nhref="$href">$name</a>) . (' ' x $pad);
 300                 $mtime = strftime('%Y-%m-%d %k:%M', gmtime($mtime));
 301                 $entry .= $mtime . $hsize;
 302         }
 303
 304         # filter out '.gz' files as long as the mtime matches the
 305         # uncompressed version
 306         delete(@other{keys %want_gz});
 307         @entries = ((map { ${$dirs{$_}} } sort keys %dirs),
 308                         (map { ${$other{$_}} } sort keys %other));
 309
 310         my $path_info_html = ascii_html($path_info);
 311         my $body = "<html><head><title>Index of $path_info_html</title>" .
 312                 ${$self->{style}} .
 313                 "</head><body><pre>Index of $path_info_html</pre><hr><pre>\n";
 314         $body .= join("\n", @entries) . "</pre><hr></body></html>\n";
 315         [ 200, [ qw(Content-Type text/html
 316                         Content-Length), bytes::length($body) ], [ $body ] ]
 317 }
 318
 319 sub call { # PSGI app endpoint
 320         my ($self, $env) = @_;
 321         return r(405) if $env->{REQUEST_METHOD} !~ /\A(?:GET|HEAD)\z/;
 322         my $path_info = $env->{PATH_INFO};
 323         return r(403) if index($path_info, "\0") >= 0;
 324         my (@parts) = split(m!/+!, $path_info, -1);
 325         return r(403) if grep(/\A(?:\.\.)\z/, @parts) || $parts[0] ne '';
 326
 327         my $fs_path = join('/', $self->{docroot}, @parts);
 328         return dir_response($self, $env, $fs_path) if $parts[-1] eq '';
 329
 330         my $res = response($env, [], $fs_path);
 331         $res->[0] == 404 && -d $fs_path ? redirect_slash($env) : $res;
 332 }
 333
 334 1;