lib/PublicInbox/WwwStream.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # HTML body stream for which yields getline+close methods
   5 #
   6 # public-inbox-httpd favors "getline" response bodies to take a
   7 # "pull"-based approach to feeding slow clients (as opposed to a
   8 # more common "push" model)
   9 package PublicInbox::WwwStream;
  10 use strict;
  11 use warnings;
  12 use base qw(Exporter);
  13 our @EXPORT_OK = qw(html_oneshot);
  14 use bytes (); # length
  15 use PublicInbox::Hval qw(ascii_html prurl);
  16 our $TOR_URL = 'https://www.torproject.org/';
  17 our $CODE_URL = 'https://public-inbox.org/public-inbox.git';
  18
  19 # noop for HTTP.pm (and any other PSGI servers)
  20 sub close {}
  21
  22 sub base_url ($) {
  23         my $ctx = shift;
  24         my $base_url = $ctx->{-inbox}->base_url($ctx->{env});
  25         chop $base_url; # no trailing slash for clone
  26         $base_url;
  27 }
  28
  29 sub new {
  30         my ($class, $ctx, $cb) = @_;
  31
  32         bless {
  33                 nr => 0,
  34                 cb => $cb,
  35                 ctx => $ctx,
  36                 base_url => base_url($ctx),
  37         }, $class;
  38 }
  39
  40 sub response {
  41         my ($class, $ctx, $code, $cb) = @_;
  42         [ $code, [ 'Content-Type', 'text/html; charset=UTF-8' ],
  43           $class->new($ctx, $cb) ]
  44 }
  45
  46 sub _html_top ($) {
  47         my ($self) = @_;
  48         my $ctx = $self->{ctx};
  49         my $ibx = $ctx->{-inbox};
  50         my $desc = ascii_html($ibx->description);
  51         my $title = delete($ctx->{-title_html}) // $desc;
  52         my $upfx = $ctx->{-upfx} || '';
  53         my $help = $upfx.'_/text/help';
  54         my $color = $upfx.'_/text/color';
  55         my $atom = $ctx->{-atom} || $upfx.'new.atom';
  56         my $top = "<b>$desc</b>";
  57         my $links = "<a\nhref=\"$help\">help</a> / ".
  58                         "<a\nhref=\"$color\">color</a> / ".
  59                         "<a\nhref=\"$atom\">Atom feed</a>";
  60         if ($ibx->search) {
  61                 my $q_val = delete($ctx->{-q_value_html}) // '';
  62                 $q_val = qq(\nvalue="$q_val") if $q_val ne '';
  63                 # XXX gross, for SearchView.pm
  64                 my $extra = delete($ctx->{-extra_form_html}) // '';
  65                 my $action = $upfx eq '' ? './' : $upfx;
  66                 $top = qq{<form\naction="$action"><pre>$top} .
  67                           qq{\n<input\nname=q\ntype=text$q_val />} .
  68                           $extra .
  69                           qq{<input\ntype=submit\nvalue=search />} .
  70                           ' ' . $links .
  71                           q{</pre></form>}
  72         } else {
  73                 $top = '<pre>' . $top . "\n" . $links . '</pre>';
  74         }
  75         "<html><head><title>$title</title>" .
  76                 qq(<link\nrel=alternate\ntitle="Atom feed"\n).
  77                 qq(href="$atom"\ntype="application/atom+xml"/>) .
  78                 $ctx->{www}->style($upfx) .
  79                 '</head><body>'. $top . (delete($ctx->{-html_tip}) // '');
  80 }
  81
  82 sub code_footer ($) {
  83         my ($env) = @_;
  84         my $u = prurl($env, $CODE_URL);
  85         qq(AGPL code for this site: git clone <a\nhref="$u">$u</a>)
  86 }
  87
  88 sub _html_end {
  89         my ($self) = @_;
  90         my $urls = 'Archives are clonable:';
  91         my $ctx = $self->{ctx};
  92         my $ibx = $ctx->{-inbox};
  93         my $desc = ascii_html($ibx->description);
  94
  95         my @urls;
  96         my $http = $self->{base_url};
  97         my $max = $ibx->max_git_epoch;
  98         my $dir = (split(m!/!, $http))[-1];
  99         my %seen = ($http => 1);
 100         if (defined($max)) { # v2
 101                 for my $i (0..$max) {
 102                         # old parts my be deleted:
 103                         -d "$ibx->{inboxdir}/git/$i.git" or next;
 104                         my $url = "$http/$i";
 105                         $seen{$url} = 1;
 106                         push @urls, "$url $dir/git/$i.git";
 107                 }
 108         } else { # v1
 109                 push @urls, $http;
 110         }
 111
 112         # FIXME: epoch splits can be different in other repositories,
 113         # use the "cloneurl" file as-is for now:
 114         foreach my $u (@{$ibx->cloneurl}) {
 115                 next if $seen{$u}++;
 116                 push @urls, $u =~ /\Ahttps?:/ ? qq(<a\nhref="$u">$u</a>) : $u;
 117         }
 118
 119         if (defined($max) || scalar(@urls) > 1) {
 120                 $urls .= "\n" .
 121                         join("\n", map { "\tgit clone --mirror $_" } @urls);
 122         } else {
 123                 $urls .= " git clone --mirror $urls[0]";
 124         }
 125         if (defined $max) {
 126                 my $addrs = $ibx->{address};
 127                 $addrs = join(' ', @$addrs) if ref($addrs) eq 'ARRAY';
 128                 $urls .=  <<EOF
 129
 130
 131         # If you have public-inbox 1.1+ installed, you may
 132         # initialize and index your mirror using the following commands:
 133         public-inbox-init -V2 $ibx->{name} $dir/ $http \\
 134                 $addrs
 135         public-inbox-index $dir
 136 EOF
 137         } else { # v1
 138                 $urls .= "\n";
 139         }
 140
 141         my $cfg_link = ($ctx->{-upfx} // '').'_/text/config/raw';
 142         $urls .= qq(\nExample <a\nhref="$cfg_link">config snippet</a> for mirrors\n);
 143         my @nntp = map { qq(<a\nhref="$_">$_</a>) } @{$ibx->nntp_url};
 144         if (@nntp) {
 145                 $urls .= "\n";
 146                 $urls .= @nntp == 1 ? 'Newsgroup' : 'Newsgroups are';
 147                 $urls .= ' available over NNTP:';
 148                 $urls .= "\n\t" . join("\n\t", @nntp) . "\n";
 149         }
 150         if ($urls =~ m!\b[^:]+://\w+\.onion/!) {
 151                 $urls .= "\n note: .onion URLs require Tor: ";
 152                 $urls .= qq[<a\nhref="$TOR_URL">$TOR_URL</a>];
 153         }
 154         '<hr><pre>'.join("\n\n",
 155                 $desc,
 156                 $urls,
 157                 code_footer($ctx->{env})
 158         ).'</pre></body></html>';
 159 }
 160
 161 # callback for HTTP.pm (and any other PSGI servers)
 162 sub getline {
 163         my ($self) = @_;
 164         my $nr = $self->{nr}++;
 165
 166         return _html_top($self) if $nr == 0;
 167
 168         if (my $middle = $self->{cb}) {
 169                 $middle = $middle->($nr, $self->{ctx}) and return $middle;
 170         }
 171
 172         delete $self->{cb} ? _html_end($self) : undef;
 173 }
 174
 175 sub html_oneshot ($$;$) {
 176         my ($ctx, $code, $sref) = @_;
 177         my $self = bless {
 178                 ctx => $ctx,
 179                 base_url => base_url($ctx),
 180         }, __PACKAGE__;
 181         my @x = (_html_top($self), $sref ? $$sref : (), _html_end($self));
 182         my $len = 0;
 183         $len += bytes::length($_) for @x;
 184         [ $code, [
 185                 'Content-Type' => 'text/html; charset=UTF-8',
 186                 'Content-Length' => $len
 187         ], \@x ];
 188 }
 189
 190 1;