lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which popen_rd);
   7 use PublicInbox::Over;
   8 use PublicInbox::SearchIdx;
   9 use File::Temp 0.19 (); # ->newdir
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12 use POSIX ();
  13
  14 # support testing with dev versions of Xapian which installs
  15 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  16 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  17 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  18
  19 sub commit_changes ($$$$) {
  20         my ($ibx, $im, $tmp, $opt) = @_;
  21         my $reshard = $opt->{reshard};
  22         my $reindex = $opt->{reindex};
  23
  24         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  25         my @old_shard;
  26
  27         while (my ($old, $newdir) = each %$tmp) {
  28                 next if $old eq ''; # no invalid paths
  29                 my @st = stat($old);
  30                 if (!@st && !defined($opt->{reshard})) {
  31                         die "failed to stat($old): $!";
  32                 }
  33
  34                 my $new = $newdir->dirname if defined($newdir);
  35                 my $over = "$old/over.sqlite3";
  36                 if (-f $over) { # only for v1, v2 over is untouched
  37                         defined $new or die "BUG: $over exists when culling v2";
  38                         $over = PublicInbox::Over->new($over);
  39                         my $tmp_over = "$new/over.sqlite3";
  40                         $over->connect->sqlite_backup_to_file($tmp_over);
  41                         $over = undef;
  42                 }
  43
  44                 if (!defined($new)) { # culled shard
  45                         push @old_shard, $old;
  46                         next;
  47                 }
  48
  49                 if (@st) {
  50                         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  51                         rename($old, "$new/old") or
  52                                         die "rename $old => $new/old: $!\n";
  53                 }
  54                 # Xtmpdir->DESTROY won't remove $new after this:
  55                 rename($new, $old) or die "rename $new => $old: $!\n";
  56                 if (@st) {
  57                         my $prev = "$old/old";
  58                         remove_tree($prev) or
  59                                 die "failed to remove $prev: $!\n";
  60                 }
  61         }
  62         remove_tree(@old_shard);
  63         $tmp = undef;
  64         if (!$opt->{-coarse_lock}) {
  65                 $opt->{-skip_lock} = 1;
  66
  67                 if ($im->can('count_shards')) {
  68                         my $pr = $opt->{-progress};
  69                         my $n = $im->count_shards;
  70                         if (defined $reshard && $n != $reshard) {
  71                                 die
  72 "BUG: counted $n shards after resharding to $reshard";
  73                         }
  74                         my $prev = $im->{shards};
  75                         if ($pr && $prev != $n) {
  76                                 $pr->("shard count changed: $prev => $n\n");
  77                                 $im->{shards} = $n;
  78                         }
  79                 }
  80
  81                 PublicInbox::Admin::index_inbox($ibx, $im, $opt);
  82         }
  83 }
  84
  85 sub cb_spawn {
  86         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  87         defined(my $pid = fork) or die "fork: $!";
  88         return $pid if $pid > 0;
  89         $cb->($args, $opt);
  90         POSIX::_exit(0);
  91 }
  92
  93 sub runnable_or_die ($) {
  94         my ($exe) = @_;
  95         which($exe) or die "$exe not found in PATH\n";
  96 }
  97
  98 sub prepare_reindex ($$$) {
  99         my ($ibx, $im, $reindex) = @_;
 100         if ($ibx->version == 1) {
 101                 my $dir = $ibx->search->xdir(1);
 102                 my $xdb = $PublicInbox::Search::X{Database}->new($dir);
 103                 if (my $lc = $xdb->get_metadata('last_commit')) {
 104                         $reindex->{from} = $lc;
 105                 }
 106         } else { # v2
 107                 my $max;
 108                 $im->git_dir_latest(\$max) or return;
 109                 my $from = $reindex->{from};
 110                 my $mm = $ibx->mm;
 111                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 112                 foreach my $i (0..$max) {
 113                         $from->[$i] = $mm->last_commit_xap($v, $i);
 114                 }
 115         }
 116 }
 117
 118 sub same_fs_or_die ($$) {
 119         my ($x, $y) = @_;
 120         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
 121         die "$x and $y reside on different filesystems\n";
 122 }
 123
 124 sub process_queue {
 125         my ($queue, $cb, $max, $opt) = @_;
 126         if ($max <= 1) {
 127                 while (defined(my $args = shift @$queue)) {
 128                         $cb->($args, $opt);
 129                 }
 130                 return;
 131         }
 132
 133         # run in parallel:
 134         my %pids;
 135         while (@$queue) {
 136                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 137                         my $args = shift @$queue;
 138                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 139                 }
 140
 141                 while (scalar keys %pids) {
 142                         my $pid = waitpid(-1, 0);
 143                         my $args = delete $pids{$pid};
 144                         die join(' ', @$args)." failed: $?\n" if $?;
 145                 }
 146         }
 147 }
 148
 149 sub setup_signals () {
 150         # http://www.tldp.org/LDP/abs/html/exitcodes.html
 151         $SIG{INT} = sub { exit(130) };
 152         $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = sub { exit(1) };
 153 }
 154
 155 sub run {
 156         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 157         my $cb = \&${\"PublicInbox::Xapcmd::$task"};
 158         PublicInbox::Admin::progress_prepare($opt ||= {});
 159         my $dir = $ibx->{inboxdir} or die "no inboxdir in inbox\n";
 160         runnable_or_die($XAPIAN_COMPACT) if $opt->{compact};
 161         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 162         my $from; # per-epoch ranges
 163
 164         if (!$opt->{-coarse_lock}) {
 165                 $reindex = $opt->{reindex} = {};
 166                 $from = $reindex->{from} = [];
 167                 require PublicInbox::SearchIdx;
 168                 PublicInbox::SearchIdx::load_xapian_writable();
 169         }
 170
 171         $ibx->umask_prepare;
 172         my $old = $ibx->search->xdir(1);
 173         -d $old or die "$old does not exist\n";
 174
 175         my $tmp = {};
 176         my @q;
 177         my $reshard = $opt->{reshard};
 178         if (defined $reshard && $reshard <= 0) {
 179                 die "--reshard must be a positive number\n";
 180         }
 181
 182         local %SIG = %SIG;
 183         setup_signals();
 184
 185         # we want temporary directories to be as deep as possible,
 186         # so v2 shards can keep "xap$SCHEMA_VERSION" on a separate FS.
 187         if ($ibx->version == 1) {
 188                 if (defined $reshard) {
 189                         warn
 190 "--reshard=$reshard ignored for v1 $ibx->{inboxdir}\n";
 191                 }
 192                 my $dir = dirname($old);
 193                 same_fs_or_die($dir, $old);
 194                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 195                 my $wip = File::Temp->newdir("xapian$v-XXXXXXXX", DIR => $dir);
 196                 $tmp->{$old} = $wip;
 197                 push @q, [ $old, $wip ];
 198         } else {
 199                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 200                 my @old_shards;
 201                 while (defined(my $dn = readdir($dh))) {
 202                         if ($dn =~ /\A[0-9]+\z/) {
 203                                 push @old_shards, $dn;
 204                         } elsif ($dn eq '.' || $dn eq '..') {
 205                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 206                         } else {
 207                                 warn "W: skipping unknown dir: $old/$dn\n"
 208                         }
 209                 }
 210                 die "No Xapian shards found in $old\n" unless @old_shards;
 211
 212                 my ($src, $max_shard);
 213                 if (!defined($reshard) || $reshard == scalar(@old_shards)) {
 214                         # 1:1 copy
 215                         $max_shard = scalar(@old_shards) - 1;
 216                 } else {
 217                         # M:N copy
 218                         $max_shard = $reshard - 1;
 219                         $src = [ map { "$old/$_" } @old_shards ];
 220                 }
 221                 foreach my $dn (0..$max_shard) {
 222                         my $tmpl = "$dn-XXXXXXXX";
 223                         my $wip = File::Temp->newdir($tmpl, DIR => $old);
 224                         same_fs_or_die($old, $wip->dirname);
 225                         my $cur = "$old/$dn";
 226                         push @q, [ $src // $cur , $wip ];
 227                         $tmp->{$cur} = $wip;
 228                 }
 229                 # mark old shards to be unlinked
 230                 if ($src) {
 231                         $tmp->{$_} ||= undef for @$src;
 232                 }
 233         }
 234         my $max = $opt->{jobs} || scalar(@q);
 235         $ibx->with_umask(sub {
 236                 my $im = $ibx->importer(0);
 237                 $im->lock_acquire;
 238
 239                 # fine-grained locking if we prepare for reindex
 240                 if (!$opt->{-coarse_lock}) {
 241                         prepare_reindex($ibx, $im, $reindex);
 242                         $im->lock_release;
 243                 }
 244
 245                 $ibx->cleanup;
 246                 process_queue(\@q, $cb, $max, $opt);
 247                 $im->lock_acquire if !$opt->{-coarse_lock};
 248                 commit_changes($ibx, $im, $tmp, $opt);
 249         });
 250 }
 251
 252 sub cpdb_retryable ($$) {
 253         my ($src, $pfx) = @_;
 254         if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 255                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 256                 $src->reopen;
 257                 return 1;
 258         }
 259         if ($@) {
 260                 warn "$pfx E: ", ref($@), "\n";
 261                 die;
 262         }
 263         0;
 264 }
 265
 266 sub progress_pfx ($) {
 267         my ($wip) = @_; # tempdir v2: ([0-9])+-XXXXXXXX
 268         my @p = split('/', $wip);
 269
 270         # return "xap15/0" for v2, or "xapian15" for v1:
 271         ($p[-1] =~ /\A([0-9]+)/) ? "$p[-2]/$1" : $p[-1];
 272 }
 273
 274 # xapian-compact wrapper
 275 sub compact ($$) {
 276         my ($args, $opt) = @_;
 277         my ($src, $newdir) = @$args;
 278         my $dst = ref($newdir) ? $newdir->dirname : $newdir;
 279         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 280         my $pr = $opt->{-progress};
 281         my $rdr = {};
 282
 283         foreach my $fd (0..2) {
 284                 defined(my $dfd = $opt->{$fd}) or next;
 285                 $rdr->{$fd} = $dfd;
 286         }
 287
 288         # we rely on --no-renumber to keep docids synched to NNTP
 289         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 290         for my $sw (qw(no-full fuller)) {
 291                 push @$cmd, "--$sw" if $opt->{$sw};
 292         }
 293         for my $sw (qw(blocksize)) {
 294                 defined(my $v = $opt->{$sw}) or next;
 295                 push @$cmd, "--$sw", $v;
 296         }
 297         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 298         push @$cmd, $src, $dst;
 299         my $rd = popen_rd($cmd, undef, $rdr);
 300         while (<$rd>) {
 301                 if ($pr) {
 302                         s/\r/\r$pfx /g;
 303                         $pr->("$pfx $_");
 304                 }
 305         }
 306         close $rd or die join(' ', @$cmd)." failed: $?n";
 307 }
 308
 309 sub cpdb_loop ($$$;$$) {
 310         my ($src, $dst, $pr_data, $cur_shard, $reshard) = @_;
 311         my ($pr, $fmt, $nr, $pfx);
 312         if ($pr_data) {
 313                 $pr = $pr_data->{pr};
 314                 $fmt = $pr_data->{fmt};
 315                 $nr = \($pr_data->{nr});
 316                 $pfx = $pr_data->{pfx};
 317         }
 318
 319         my ($it, $end);
 320         do {
 321                 eval {
 322                         $it = $src->postlist_begin('');
 323                         $end = $src->postlist_end('');
 324                 };
 325         } while (cpdb_retryable($src, $pfx));
 326
 327         do {
 328                 eval {
 329                         for (; $it != $end; $it++) {
 330                                 my $docid = $it->get_docid;
 331                                 if (defined $reshard) {
 332                                         my $dst_shard = $docid % $reshard;
 333                                         next if $dst_shard != $cur_shard;
 334                                 }
 335                                 my $doc = $src->get_document($docid);
 336                                 $dst->replace_document($docid, $doc);
 337                                 if ($pr_data && !(++$$nr  & 1023)) {
 338                                         $pr->(sprintf($fmt, $$nr));
 339                                 }
 340                         }
 341
 342                         # unlike copydatabase(1), we don't copy spelling
 343                         # and synonym data (or other user metadata) since
 344                         # the Perl APIs don't expose iterators for them
 345                         # (and public-inbox does not use those features)
 346                 };
 347         } while (cpdb_retryable($src, $pfx));
 348 }
 349
 350 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 351 # to the overhead of Perl.
 352 sub cpdb ($$) {
 353         my ($args, $opt) = @_;
 354         my ($old, $newdir) = @$args;
 355         my $new = $newdir->dirname;
 356         my ($src, $cur_shard);
 357         my $reshard;
 358         PublicInbox::SearchIdx::load_xapian_writable() or die;
 359         my $XapianDatabase = $PublicInbox::Search::X{Database};
 360         if (ref($old) eq 'ARRAY') {
 361                 ($cur_shard) = ($new =~ m!xap[0-9]+/([0-9]+)\b!);
 362                 defined $cur_shard or
 363                         die "BUG: could not extract shard # from $new";
 364                 $reshard = $opt->{reshard};
 365                 defined $reshard or die 'BUG: got array src w/o --reshard';
 366
 367                 # resharding, M:N copy means have full read access
 368                 foreach (@$old) {
 369                         if ($src) {
 370                                 my $sub = $XapianDatabase->new($_);
 371                                 $src->add_database($sub);
 372                         } else {
 373                                 $src = $XapianDatabase->new($_);
 374                         }
 375                 }
 376         } else {
 377                 $src = $XapianDatabase->new($old);
 378         }
 379
 380         my ($tmp, $ft);
 381         local %SIG = %SIG;
 382         if ($opt->{compact}) {
 383                 my $dir = dirname($new);
 384                 same_fs_or_die($dir, $new);
 385                 $ft = File::Temp->newdir("$new.compact-XXXXXX", DIR => $dir);
 386                 setup_signals();
 387                 $tmp = $ft->dirname;
 388         } else {
 389                 $tmp = $new;
 390         }
 391
 392         # like copydatabase(1), be sure we don't overwrite anything in case
 393         # of other bugs:
 394         my $creat = eval($PublicInbox::Search::Xap.'::DB_CREATE()');
 395         die if $@;
 396         my $XapianWritableDatabase = $PublicInbox::Search::X{WritableDatabase};
 397         my $dst = $XapianWritableDatabase->new($tmp, $creat);
 398         my $pr = $opt->{-progress};
 399         my $pfx = $opt->{-progress_pfx} = progress_pfx($new);
 400         my $pr_data = { pr => $pr, pfx => $pfx, nr => 0 } if $pr;
 401
 402         do {
 403                 eval {
 404                         # update the only metadata key for v1:
 405                         my $lc = $src->get_metadata('last_commit');
 406                         $dst->set_metadata('last_commit', $lc) if $lc;
 407
 408                         # only the first xapian shard (0) gets 'indexlevel'
 409                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 410                                 my $l = $src->get_metadata('indexlevel');
 411                                 if ($l eq 'medium') {
 412                                         $dst->set_metadata('indexlevel', $l);
 413                                 }
 414                         }
 415                         if ($pr_data) {
 416                                 my $tot = $src->get_doccount;
 417
 418                                 # we can only estimate when resharding,
 419                                 # because removed spam causes slight imbalance
 420                                 my $est = '';
 421                                 if (defined $cur_shard && $reshard > 1) {
 422                                         $tot = int($tot/$reshard);
 423                                         $est = 'around ';
 424                                 }
 425                                 my $fmt = "$pfx % ".length($tot)."u/$tot\n";
 426                                 $pr->("$pfx copying $est$tot documents\n");
 427                                 $pr_data->{fmt} = $fmt;
 428                                 $pr_data->{total} = $tot;
 429                         }
 430                 };
 431         } while (cpdb_retryable($src, $pfx));
 432
 433         if (defined $reshard) {
 434                 # we rely on document IDs matching NNTP article number,
 435                 # so we can't have the Xapian sharding DB support rewriting
 436                 # document IDs.  Thus we iterate through each shard
 437                 # individually.
 438                 $src = undef;
 439                 foreach (@$old) {
 440                         my $old = $XapianDatabase->new($_);
 441                         cpdb_loop($old, $dst, $pr_data, $cur_shard, $reshard);
 442                 }
 443         } else {
 444                 cpdb_loop($src, $dst, $pr_data);
 445         }
 446
 447         $pr->(sprintf($pr_data->{fmt}, $pr_data->{nr})) if $pr;
 448         return unless $opt->{compact};
 449
 450         $src = $dst = undef; # flushes and closes
 451
 452         # this is probably the best place to do xapian-compact
 453         # since $dst isn't readable by HTTP or NNTP clients, yet:
 454         compact([ $tmp, $new ], $opt);
 455         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 456 }
 457
 458 1;