lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which spawn);
   7 use PublicInbox::Over;
   8 use File::Temp qw(tempdir);
   9 use File::Path qw(remove_tree);
  10
  11 sub commit_changes ($$$) {
  12         my ($im, $old, $new) = @_;
  13         my @st = stat($old) or die "failed to stat($old): $!\n";
  14
  15         my $over = "$old/over.sqlite3";
  16         if (-f $over) {
  17                 $over = PublicInbox::Over->new($over);
  18                 $over->connect->sqlite_backup_to_file("$new/over.sqlite3");
  19         }
  20         rename($old, "$new/old") or die "rename $old => $new/old: $!\n";
  21         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  22         rename($new, $old) or die "rename $new => $old: $!\n";
  23         $im->lock_release;
  24         remove_tree("$old/old") or die "failed to remove $old/old: $!\n";
  25 }
  26
  27 sub run {
  28         my ($ibx, $cmd) = @_;
  29         my $dir = $ibx->{mainrepo} or die "no mainrepo in inbox\n";
  30         which($cmd->[0]) or die "$cmd->[0] not found in PATH\n";
  31         $ibx->umask_prepare;
  32         my $old = $ibx->search->xdir(1);
  33         -d $old or die "$old does not exist\n";
  34         my $new = tempdir($cmd->[0].'-XXXXXXXX', CLEANUP => 1, DIR => $dir);
  35         my $v = $ibx->{version} || 1;
  36         my @cmds;
  37         if ($v == 1) {
  38                 push @cmds, [@$cmd, $old, $new];
  39         } else {
  40                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
  41                 while (defined(my $dn = readdir($dh))) {
  42                         if ($dn =~ /\A\d+\z/) {
  43                                 push @cmds, [@$cmd, "$old/$dn", "$new/$dn"];
  44                         } elsif ($dn eq '.' || $dn eq '..') {
  45                         } elsif ($dn =~ /\Aover\.sqlite3/) {
  46                         } else {
  47                                 warn "W: skipping unknown dir: $old/$dn\n"
  48                         }
  49                 }
  50                 die "No Xapian parts found in $old\n" unless @cmds;
  51         }
  52         my $im = $ibx->importer(0);
  53         $ibx->with_umask(sub {
  54                 $im->lock_acquire;
  55                 my %pids = map {; spawn($_) => join(' ', @$_) } @cmds;
  56                 while (scalar keys %pids) {
  57                         my $pid = waitpid(-1, 0);
  58                         my $desc = delete $pids{$pid};
  59                         die "$desc failed: $?\n" if $?;
  60                 }
  61                 commit_changes($im, $old, $new);
  62         });
  63 }
  64
  65 1;