lib/PublicInbox/WwwStream.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # HTML body stream for which yields getline+close methods
   5 #
   6 # public-inbox-httpd favors "getline" response bodies to take a
   7 # "pull"-based approach to feeding slow clients (as opposed to a
   8 # more common "push" model)
   9 package PublicInbox::WwwStream;
  10 use strict;
  11 use warnings;
  12 use bytes (); # length
  13 use PublicInbox::Hval qw(ascii_html prurl);
  14 our $TOR_URL = 'https://www.torproject.org/';
  15 our $CODE_URL = 'https://public-inbox.org/public-inbox.git';
  16
  17 # noop for HTTP.pm (and any other PSGI servers)
  18 sub close {}
  19
  20 sub base_url ($) {
  21         my $ctx = shift;
  22         my $base_url = $ctx->{-inbox}->base_url($ctx->{env});
  23         chop $base_url; # no trailing slash for clone
  24         $base_url;
  25 }
  26
  27 sub new {
  28         my ($class, $ctx, $cb) = @_;
  29
  30         bless {
  31                 nr => 0,
  32                 cb => $cb,
  33                 ctx => $ctx,
  34                 base_url => base_url($ctx),
  35         }, $class;
  36 }
  37
  38 sub response {
  39         my ($class, $ctx, $code, $cb) = @_;
  40         [ $code, [ 'Content-Type', 'text/html; charset=UTF-8' ],
  41           $class->new($ctx, $cb) ]
  42 }
  43
  44 sub _html_top ($) {
  45         my ($self) = @_;
  46         my $ctx = $self->{ctx};
  47         my $ibx = $ctx->{-inbox};
  48         my $desc = ascii_html($ibx->description);
  49         my $title = delete($ctx->{-title_html}) // $desc;
  50         my $upfx = $ctx->{-upfx} || '';
  51         my $help = $upfx.'_/text/help';
  52         my $color = $upfx.'_/text/color';
  53         my $atom = $ctx->{-atom} || $upfx.'new.atom';
  54         my $top = "<b>$desc</b>";
  55         my $links = "<a\nhref=\"$help\">help</a> / ".
  56                         "<a\nhref=\"$color\">color</a> / ".
  57                         "<a\nhref=\"$atom\">Atom feed</a>";
  58         if ($ibx->search) {
  59                 my $q_val = delete($ctx->{-q_value_html}) // '';
  60                 $q_val = qq(\nvalue="$q_val") if $q_val ne '';
  61                 # XXX gross, for SearchView.pm
  62                 my $extra = delete($ctx->{-extra_form_html}) // '';
  63                 my $action = $upfx eq '' ? './' : $upfx;
  64                 $top = qq{<form\naction="$action"><pre>$top} .
  65                           qq{\n<input\nname=q\ntype=text$q_val />} .
  66                           $extra .
  67                           qq{<input\ntype=submit\nvalue=search />} .
  68                           ' ' . $links .
  69                           q{</pre></form>}
  70         } else {
  71                 $top = '<pre>' . $top . "\n" . $links . '</pre>';
  72         }
  73         "<html><head><title>$title</title>" .
  74                 qq(<link\nrel=alternate\ntitle="Atom feed"\n).
  75                 qq(href="$atom"\ntype="application/atom+xml"/>) .
  76                 $ctx->{www}->style($upfx) .
  77                 '</head><body>'. $top . (delete($ctx->{-html_tip}) // '');
  78 }
  79
  80 sub code_footer ($) {
  81         my ($env) = @_;
  82         my $u = prurl($env, $CODE_URL);
  83         qq(AGPL code for this site: git clone <a\nhref="$u">$u</a>)
  84 }
  85
  86 sub _html_end {
  87         my ($self) = @_;
  88         my $urls = 'Archives are clonable:';
  89         my $ctx = $self->{ctx};
  90         my $ibx = $ctx->{-inbox};
  91         my $desc = ascii_html($ibx->description);
  92
  93         my @urls;
  94         my $http = $self->{base_url};
  95         my $max = $ibx->max_git_epoch;
  96         my $dir = (split(m!/!, $http))[-1];
  97         my %seen = ($http => 1);
  98         if (defined($max)) { # v2
  99                 for my $i (0..$max) {
 100                         # old parts my be deleted:
 101                         -d "$ibx->{inboxdir}/git/$i.git" or next;
 102                         my $url = "$http/$i";
 103                         $seen{$url} = 1;
 104                         push @urls, "$url $dir/git/$i.git";
 105                 }
 106         } else { # v1
 107                 push @urls, $http;
 108         }
 109
 110         # FIXME: epoch splits can be different in other repositories,
 111         # use the "cloneurl" file as-is for now:
 112         foreach my $u (@{$ibx->cloneurl}) {
 113                 next if $seen{$u}++;
 114                 push @urls, $u =~ /\Ahttps?:/ ? qq(<a\nhref="$u">$u</a>) : $u;
 115         }
 116
 117         if (defined($max) || scalar(@urls) > 1) {
 118                 $urls .= "\n" .
 119                         join("\n", map { "\tgit clone --mirror $_" } @urls);
 120         } else {
 121                 $urls .= " git clone --mirror $urls[0]";
 122         }
 123         if (defined $max) {
 124                 my $addrs = $ibx->{address};
 125                 $addrs = join(' ', @$addrs) if ref($addrs) eq 'ARRAY';
 126                 $urls .=  <<EOF
 127
 128
 129         # If you have public-inbox 1.1+ installed, you may
 130         # initialize and index your mirror using the following commands:
 131         public-inbox-init -V2 $ibx->{name} $dir/ $http \\
 132                 $addrs
 133         public-inbox-index $dir
 134 EOF
 135         } else { # v1
 136                 $urls .= "\n";
 137         }
 138
 139         my $cfg_link = ($ctx->{-upfx} // '').'_/text/config/raw';
 140         $urls .= qq(\nExample <a\nhref="$cfg_link">config snippet</a> for mirrors\n);
 141         my @nntp = map { qq(<a\nhref="$_">$_</a>) } @{$ibx->nntp_url};
 142         if (@nntp) {
 143                 $urls .= "\n";
 144                 $urls .= @nntp == 1 ? 'Newsgroup' : 'Newsgroups are';
 145                 $urls .= ' available over NNTP:';
 146                 $urls .= "\n\t" . join("\n\t", @nntp) . "\n";
 147         }
 148         if ($urls =~ m!\b[^:]+://\w+\.onion/!) {
 149                 $urls .= "\n note: .onion URLs require Tor: ";
 150                 $urls .= qq[<a\nhref="$TOR_URL">$TOR_URL</a>];
 151         }
 152         '<hr><pre>'.join("\n\n",
 153                 $desc,
 154                 $urls,
 155                 code_footer($ctx->{env})
 156         ).'</pre></body></html>';
 157 }
 158
 159 # callback for HTTP.pm (and any other PSGI servers)
 160 sub getline {
 161         my ($self) = @_;
 162         my $nr = $self->{nr}++;
 163
 164         return _html_top($self) if $nr == 0;
 165
 166         if (my $middle = $self->{cb}) {
 167                 $middle = $middle->($nr, $self->{ctx}) and return $middle;
 168         }
 169
 170         delete $self->{cb} ? _html_end($self) : undef;
 171 }
 172
 173 sub oneshot {
 174         my ($ctx, $code, $sref) = @_;
 175         my $self = bless {
 176                 ctx => $ctx,
 177                 base_url => base_url($ctx),
 178         }, __PACKAGE__;
 179         my @x = (_html_top($self), $sref ? $$sref : (), _html_end($self));
 180         my $len = 0;
 181         $len += bytes::length($_) for @x;
 182         [ $code, [
 183                 'Content-Type' => 'text/html; charset=UTF-8',
 184                 'Content-Length' => $len
 185         ], \@x ];
 186 }
 187
 188 1;