lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which popen_rd);
   7 use PublicInbox::Over;
   8 use PublicInbox::SearchIdx;
   9 use File::Temp 0.19 (); # ->newdir
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12 use POSIX ();
  13
  14 # support testing with dev versions of Xapian which installs
  15 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  16 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  17 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  18
  19 sub commit_changes ($$$$) {
  20         my ($ibx, $im, $tmp, $opt) = @_;
  21         my $reshard = $opt->{reshard};
  22         my $reindex = $opt->{reindex};
  23
  24         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  25         my @old_shard;
  26         my $over_chg;
  27
  28         while (my ($old, $newdir) = each %$tmp) {
  29                 next if $old eq ''; # no invalid paths
  30                 my @st = stat($old);
  31                 if (!@st && !defined($opt->{reshard})) {
  32                         die "failed to stat($old): $!";
  33                 }
  34
  35                 my $new = $newdir->dirname if defined($newdir);
  36                 my $over = "$old/over.sqlite3";
  37                 if (-f $over) { # only for v1, v2 over is untouched
  38                         defined $new or die "BUG: $over exists when culling v2";
  39                         $over = PublicInbox::Over->new($over);
  40                         my $tmp_over = "$new/over.sqlite3";
  41                         $over->connect->sqlite_backup_to_file($tmp_over);
  42                         $over = undef;
  43                         $over_chg = 1;
  44                 }
  45
  46                 if (!defined($new)) { # culled shard
  47                         push @old_shard, $old;
  48                         next;
  49                 }
  50
  51                 if (@st) {
  52                         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  53                         rename($old, "$new/old") or
  54                                         die "rename $old => $new/old: $!\n";
  55                 }
  56                 # Xtmpdir->DESTROY won't remove $new after this:
  57                 rename($new, $old) or die "rename $new => $old: $!\n";
  58                 if (@st) {
  59                         my $prev = "$old/old";
  60                         remove_tree($prev) or
  61                                 die "failed to remove $prev: $!\n";
  62                 }
  63         }
  64
  65         # trigger ->check_inodes in read-only daemons
  66         syswrite($im->{lockfh}, '.') if $over_chg;
  67
  68         remove_tree(@old_shard);
  69         $tmp = undef;
  70         if (!$opt->{-coarse_lock}) {
  71                 $opt->{-skip_lock} = 1;
  72
  73                 if ($im->can('count_shards')) {
  74                         my $pr = $opt->{-progress};
  75                         my $n = $im->count_shards;
  76                         if (defined $reshard && $n != $reshard) {
  77                                 die
  78 "BUG: counted $n shards after resharding to $reshard";
  79                         }
  80                         my $prev = $im->{shards};
  81                         if ($pr && $prev != $n) {
  82                                 $pr->("shard count changed: $prev => $n\n");
  83                                 $im->{shards} = $n;
  84                         }
  85                 }
  86
  87                 PublicInbox::Admin::index_inbox($ibx, $im, $opt);
  88         }
  89 }
  90
  91 sub cb_spawn {
  92         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  93         defined(my $pid = fork) or die "fork: $!";
  94         return $pid if $pid > 0;
  95         $cb->($args, $opt);
  96         POSIX::_exit(0);
  97 }
  98
  99 sub runnable_or_die ($) {
 100         my ($exe) = @_;
 101         which($exe) or die "$exe not found in PATH\n";
 102 }
 103
 104 sub prepare_reindex ($$$) {
 105         my ($ibx, $im, $reindex) = @_;
 106         if ($ibx->version == 1) {
 107                 my $dir = $ibx->search->xdir(1);
 108                 my $xdb = $PublicInbox::Search::X{Database}->new($dir);
 109                 if (my $lc = $xdb->get_metadata('last_commit')) {
 110                         $reindex->{from} = $lc;
 111                 }
 112         } else { # v2
 113                 my $max;
 114                 $im->git_dir_latest(\$max) or return;
 115                 my $from = $reindex->{from};
 116                 my $mm = $ibx->mm;
 117                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 118                 foreach my $i (0..$max) {
 119                         $from->[$i] = $mm->last_commit_xap($v, $i);
 120                 }
 121         }
 122 }
 123
 124 sub same_fs_or_die ($$) {
 125         my ($x, $y) = @_;
 126         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
 127         die "$x and $y reside on different filesystems\n";
 128 }
 129
 130 sub process_queue {
 131         my ($queue, $cb, $opt) = @_;
 132         my $max = $opt->{jobs} // scalar(@$queue);
 133         if ($max <= 1) {
 134                 while (defined(my $args = shift @$queue)) {
 135                         $cb->($args, $opt);
 136                 }
 137                 return;
 138         }
 139
 140         # run in parallel:
 141         my %pids;
 142         while (@$queue) {
 143                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 144                         my $args = shift @$queue;
 145                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 146                 }
 147
 148                 while (scalar keys %pids) {
 149                         my $pid = waitpid(-1, 0);
 150                         my $args = delete $pids{$pid};
 151                         if ($args) {
 152                                 die join(' ', @$args)." failed: $?\n" if $?;
 153                         } else {
 154                                 warn "unknown PID($pid) reaped: $?\n";
 155                         }
 156                 }
 157         }
 158 }
 159
 160 sub setup_signals () {
 161         # http://www.tldp.org/LDP/abs/html/exitcodes.html
 162         $SIG{INT} = sub { exit(130) };
 163         $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = sub { exit(1) };
 164 }
 165
 166 sub prepare_run {
 167         my ($ibx, $opt) = @_;
 168         my $tmp = {}; # old shard dir => File::Temp->newdir object or undef
 169         my @queue; # ([old//src,newdir]) - list of args for cpdb() or compact()
 170
 171         my $old = $ibx->search->xdir(1);
 172         -d $old or die "$old does not exist\n";
 173         my $reshard = $opt->{reshard};
 174         if (defined $reshard && $reshard <= 0) {
 175                 die "--reshard must be a positive number\n";
 176         }
 177
 178         # we want temporary directories to be as deep as possible,
 179         # so v2 shards can keep "xap$SCHEMA_VERSION" on a separate FS.
 180         if ($ibx->version == 1) {
 181                 if (defined $reshard) {
 182                         warn
 183 "--reshard=$reshard ignored for v1 $ibx->{inboxdir}\n";
 184                 }
 185                 my $dir = dirname($old);
 186                 same_fs_or_die($dir, $old);
 187                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 188                 my $wip = File::Temp->newdir("xapian$v-XXXXXXXX", DIR => $dir);
 189                 $tmp->{$old} = $wip;
 190                 push @queue, [ $old, $wip ];
 191         } else {
 192                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 193                 my @old_shards;
 194                 while (defined(my $dn = readdir($dh))) {
 195                         if ($dn =~ /\A[0-9]+\z/) {
 196                                 push @old_shards, $dn;
 197                         } elsif ($dn eq '.' || $dn eq '..') {
 198                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 199                         } else {
 200                                 warn "W: skipping unknown dir: $old/$dn\n"
 201                         }
 202                 }
 203                 die "No Xapian shards found in $old\n" unless @old_shards;
 204
 205                 my ($src, $max_shard);
 206                 if (!defined($reshard) || $reshard == scalar(@old_shards)) {
 207                         # 1:1 copy
 208                         $max_shard = scalar(@old_shards) - 1;
 209                 } else {
 210                         # M:N copy
 211                         $max_shard = $reshard - 1;
 212                         $src = [ map { "$old/$_" } @old_shards ];
 213                 }
 214                 foreach my $dn (0..$max_shard) {
 215                         my $tmpl = "$dn-XXXXXXXX";
 216                         my $wip = File::Temp->newdir($tmpl, DIR => $old);
 217                         same_fs_or_die($old, $wip->dirname);
 218                         my $cur = "$old/$dn";
 219                         push @queue, [ $src // $cur , $wip ];
 220                         $tmp->{$cur} = $wip;
 221                 }
 222                 # mark old shards to be unlinked
 223                 if ($src) {
 224                         $tmp->{$_} ||= undef for @$src;
 225                 }
 226         }
 227         ($tmp, \@queue);
 228 }
 229
 230 sub check_compact () { runnable_or_die($XAPIAN_COMPACT) }
 231
 232 sub _run {
 233         my ($ibx, $cb, $opt, $reindex) = @_;
 234         my $im = $ibx->importer(0);
 235         $im->lock_acquire;
 236         my ($tmp, $queue) = prepare_run($ibx, $opt);
 237
 238         # fine-grained locking if we prepare for reindex
 239         if (!$opt->{-coarse_lock}) {
 240                 prepare_reindex($ibx, $im, $reindex);
 241                 $im->lock_release;
 242         }
 243
 244         $ibx->cleanup;
 245         process_queue($queue, $cb, $opt);
 246         $im->lock_acquire if !$opt->{-coarse_lock};
 247         commit_changes($ibx, $im, $tmp, $opt);
 248 }
 249
 250 sub run {
 251         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 252         my $cb = \&${\"PublicInbox::Xapcmd::$task"};
 253         PublicInbox::Admin::progress_prepare($opt ||= {});
 254         defined(my $dir = $ibx->{inboxdir}) or die "no inboxdir defined\n";
 255         -d $dir or die "inboxdir=$dir does not exist\n";
 256         check_compact() if $opt->{compact};
 257         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 258
 259         if (!$opt->{-coarse_lock}) {
 260                 $reindex = $opt->{reindex} = { # per-epoch ranges for v2
 261                         from => $ibx->version == 1 ? '' : [],
 262                 };
 263                 require PublicInbox::SearchIdx;
 264                 PublicInbox::SearchIdx::load_xapian_writable();
 265         }
 266
 267         local %SIG = %SIG;
 268         setup_signals();
 269         $ibx->umask_prepare;
 270         $ibx->with_umask(\&_run, $ibx, $cb, $opt, $reindex);
 271 }
 272
 273 sub cpdb_retryable ($$) {
 274         my ($src, $pfx) = @_;
 275         if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 276                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 277                 $src->reopen;
 278                 return 1;
 279         }
 280         if ($@) {
 281                 warn "$pfx E: ", ref($@), "\n";
 282                 die;
 283         }
 284         0;
 285 }
 286
 287 sub progress_pfx ($) {
 288         my ($wip) = @_; # tempdir v2: ([0-9])+-XXXXXXXX
 289         my @p = split('/', $wip);
 290
 291         # return "xap15/0" for v2, or "xapian15" for v1:
 292         ($p[-1] =~ /\A([0-9]+)/) ? "$p[-2]/$1" : $p[-1];
 293 }
 294
 295 # xapian-compact wrapper
 296 sub compact ($$) {
 297         my ($args, $opt) = @_;
 298         my ($src, $newdir) = @$args;
 299         my $dst = ref($newdir) ? $newdir->dirname : $newdir;
 300         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 301         my $pr = $opt->{-progress};
 302         my $rdr = {};
 303
 304         foreach my $fd (0..2) {
 305                 defined(my $dfd = $opt->{$fd}) or next;
 306                 $rdr->{$fd} = $dfd;
 307         }
 308
 309         # we rely on --no-renumber to keep docids synched to NNTP
 310         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 311         for my $sw (qw(no-full fuller)) {
 312                 push @$cmd, "--$sw" if $opt->{$sw};
 313         }
 314         for my $sw (qw(blocksize)) {
 315                 defined(my $v = $opt->{$sw}) or next;
 316                 push @$cmd, "--$sw", $v;
 317         }
 318         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 319         push @$cmd, $src, $dst;
 320         my $rd = popen_rd($cmd, undef, $rdr);
 321         while (<$rd>) {
 322                 if ($pr) {
 323                         s/\r/\r$pfx /g;
 324                         $pr->("$pfx $_");
 325                 }
 326         }
 327         close $rd or die join(' ', @$cmd)." failed: $?n";
 328 }
 329
 330 sub cpdb_loop ($$$;$$) {
 331         my ($src, $dst, $pr_data, $cur_shard, $reshard) = @_;
 332         my ($pr, $fmt, $nr, $pfx);
 333         if ($pr_data) {
 334                 $pr = $pr_data->{pr};
 335                 $fmt = $pr_data->{fmt};
 336                 $nr = \($pr_data->{nr});
 337                 $pfx = $pr_data->{pfx};
 338         }
 339
 340         my ($it, $end);
 341         do {
 342                 eval {
 343                         $it = $src->postlist_begin('');
 344                         $end = $src->postlist_end('');
 345                 };
 346         } while (cpdb_retryable($src, $pfx));
 347
 348         do {
 349                 eval {
 350                         for (; $it != $end; $it++) {
 351                                 my $docid = $it->get_docid;
 352                                 if (defined $reshard) {
 353                                         my $dst_shard = $docid % $reshard;
 354                                         next if $dst_shard != $cur_shard;
 355                                 }
 356                                 my $doc = $src->get_document($docid);
 357                                 $dst->replace_document($docid, $doc);
 358                                 if ($pr_data && !(++$$nr  & 1023)) {
 359                                         $pr->(sprintf($fmt, $$nr));
 360                                 }
 361                         }
 362
 363                         # unlike copydatabase(1), we don't copy spelling
 364                         # and synonym data (or other user metadata) since
 365                         # the Perl APIs don't expose iterators for them
 366                         # (and public-inbox does not use those features)
 367                 };
 368         } while (cpdb_retryable($src, $pfx));
 369 }
 370
 371 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 372 # to the overhead of Perl.
 373 sub cpdb ($$) {
 374         my ($args, $opt) = @_;
 375         my ($old, $newdir) = @$args;
 376         my $new = $newdir->dirname;
 377         my ($src, $cur_shard);
 378         my $reshard;
 379         PublicInbox::SearchIdx::load_xapian_writable() or die;
 380         my $XapianDatabase = $PublicInbox::Search::X{Database};
 381         if (ref($old) eq 'ARRAY') {
 382                 ($cur_shard) = ($new =~ m!xap[0-9]+/([0-9]+)\b!);
 383                 defined $cur_shard or
 384                         die "BUG: could not extract shard # from $new";
 385                 $reshard = $opt->{reshard};
 386                 defined $reshard or die 'BUG: got array src w/o --reshard';
 387
 388                 # resharding, M:N copy means have full read access
 389                 foreach (@$old) {
 390                         if ($src) {
 391                                 my $sub = $XapianDatabase->new($_);
 392                                 $src->add_database($sub);
 393                         } else {
 394                                 $src = $XapianDatabase->new($_);
 395                         }
 396                 }
 397         } else {
 398                 $src = $XapianDatabase->new($old);
 399         }
 400
 401         my ($tmp, $ft);
 402         local %SIG = %SIG;
 403         if ($opt->{compact}) {
 404                 my $dir = dirname($new);
 405                 same_fs_or_die($dir, $new);
 406                 $ft = File::Temp->newdir("$new.compact-XXXXXX", DIR => $dir);
 407                 setup_signals();
 408                 $tmp = $ft->dirname;
 409         } else {
 410                 $tmp = $new;
 411         }
 412
 413         # like copydatabase(1), be sure we don't overwrite anything in case
 414         # of other bugs:
 415         my $flag = eval($PublicInbox::Search::Xap.'::DB_CREATE()');
 416         die if $@;
 417         my $XapianWritableDatabase = $PublicInbox::Search::X{WritableDatabase};
 418         $flag |= $PublicInbox::SearchIdx::DB_NO_SYNC if !$opt->{sync};
 419         my $dst = $XapianWritableDatabase->new($tmp, $flag);
 420         my $pr = $opt->{-progress};
 421         my $pfx = $opt->{-progress_pfx} = progress_pfx($new);
 422         my $pr_data = { pr => $pr, pfx => $pfx, nr => 0 } if $pr;
 423
 424         do {
 425                 eval {
 426                         # update the only metadata key for v1:
 427                         my $lc = $src->get_metadata('last_commit');
 428                         $dst->set_metadata('last_commit', $lc) if $lc;
 429
 430                         # only the first xapian shard (0) gets 'indexlevel'
 431                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 432                                 my $l = $src->get_metadata('indexlevel');
 433                                 if ($l eq 'medium') {
 434                                         $dst->set_metadata('indexlevel', $l);
 435                                 }
 436                         }
 437                         if ($pr_data) {
 438                                 my $tot = $src->get_doccount;
 439
 440                                 # we can only estimate when resharding,
 441                                 # because removed spam causes slight imbalance
 442                                 my $est = '';
 443                                 if (defined $cur_shard && $reshard > 1) {
 444                                         $tot = int($tot/$reshard);
 445                                         $est = 'around ';
 446                                 }
 447                                 my $fmt = "$pfx % ".length($tot)."u/$tot\n";
 448                                 $pr->("$pfx copying $est$tot documents\n");
 449                                 $pr_data->{fmt} = $fmt;
 450                                 $pr_data->{total} = $tot;
 451                         }
 452                 };
 453         } while (cpdb_retryable($src, $pfx));
 454
 455         if (defined $reshard) {
 456                 # we rely on document IDs matching NNTP article number,
 457                 # so we can't have the Xapian sharding DB support rewriting
 458                 # document IDs.  Thus we iterate through each shard
 459                 # individually.
 460                 $src = undef;
 461                 foreach (@$old) {
 462                         my $old = $XapianDatabase->new($_);
 463                         cpdb_loop($old, $dst, $pr_data, $cur_shard, $reshard);
 464                 }
 465         } else {
 466                 cpdb_loop($src, $dst, $pr_data);
 467         }
 468
 469         $pr->(sprintf($pr_data->{fmt}, $pr_data->{nr})) if $pr;
 470         return unless $opt->{compact};
 471
 472         $src = $dst = undef; # flushes and closes
 473
 474         # this is probably the best place to do xapian-compact
 475         # since $dst isn't readable by HTTP or NNTP clients, yet:
 476         compact([ $tmp, $new ], $opt);
 477         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 478 }
 479
 480 1;