lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which popen_rd);
   7 use PublicInbox::Over;
   8 use PublicInbox::SearchIdx qw(nodatacow_dir);
   9 use File::Temp 0.19 (); # ->newdir
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12 use POSIX ();
  13
  14 # support testing with dev versions of Xapian which installs
  15 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  16 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  17 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  18
  19 sub commit_changes ($$$$) {
  20         my ($ibx, $im, $tmp, $opt) = @_;
  21         my $reshard = $opt->{reshard};
  22         my $reindex = $opt->{reindex};
  23
  24         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  25         my @old_shard;
  26         my $over_chg;
  27
  28         while (my ($old, $newdir) = each %$tmp) {
  29                 next if $old eq ''; # no invalid paths
  30                 my @st = stat($old);
  31                 if (!@st && !defined($opt->{reshard})) {
  32                         die "failed to stat($old): $!";
  33                 }
  34
  35                 my $new = $newdir->dirname if defined($newdir);
  36                 my $over = "$old/over.sqlite3";
  37                 if (-f $over) { # only for v1, v2 over is untouched
  38                         defined $new or die "BUG: $over exists when culling v2";
  39                         $over = PublicInbox::Over->new($over);
  40                         my $tmp_over = "$new/over.sqlite3";
  41                         $over->connect->sqlite_backup_to_file($tmp_over);
  42                         $over = undef;
  43                         $over_chg = 1;
  44                 }
  45
  46                 if (!defined($new)) { # culled shard
  47                         push @old_shard, $old;
  48                         next;
  49                 }
  50
  51                 if (@st) {
  52                         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  53                         rename($old, "$new/old") or
  54                                         die "rename $old => $new/old: $!\n";
  55                 }
  56                 # Xtmpdir->DESTROY won't remove $new after this:
  57                 rename($new, $old) or die "rename $new => $old: $!\n";
  58                 if (@st) {
  59                         my $prev = "$old/old";
  60                         remove_tree($prev) or
  61                                 die "failed to remove $prev: $!\n";
  62                 }
  63         }
  64
  65         # trigger ->check_inodes in read-only daemons
  66         syswrite($im->{lockfh}, '.') if $over_chg;
  67
  68         remove_tree(@old_shard);
  69         $tmp = undef;
  70         if (!$opt->{-coarse_lock}) {
  71                 $opt->{-skip_lock} = 1;
  72
  73                 if ($im->can('count_shards')) {
  74                         my $pr = $opt->{-progress};
  75                         my $n = $im->count_shards;
  76                         if (defined $reshard && $n != $reshard) {
  77                                 die
  78 "BUG: counted $n shards after resharding to $reshard";
  79                         }
  80                         my $prev = $im->{shards};
  81                         if ($pr && $prev != $n) {
  82                                 $pr->("shard count changed: $prev => $n\n");
  83                                 $im->{shards} = $n;
  84                         }
  85                 }
  86
  87                 PublicInbox::Admin::index_inbox($ibx, $im, $opt);
  88         }
  89 }
  90
  91 sub cb_spawn {
  92         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  93         defined(my $pid = fork) or die "fork: $!";
  94         return $pid if $pid > 0;
  95         $cb->($args, $opt);
  96         POSIX::_exit(0);
  97 }
  98
  99 sub runnable_or_die ($) {
 100         my ($exe) = @_;
 101         which($exe) or die "$exe not found in PATH\n";
 102 }
 103
 104 sub prepare_reindex ($$$) {
 105         my ($ibx, $im, $reindex) = @_;
 106         if ($ibx->version == 1) {
 107                 my $dir = $ibx->search->xdir(1);
 108                 my $xdb = $PublicInbox::Search::X{Database}->new($dir);
 109                 if (my $lc = $xdb->get_metadata('last_commit')) {
 110                         $reindex->{from} = $lc;
 111                 }
 112         } else { # v2
 113                 my $max;
 114                 $im->git_dir_latest(\$max) or return;
 115                 my $from = $reindex->{from};
 116                 my $mm = $ibx->mm;
 117                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 118                 foreach my $i (0..$max) {
 119                         $from->[$i] = $mm->last_commit_xap($v, $i);
 120                 }
 121         }
 122 }
 123
 124 sub same_fs_or_die ($$) {
 125         my ($x, $y) = @_;
 126         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
 127         die "$x and $y reside on different filesystems\n";
 128 }
 129
 130 sub process_queue {
 131         my ($queue, $cb, $opt) = @_;
 132         my $max = $opt->{jobs} // scalar(@$queue);
 133         if ($max <= 1) {
 134                 while (defined(my $args = shift @$queue)) {
 135                         $cb->($args, $opt);
 136                 }
 137                 return;
 138         }
 139
 140         # run in parallel:
 141         my %pids;
 142         while (@$queue) {
 143                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 144                         my $args = shift @$queue;
 145                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 146                 }
 147
 148                 while (scalar keys %pids) {
 149                         my $pid = waitpid(-1, 0);
 150                         my $args = delete $pids{$pid};
 151                         if ($args) {
 152                                 die join(' ', @$args)." failed: $?\n" if $?;
 153                         } else {
 154                                 warn "unknown PID($pid) reaped: $?\n";
 155                         }
 156                 }
 157         }
 158 }
 159
 160 sub setup_signals () {
 161         # http://www.tldp.org/LDP/abs/html/exitcodes.html
 162         $SIG{INT} = sub { exit(130) };
 163         $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = sub { exit(1) };
 164 }
 165
 166 sub prepare_run {
 167         my ($ibx, $opt) = @_;
 168         my $tmp = {}; # old shard dir => File::Temp->newdir object or undef
 169         my @queue; # ([old//src,newdir]) - list of args for cpdb() or compact()
 170         my $old;
 171         if (my $srch = $ibx->search) {
 172                 $old = $srch->xdir(1);
 173                 -d $old or die "$old does not exist\n";
 174         }
 175         my $reshard = $opt->{reshard};
 176         if (defined $reshard && $reshard <= 0) {
 177                 die "--reshard must be a positive number\n";
 178         }
 179
 180         # we want temporary directories to be as deep as possible,
 181         # so v2 shards can keep "xap$SCHEMA_VERSION" on a separate FS.
 182         if ($old && $ibx->version == 1) {
 183                 if (defined $reshard) {
 184                         warn
 185 "--reshard=$reshard ignored for v1 $ibx->{inboxdir}\n";
 186                 }
 187                 my $dir = dirname($old);
 188                 same_fs_or_die($dir, $old);
 189                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 190                 my $wip = File::Temp->newdir("xapian$v-XXXXXXXX", DIR => $dir);
 191                 $tmp->{$old} = $wip;
 192                 nodatacow_dir($wip->dirname);
 193                 push @queue, [ $old, $wip ];
 194         } elsif ($old) {
 195                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 196                 my @old_shards;
 197                 while (defined(my $dn = readdir($dh))) {
 198                         if ($dn =~ /\A[0-9]+\z/) {
 199                                 push @old_shards, $dn;
 200                         } elsif ($dn eq '.' || $dn eq '..') {
 201                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 202                         } else {
 203                                 warn "W: skipping unknown dir: $old/$dn\n"
 204                         }
 205                 }
 206                 die "No Xapian shards found in $old\n" unless @old_shards;
 207
 208                 my ($src, $max_shard);
 209                 if (!defined($reshard) || $reshard == scalar(@old_shards)) {
 210                         # 1:1 copy
 211                         $max_shard = scalar(@old_shards) - 1;
 212                 } else {
 213                         # M:N copy
 214                         $max_shard = $reshard - 1;
 215                         $src = [ map { "$old/$_" } @old_shards ];
 216                 }
 217                 foreach my $dn (0..$max_shard) {
 218                         my $tmpl = "$dn-XXXXXXXX";
 219                         my $wip = File::Temp->newdir($tmpl, DIR => $old);
 220                         same_fs_or_die($old, $wip->dirname);
 221                         my $cur = "$old/$dn";
 222                         push @queue, [ $src // $cur , $wip ];
 223                         nodatacow_dir($wip->dirname);
 224                         $tmp->{$cur} = $wip;
 225                 }
 226                 # mark old shards to be unlinked
 227                 if ($src) {
 228                         $tmp->{$_} ||= undef for @$src;
 229                 }
 230         }
 231         ($tmp, \@queue);
 232 }
 233
 234 sub check_compact () { runnable_or_die($XAPIAN_COMPACT) }
 235
 236 sub _run {
 237         my ($ibx, $cb, $opt, $reindex) = @_;
 238         my $im = $ibx->importer(0);
 239         $im->lock_acquire;
 240         my ($tmp, $queue) = prepare_run($ibx, $opt);
 241
 242         # fine-grained locking if we prepare for reindex
 243         if (!$opt->{-coarse_lock}) {
 244                 prepare_reindex($ibx, $im, $reindex);
 245                 $im->lock_release;
 246         }
 247
 248         $ibx->cleanup;
 249         process_queue($queue, $cb, $opt);
 250         $im->lock_acquire if !$opt->{-coarse_lock};
 251         commit_changes($ibx, $im, $tmp, $opt);
 252 }
 253
 254 sub run {
 255         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 256         my $cb = \&${\"PublicInbox::Xapcmd::$task"};
 257         PublicInbox::Admin::progress_prepare($opt ||= {});
 258         defined(my $dir = $ibx->{inboxdir}) or die "no inboxdir defined\n";
 259         -d $dir or die "inboxdir=$dir does not exist\n";
 260         check_compact() if $opt->{compact} && $ibx->search;
 261         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 262
 263         if (!$opt->{-coarse_lock}) {
 264                 $reindex = $opt->{reindex} = { # per-epoch ranges for v2
 265                         from => $ibx->version == 1 ? '' : [],
 266                 };
 267                 PublicInbox::SearchIdx::load_xapian_writable();
 268         }
 269
 270         local %SIG = %SIG;
 271         setup_signals();
 272         $ibx->umask_prepare;
 273         $ibx->with_umask(\&_run, $ibx, $cb, $opt, $reindex);
 274 }
 275
 276 sub cpdb_retryable ($$) {
 277         my ($src, $pfx) = @_;
 278         if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 279                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 280                 $src->reopen;
 281                 return 1;
 282         }
 283         if ($@) {
 284                 warn "$pfx E: ", ref($@), "\n";
 285                 die;
 286         }
 287         0;
 288 }
 289
 290 sub progress_pfx ($) {
 291         my ($wip) = @_; # tempdir v2: ([0-9])+-XXXXXXXX
 292         my @p = split('/', $wip);
 293
 294         # return "xap15/0" for v2, or "xapian15" for v1:
 295         ($p[-1] =~ /\A([0-9]+)/) ? "$p[-2]/$1" : $p[-1];
 296 }
 297
 298 # xapian-compact wrapper
 299 sub compact ($$) {
 300         my ($args, $opt) = @_;
 301         my ($src, $newdir) = @$args;
 302         my $dst = ref($newdir) ? $newdir->dirname : $newdir;
 303         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 304         my $pr = $opt->{-progress};
 305         my $rdr = {};
 306
 307         foreach my $fd (0..2) {
 308                 defined(my $dfd = $opt->{$fd}) or next;
 309                 $rdr->{$fd} = $dfd;
 310         }
 311
 312         # we rely on --no-renumber to keep docids synched to NNTP
 313         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 314         for my $sw (qw(no-full fuller)) {
 315                 push @$cmd, "--$sw" if $opt->{$sw};
 316         }
 317         for my $sw (qw(blocksize)) {
 318                 defined(my $v = $opt->{$sw}) or next;
 319                 push @$cmd, "--$sw", $v;
 320         }
 321         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 322         push @$cmd, $src, $dst;
 323         my $rd = popen_rd($cmd, undef, $rdr);
 324         while (<$rd>) {
 325                 if ($pr) {
 326                         s/\r/\r$pfx /g;
 327                         $pr->("$pfx $_");
 328                 }
 329         }
 330         close $rd or die join(' ', @$cmd)." failed: $?n";
 331 }
 332
 333 sub cpdb_loop ($$$;$$) {
 334         my ($src, $dst, $pr_data, $cur_shard, $reshard) = @_;
 335         my ($pr, $fmt, $nr, $pfx);
 336         if ($pr_data) {
 337                 $pr = $pr_data->{pr};
 338                 $fmt = $pr_data->{fmt};
 339                 $nr = \($pr_data->{nr});
 340                 $pfx = $pr_data->{pfx};
 341         }
 342
 343         my ($it, $end);
 344         do {
 345                 eval {
 346                         $it = $src->postlist_begin('');
 347                         $end = $src->postlist_end('');
 348                 };
 349         } while (cpdb_retryable($src, $pfx));
 350
 351         do {
 352                 eval {
 353                         for (; $it != $end; $it++) {
 354                                 my $docid = $it->get_docid;
 355                                 if (defined $reshard) {
 356                                         my $dst_shard = $docid % $reshard;
 357                                         next if $dst_shard != $cur_shard;
 358                                 }
 359                                 my $doc = $src->get_document($docid);
 360                                 $dst->replace_document($docid, $doc);
 361                                 if ($pr_data && !(++$$nr  & 1023)) {
 362                                         $pr->(sprintf($fmt, $$nr));
 363                                 }
 364                         }
 365
 366                         # unlike copydatabase(1), we don't copy spelling
 367                         # and synonym data (or other user metadata) since
 368                         # the Perl APIs don't expose iterators for them
 369                         # (and public-inbox does not use those features)
 370                 };
 371         } while (cpdb_retryable($src, $pfx));
 372 }
 373
 374 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 375 # to the overhead of Perl.
 376 sub cpdb ($$) {
 377         my ($args, $opt) = @_;
 378         my ($old, $newdir) = @$args;
 379         my $new = $newdir->dirname;
 380         my ($src, $cur_shard);
 381         my $reshard;
 382         PublicInbox::SearchIdx::load_xapian_writable() or die;
 383         my $XapianDatabase = $PublicInbox::Search::X{Database};
 384         if (ref($old) eq 'ARRAY') {
 385                 ($cur_shard) = ($new =~ m!xap[0-9]+/([0-9]+)\b!);
 386                 defined $cur_shard or
 387                         die "BUG: could not extract shard # from $new";
 388                 $reshard = $opt->{reshard};
 389                 defined $reshard or die 'BUG: got array src w/o --reshard';
 390
 391                 # resharding, M:N copy means have full read access
 392                 foreach (@$old) {
 393                         if ($src) {
 394                                 my $sub = $XapianDatabase->new($_);
 395                                 $src->add_database($sub);
 396                         } else {
 397                                 $src = $XapianDatabase->new($_);
 398                         }
 399                 }
 400         } else {
 401                 $src = $XapianDatabase->new($old);
 402         }
 403
 404         my ($tmp, $ft);
 405         local %SIG = %SIG;
 406         if ($opt->{compact}) {
 407                 my $dir = dirname($new);
 408                 same_fs_or_die($dir, $new);
 409                 $ft = File::Temp->newdir("$new.compact-XXXXXX", DIR => $dir);
 410                 setup_signals();
 411                 $tmp = $ft->dirname;
 412                 nodatacow_dir($tmp);
 413         } else {
 414                 $tmp = $new;
 415         }
 416
 417         # like copydatabase(1), be sure we don't overwrite anything in case
 418         # of other bugs:
 419         my $flag = eval($PublicInbox::Search::Xap.'::DB_CREATE()');
 420         die if $@;
 421         my $XapianWritableDatabase = $PublicInbox::Search::X{WritableDatabase};
 422         $flag |= $PublicInbox::SearchIdx::DB_NO_SYNC if !$opt->{sync};
 423         my $dst = $XapianWritableDatabase->new($tmp, $flag);
 424         my $pr = $opt->{-progress};
 425         my $pfx = $opt->{-progress_pfx} = progress_pfx($new);
 426         my $pr_data = { pr => $pr, pfx => $pfx, nr => 0 } if $pr;
 427
 428         do {
 429                 eval {
 430                         # update the only metadata key for v1:
 431                         my $lc = $src->get_metadata('last_commit');
 432                         $dst->set_metadata('last_commit', $lc) if $lc;
 433
 434                         # only the first xapian shard (0) gets 'indexlevel'
 435                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 436                                 my $l = $src->get_metadata('indexlevel');
 437                                 if ($l eq 'medium') {
 438                                         $dst->set_metadata('indexlevel', $l);
 439                                 }
 440                         }
 441                         if ($pr_data) {
 442                                 my $tot = $src->get_doccount;
 443
 444                                 # we can only estimate when resharding,
 445                                 # because removed spam causes slight imbalance
 446                                 my $est = '';
 447                                 if (defined $cur_shard && $reshard > 1) {
 448                                         $tot = int($tot/$reshard);
 449                                         $est = 'around ';
 450                                 }
 451                                 my $fmt = "$pfx % ".length($tot)."u/$tot\n";
 452                                 $pr->("$pfx copying $est$tot documents\n");
 453                                 $pr_data->{fmt} = $fmt;
 454                                 $pr_data->{total} = $tot;
 455                         }
 456                 };
 457         } while (cpdb_retryable($src, $pfx));
 458
 459         if (defined $reshard) {
 460                 # we rely on document IDs matching NNTP article number,
 461                 # so we can't have the Xapian sharding DB support rewriting
 462                 # document IDs.  Thus we iterate through each shard
 463                 # individually.
 464                 $src = undef;
 465                 foreach (@$old) {
 466                         my $old = $XapianDatabase->new($_);
 467                         cpdb_loop($old, $dst, $pr_data, $cur_shard, $reshard);
 468                 }
 469         } else {
 470                 cpdb_loop($src, $dst, $pr_data);
 471         }
 472
 473         $pr->(sprintf($pr_data->{fmt}, $pr_data->{nr})) if $pr;
 474         return unless $opt->{compact};
 475
 476         $src = $dst = undef; # flushes and closes
 477
 478         # this is probably the best place to do xapian-compact
 479         # since $dst isn't readable by HTTP or NNTP clients, yet:
 480         compact([ $tmp, $new ], $opt);
 481         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 482 }
 483
 484 1;