lib/PublicInbox/WwwStatic.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 package PublicInbox::WwwStatic;
   5 use strict;
   6 use Fcntl qw(:seek);
   7
   8 sub prepare_range {
   9         my ($env, $in, $h, $beg, $end, $size) = @_;
  10         my $code = 200;
  11         my $len = $size;
  12         if ($beg eq '') {
  13                 if ($end ne '') { # "bytes=-$end" => last N bytes
  14                         $beg = $size - $end;
  15                         $beg = 0 if $beg < 0;
  16                         $end = $size - 1;
  17                         $code = 206;
  18                 } else {
  19                         $code = 416;
  20                 }
  21         } else {
  22                 if ($beg > $size) {
  23                         $code = 416;
  24                 } elsif ($end eq '' || $end >= $size) {
  25                         $end = $size - 1;
  26                         $code = 206;
  27                 } elsif ($end < $size) {
  28                         $code = 206;
  29                 } else {
  30                         $code = 416;
  31                 }
  32         }
  33         if ($code == 206) {
  34                 $len = $end - $beg + 1;
  35                 if ($len <= 0) {
  36                         $code = 416;
  37                 } else {
  38                         sysseek($in, $beg, SEEK_SET) or return [ 500, [], [] ];
  39                         push @$h, qw(Accept-Ranges bytes Content-Range);
  40                         push @$h, "bytes $beg-$end/$size";
  41
  42                         # FIXME: Plack::Middleware::Deflater bug?
  43                         $env->{'psgix.no-compress'} = 1;
  44                 }
  45         }
  46         ($code, $len);
  47 }
  48
  49 sub response {
  50         my ($env, $h, $path, $type) = @_;
  51         return unless -f $path && -r _; # just in case it's a FIFO :P
  52
  53         # TODO: If-Modified-Since and Last-Modified?
  54         open my $in, '<', $path or return;
  55         my $size = -s $in;
  56         my $len = $size;
  57         my $code = 200;
  58         push @$h, 'Content-Type', $type;
  59         if (($env->{HTTP_RANGE} || '') =~ /\bbytes=([0-9]*)-([0-9]*)\z/) {
  60                 ($code, $len) = prepare_range($env, $in, $h, $1, $2, $size);
  61                 if ($code == 416) {
  62                         push @$h, 'Content-Range', "bytes */$size";
  63                         return [ 416, $h, [] ];
  64                 }
  65         }
  66         push @$h, 'Content-Length', $len;
  67         my $body = bless {
  68                 initial_rd => 65536,
  69                 len => $len,
  70                 in => $in,
  71                 path => $path,
  72                 env => $env,
  73         }, __PACKAGE__;
  74         [ $code, $h, $body ];
  75 }
  76
  77 # called by PSGI servers:
  78 sub getline {
  79         my ($self) = @_;
  80         my $len = $self->{len};
  81         return if $len == 0;
  82         my $n = delete($self->{initial_rd}) // 8192;
  83         $n = $len if $len < $n;
  84         my $r = sysread($self->{in}, my $buf, $n);
  85         if (!defined $r) {
  86                 $self->{env}->{'psgi.errors'}->print(
  87                         "$self->{path} read error: $!\n");
  88         } elsif ($r > 0) { # success!
  89                 $self->{len} = $len - $r;
  90                 return $buf;
  91         } else {
  92                 $self->{env}->{'psgi.errors'}->print(
  93                         "$self->{path} EOF with $len bytes left\n");
  94         }
  95
  96         # drop the client on error
  97         if (my $io = $self->{env}->{'psgix.io'}) {
  98                 $io->close; # this is PublicInbox::DS::close
  99         }
 100         undef;
 101 }
 102
 103 sub close {} # noop, just let everything go out-of-scope
 104
 105 1;