lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which popen_rd);
   7 use PublicInbox::Over;
   8 use PublicInbox::SearchIdx;
   9 use File::Temp 0.19 (); # ->newdir
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12 use POSIX ();
  13
  14 # support testing with dev versions of Xapian which installs
  15 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  16 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  17 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  18
  19 sub commit_changes ($$$$) {
  20         my ($ibx, $im, $tmp, $opt) = @_;
  21         my $reshard = $opt->{reshard};
  22         my $reindex = $opt->{reindex};
  23
  24         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  25         my @old_shard;
  26
  27         while (my ($old, $newdir) = each %$tmp) {
  28                 next if $old eq ''; # no invalid paths
  29                 my @st = stat($old);
  30                 if (!@st && !defined($opt->{reshard})) {
  31                         die "failed to stat($old): $!";
  32                 }
  33
  34                 my $new = $newdir->dirname if defined($newdir);
  35                 my $over = "$old/over.sqlite3";
  36                 if (-f $over) { # only for v1, v2 over is untouched
  37                         defined $new or die "BUG: $over exists when culling v2";
  38                         $over = PublicInbox::Over->new($over);
  39                         my $tmp_over = "$new/over.sqlite3";
  40                         $over->connect->sqlite_backup_to_file($tmp_over);
  41                         $over = undef;
  42                 }
  43
  44                 if (!defined($new)) { # culled shard
  45                         push @old_shard, $old;
  46                         next;
  47                 }
  48
  49                 if (@st) {
  50                         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  51                         rename($old, "$new/old") or
  52                                         die "rename $old => $new/old: $!\n";
  53                 }
  54                 # Xtmpdir->DESTROY won't remove $new after this:
  55                 rename($new, $old) or die "rename $new => $old: $!\n";
  56                 if (@st) {
  57                         my $prev = "$old/old";
  58                         remove_tree($prev) or
  59                                 die "failed to remove $prev: $!\n";
  60                 }
  61         }
  62         remove_tree(@old_shard);
  63         $tmp = undef;
  64         if (!$opt->{-coarse_lock}) {
  65                 $opt->{-skip_lock} = 1;
  66
  67                 if ($im->can('count_shards')) {
  68                         my $pr = $opt->{-progress};
  69                         my $n = $im->count_shards;
  70                         if (defined $reshard && $n != $reshard) {
  71                                 die
  72 "BUG: counted $n shards after resharding to $reshard";
  73                         }
  74                         my $prev = $im->{shards};
  75                         if ($pr && $prev != $n) {
  76                                 $pr->("shard count changed: $prev => $n\n");
  77                                 $im->{shards} = $n;
  78                         }
  79                 }
  80
  81                 PublicInbox::Admin::index_inbox($ibx, $im, $opt);
  82         }
  83 }
  84
  85 sub cb_spawn {
  86         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  87         defined(my $pid = fork) or die "fork: $!";
  88         return $pid if $pid > 0;
  89         $cb->($args, $opt);
  90         POSIX::_exit(0);
  91 }
  92
  93 sub runnable_or_die ($) {
  94         my ($exe) = @_;
  95         which($exe) or die "$exe not found in PATH\n";
  96 }
  97
  98 sub prepare_reindex ($$$) {
  99         my ($ibx, $im, $reindex) = @_;
 100         if ($ibx->version == 1) {
 101                 my $dir = $ibx->search->xdir(1);
 102                 my $xdb = $PublicInbox::Search::X{Database}->new($dir);
 103                 if (my $lc = $xdb->get_metadata('last_commit')) {
 104                         $reindex->{from} = $lc;
 105                 }
 106         } else { # v2
 107                 my $max;
 108                 $im->git_dir_latest(\$max) or return;
 109                 my $from = $reindex->{from};
 110                 my $mm = $ibx->mm;
 111                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 112                 foreach my $i (0..$max) {
 113                         $from->[$i] = $mm->last_commit_xap($v, $i);
 114                 }
 115         }
 116 }
 117
 118 sub same_fs_or_die ($$) {
 119         my ($x, $y) = @_;
 120         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
 121         die "$x and $y reside on different filesystems\n";
 122 }
 123
 124 sub process_queue {
 125         my ($queue, $cb, $opt) = @_;
 126         my $max = $opt->{jobs} || scalar(@$queue);
 127         if ($max <= 1) {
 128                 while (defined(my $args = shift @$queue)) {
 129                         $cb->($args, $opt);
 130                 }
 131                 return;
 132         }
 133
 134         # run in parallel:
 135         my %pids;
 136         while (@$queue) {
 137                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 138                         my $args = shift @$queue;
 139                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 140                 }
 141
 142                 while (scalar keys %pids) {
 143                         my $pid = waitpid(-1, 0);
 144                         my $args = delete $pids{$pid};
 145                         die join(' ', @$args)." failed: $?\n" if $?;
 146                 }
 147         }
 148 }
 149
 150 sub setup_signals () {
 151         # http://www.tldp.org/LDP/abs/html/exitcodes.html
 152         $SIG{INT} = sub { exit(130) };
 153         $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = sub { exit(1) };
 154 }
 155
 156 sub prepare_run {
 157         my ($ibx, $opt) = @_;
 158         my $tmp = {}; # old shard dir => File::Temp->newdir object or undef
 159         my @queue; # ([old//src,newdir]) - list of args for cpdb() or compact()
 160
 161         my $old = $ibx->search->xdir(1);
 162         -d $old or die "$old does not exist\n";
 163         my $reshard = $opt->{reshard};
 164         if (defined $reshard && $reshard <= 0) {
 165                 die "--reshard must be a positive number\n";
 166         }
 167
 168         # we want temporary directories to be as deep as possible,
 169         # so v2 shards can keep "xap$SCHEMA_VERSION" on a separate FS.
 170         if ($ibx->version == 1) {
 171                 if (defined $reshard) {
 172                         warn
 173 "--reshard=$reshard ignored for v1 $ibx->{inboxdir}\n";
 174                 }
 175                 my $dir = dirname($old);
 176                 same_fs_or_die($dir, $old);
 177                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 178                 my $wip = File::Temp->newdir("xapian$v-XXXXXXXX", DIR => $dir);
 179                 $tmp->{$old} = $wip;
 180                 push @queue, [ $old, $wip ];
 181         } else {
 182                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 183                 my @old_shards;
 184                 while (defined(my $dn = readdir($dh))) {
 185                         if ($dn =~ /\A[0-9]+\z/) {
 186                                 push @old_shards, $dn;
 187                         } elsif ($dn eq '.' || $dn eq '..') {
 188                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 189                         } else {
 190                                 warn "W: skipping unknown dir: $old/$dn\n"
 191                         }
 192                 }
 193                 die "No Xapian shards found in $old\n" unless @old_shards;
 194
 195                 my ($src, $max_shard);
 196                 if (!defined($reshard) || $reshard == scalar(@old_shards)) {
 197                         # 1:1 copy
 198                         $max_shard = scalar(@old_shards) - 1;
 199                 } else {
 200                         # M:N copy
 201                         $max_shard = $reshard - 1;
 202                         $src = [ map { "$old/$_" } @old_shards ];
 203                 }
 204                 foreach my $dn (0..$max_shard) {
 205                         my $tmpl = "$dn-XXXXXXXX";
 206                         my $wip = File::Temp->newdir($tmpl, DIR => $old);
 207                         same_fs_or_die($old, $wip->dirname);
 208                         my $cur = "$old/$dn";
 209                         push @queue, [ $src // $cur , $wip ];
 210                         $tmp->{$cur} = $wip;
 211                 }
 212                 # mark old shards to be unlinked
 213                 if ($src) {
 214                         $tmp->{$_} ||= undef for @$src;
 215                 }
 216         }
 217         ($tmp, \@queue);
 218 }
 219
 220 sub run {
 221         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 222         my $cb = \&${\"PublicInbox::Xapcmd::$task"};
 223         PublicInbox::Admin::progress_prepare($opt ||= {});
 224         defined(my $dir = $ibx->{inboxdir}) or die "no inboxdir defined\n";
 225         -d $dir or die "inboxdir=$dir does not exist\n";
 226         runnable_or_die($XAPIAN_COMPACT) if $opt->{compact};
 227         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 228
 229         if (!$opt->{-coarse_lock}) {
 230                 $reindex = $opt->{reindex} = {};
 231                 $reindex->{from} = []; # per-epoch ranges
 232                 require PublicInbox::SearchIdx;
 233                 PublicInbox::SearchIdx::load_xapian_writable();
 234         }
 235
 236         local %SIG = %SIG;
 237         setup_signals();
 238         $ibx->umask_prepare;
 239         $ibx->with_umask(sub {
 240                 my $im = $ibx->importer(0);
 241                 $im->lock_acquire;
 242                 my ($tmp, $queue) = prepare_run($ibx, $opt);
 243
 244                 # fine-grained locking if we prepare for reindex
 245                 if (!$opt->{-coarse_lock}) {
 246                         prepare_reindex($ibx, $im, $reindex);
 247                         $im->lock_release;
 248                 }
 249
 250                 $ibx->cleanup;
 251                 process_queue($queue, $cb, $opt);
 252                 $im->lock_acquire if !$opt->{-coarse_lock};
 253                 commit_changes($ibx, $im, $tmp, $opt);
 254         });
 255 }
 256
 257 sub cpdb_retryable ($$) {
 258         my ($src, $pfx) = @_;
 259         if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 260                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 261                 $src->reopen;
 262                 return 1;
 263         }
 264         if ($@) {
 265                 warn "$pfx E: ", ref($@), "\n";
 266                 die;
 267         }
 268         0;
 269 }
 270
 271 sub progress_pfx ($) {
 272         my ($wip) = @_; # tempdir v2: ([0-9])+-XXXXXXXX
 273         my @p = split('/', $wip);
 274
 275         # return "xap15/0" for v2, or "xapian15" for v1:
 276         ($p[-1] =~ /\A([0-9]+)/) ? "$p[-2]/$1" : $p[-1];
 277 }
 278
 279 # xapian-compact wrapper
 280 sub compact ($$) {
 281         my ($args, $opt) = @_;
 282         my ($src, $newdir) = @$args;
 283         my $dst = ref($newdir) ? $newdir->dirname : $newdir;
 284         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 285         my $pr = $opt->{-progress};
 286         my $rdr = {};
 287
 288         foreach my $fd (0..2) {
 289                 defined(my $dfd = $opt->{$fd}) or next;
 290                 $rdr->{$fd} = $dfd;
 291         }
 292
 293         # we rely on --no-renumber to keep docids synched to NNTP
 294         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 295         for my $sw (qw(no-full fuller)) {
 296                 push @$cmd, "--$sw" if $opt->{$sw};
 297         }
 298         for my $sw (qw(blocksize)) {
 299                 defined(my $v = $opt->{$sw}) or next;
 300                 push @$cmd, "--$sw", $v;
 301         }
 302         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 303         push @$cmd, $src, $dst;
 304         my $rd = popen_rd($cmd, undef, $rdr);
 305         while (<$rd>) {
 306                 if ($pr) {
 307                         s/\r/\r$pfx /g;
 308                         $pr->("$pfx $_");
 309                 }
 310         }
 311         close $rd or die join(' ', @$cmd)." failed: $?n";
 312 }
 313
 314 sub cpdb_loop ($$$;$$) {
 315         my ($src, $dst, $pr_data, $cur_shard, $reshard) = @_;
 316         my ($pr, $fmt, $nr, $pfx);
 317         if ($pr_data) {
 318                 $pr = $pr_data->{pr};
 319                 $fmt = $pr_data->{fmt};
 320                 $nr = \($pr_data->{nr});
 321                 $pfx = $pr_data->{pfx};
 322         }
 323
 324         my ($it, $end);
 325         do {
 326                 eval {
 327                         $it = $src->postlist_begin('');
 328                         $end = $src->postlist_end('');
 329                 };
 330         } while (cpdb_retryable($src, $pfx));
 331
 332         do {
 333                 eval {
 334                         for (; $it != $end; $it++) {
 335                                 my $docid = $it->get_docid;
 336                                 if (defined $reshard) {
 337                                         my $dst_shard = $docid % $reshard;
 338                                         next if $dst_shard != $cur_shard;
 339                                 }
 340                                 my $doc = $src->get_document($docid);
 341                                 $dst->replace_document($docid, $doc);
 342                                 if ($pr_data && !(++$$nr  & 1023)) {
 343                                         $pr->(sprintf($fmt, $$nr));
 344                                 }
 345                         }
 346
 347                         # unlike copydatabase(1), we don't copy spelling
 348                         # and synonym data (or other user metadata) since
 349                         # the Perl APIs don't expose iterators for them
 350                         # (and public-inbox does not use those features)
 351                 };
 352         } while (cpdb_retryable($src, $pfx));
 353 }
 354
 355 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 356 # to the overhead of Perl.
 357 sub cpdb ($$) {
 358         my ($args, $opt) = @_;
 359         my ($old, $newdir) = @$args;
 360         my $new = $newdir->dirname;
 361         my ($src, $cur_shard);
 362         my $reshard;
 363         PublicInbox::SearchIdx::load_xapian_writable() or die;
 364         my $XapianDatabase = $PublicInbox::Search::X{Database};
 365         if (ref($old) eq 'ARRAY') {
 366                 ($cur_shard) = ($new =~ m!xap[0-9]+/([0-9]+)\b!);
 367                 defined $cur_shard or
 368                         die "BUG: could not extract shard # from $new";
 369                 $reshard = $opt->{reshard};
 370                 defined $reshard or die 'BUG: got array src w/o --reshard';
 371
 372                 # resharding, M:N copy means have full read access
 373                 foreach (@$old) {
 374                         if ($src) {
 375                                 my $sub = $XapianDatabase->new($_);
 376                                 $src->add_database($sub);
 377                         } else {
 378                                 $src = $XapianDatabase->new($_);
 379                         }
 380                 }
 381         } else {
 382                 $src = $XapianDatabase->new($old);
 383         }
 384
 385         my ($tmp, $ft);
 386         local %SIG = %SIG;
 387         if ($opt->{compact}) {
 388                 my $dir = dirname($new);
 389                 same_fs_or_die($dir, $new);
 390                 $ft = File::Temp->newdir("$new.compact-XXXXXX", DIR => $dir);
 391                 setup_signals();
 392                 $tmp = $ft->dirname;
 393         } else {
 394                 $tmp = $new;
 395         }
 396
 397         # like copydatabase(1), be sure we don't overwrite anything in case
 398         # of other bugs:
 399         my $creat = eval($PublicInbox::Search::Xap.'::DB_CREATE()');
 400         die if $@;
 401         my $XapianWritableDatabase = $PublicInbox::Search::X{WritableDatabase};
 402         my $dst = $XapianWritableDatabase->new($tmp, $creat);
 403         my $pr = $opt->{-progress};
 404         my $pfx = $opt->{-progress_pfx} = progress_pfx($new);
 405         my $pr_data = { pr => $pr, pfx => $pfx, nr => 0 } if $pr;
 406
 407         do {
 408                 eval {
 409                         # update the only metadata key for v1:
 410                         my $lc = $src->get_metadata('last_commit');
 411                         $dst->set_metadata('last_commit', $lc) if $lc;
 412
 413                         # only the first xapian shard (0) gets 'indexlevel'
 414                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 415                                 my $l = $src->get_metadata('indexlevel');
 416                                 if ($l eq 'medium') {
 417                                         $dst->set_metadata('indexlevel', $l);
 418                                 }
 419                         }
 420                         if ($pr_data) {
 421                                 my $tot = $src->get_doccount;
 422
 423                                 # we can only estimate when resharding,
 424                                 # because removed spam causes slight imbalance
 425                                 my $est = '';
 426                                 if (defined $cur_shard && $reshard > 1) {
 427                                         $tot = int($tot/$reshard);
 428                                         $est = 'around ';
 429                                 }
 430                                 my $fmt = "$pfx % ".length($tot)."u/$tot\n";
 431                                 $pr->("$pfx copying $est$tot documents\n");
 432                                 $pr_data->{fmt} = $fmt;
 433                                 $pr_data->{total} = $tot;
 434                         }
 435                 };
 436         } while (cpdb_retryable($src, $pfx));
 437
 438         if (defined $reshard) {
 439                 # we rely on document IDs matching NNTP article number,
 440                 # so we can't have the Xapian sharding DB support rewriting
 441                 # document IDs.  Thus we iterate through each shard
 442                 # individually.
 443                 $src = undef;
 444                 foreach (@$old) {
 445                         my $old = $XapianDatabase->new($_);
 446                         cpdb_loop($old, $dst, $pr_data, $cur_shard, $reshard);
 447                 }
 448         } else {
 449                 cpdb_loop($src, $dst, $pr_data);
 450         }
 451
 452         $pr->(sprintf($pr_data->{fmt}, $pr_data->{nr})) if $pr;
 453         return unless $opt->{compact};
 454
 455         $src = $dst = undef; # flushes and closes
 456
 457         # this is probably the best place to do xapian-compact
 458         # since $dst isn't readable by HTTP or NNTP clients, yet:
 459         compact([ $tmp, $new ], $opt);
 460         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 461 }
 462
 463 1;