lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which popen_rd);
   7 use PublicInbox::Over;
   8 use PublicInbox::SearchIdx;
   9 use File::Temp 0.19 (); # ->newdir
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12 use POSIX ();
  13
  14 # support testing with dev versions of Xapian which installs
  15 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  16 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  17 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  18
  19 sub commit_changes ($$$$) {
  20         my ($ibx, $im, $tmp, $opt) = @_;
  21         my $reshard = $opt->{reshard};
  22         my $reindex = $opt->{reindex};
  23
  24         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  25         my @old_shard;
  26
  27         while (my ($old, $newdir) = each %$tmp) {
  28                 next if $old eq ''; # no invalid paths
  29                 my @st = stat($old);
  30                 if (!@st && !defined($opt->{reshard})) {
  31                         die "failed to stat($old): $!";
  32                 }
  33
  34                 my $new = $newdir->dirname if defined($newdir);
  35                 my $over = "$old/over.sqlite3";
  36                 if (-f $over) { # only for v1, v2 over is untouched
  37                         defined $new or die "BUG: $over exists when culling v2";
  38                         $over = PublicInbox::Over->new($over);
  39                         my $tmp_over = "$new/over.sqlite3";
  40                         $over->connect->sqlite_backup_to_file($tmp_over);
  41                         $over = undef;
  42                 }
  43
  44                 if (!defined($new)) { # culled shard
  45                         push @old_shard, $old;
  46                         next;
  47                 }
  48
  49                 if (@st) {
  50                         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  51                         rename($old, "$new/old") or
  52                                         die "rename $old => $new/old: $!\n";
  53                 }
  54                 # Xtmpdir->DESTROY won't remove $new after this:
  55                 rename($new, $old) or die "rename $new => $old: $!\n";
  56                 if (@st) {
  57                         my $prev = "$old/old";
  58                         remove_tree($prev) or
  59                                 die "failed to remove $prev: $!\n";
  60                 }
  61         }
  62         remove_tree(@old_shard);
  63         $tmp = undef;
  64         if (!$opt->{-coarse_lock}) {
  65                 $opt->{-skip_lock} = 1;
  66
  67                 if ($im->can('count_shards')) {
  68                         my $pr = $opt->{-progress};
  69                         my $n = $im->count_shards;
  70                         if (defined $reshard && $n != $reshard) {
  71                                 die
  72 "BUG: counted $n shards after resharding to $reshard";
  73                         }
  74                         my $prev = $im->{shards};
  75                         if ($pr && $prev != $n) {
  76                                 $pr->("shard count changed: $prev => $n\n");
  77                                 $im->{shards} = $n;
  78                         }
  79                 }
  80
  81                 PublicInbox::Admin::index_inbox($ibx, $im, $opt);
  82         }
  83 }
  84
  85 sub cb_spawn {
  86         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  87         defined(my $pid = fork) or die "fork: $!";
  88         return $pid if $pid > 0;
  89         $cb->($args, $opt);
  90         POSIX::_exit(0);
  91 }
  92
  93 sub runnable_or_die ($) {
  94         my ($exe) = @_;
  95         which($exe) or die "$exe not found in PATH\n";
  96 }
  97
  98 sub prepare_reindex ($$$) {
  99         my ($ibx, $im, $reindex) = @_;
 100         if ($ibx->version == 1) {
 101                 my $dir = $ibx->search->xdir(1);
 102                 my $xdb = $PublicInbox::Search::X{Database}->new($dir);
 103                 if (my $lc = $xdb->get_metadata('last_commit')) {
 104                         $reindex->{from} = $lc;
 105                 }
 106         } else { # v2
 107                 my $max;
 108                 $im->git_dir_latest(\$max) or return;
 109                 my $from = $reindex->{from};
 110                 my $mm = $ibx->mm;
 111                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 112                 foreach my $i (0..$max) {
 113                         $from->[$i] = $mm->last_commit_xap($v, $i);
 114                 }
 115         }
 116 }
 117
 118 sub same_fs_or_die ($$) {
 119         my ($x, $y) = @_;
 120         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
 121         die "$x and $y reside on different filesystems\n";
 122 }
 123
 124 sub process_queue {
 125         my ($queue, $cb, $opt) = @_;
 126         my $max = $opt->{jobs} || scalar(@$queue);
 127         if ($max <= 1) {
 128                 while (defined(my $args = shift @$queue)) {
 129                         $cb->($args, $opt);
 130                 }
 131                 return;
 132         }
 133
 134         # run in parallel:
 135         my %pids;
 136         while (@$queue) {
 137                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 138                         my $args = shift @$queue;
 139                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 140                 }
 141
 142                 while (scalar keys %pids) {
 143                         my $pid = waitpid(-1, 0);
 144                         my $args = delete $pids{$pid};
 145                         die join(' ', @$args)." failed: $?\n" if $?;
 146                 }
 147         }
 148 }
 149
 150 sub setup_signals () {
 151         # http://www.tldp.org/LDP/abs/html/exitcodes.html
 152         $SIG{INT} = sub { exit(130) };
 153         $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = sub { exit(1) };
 154 }
 155
 156 sub prepare_run {
 157         my ($ibx, $opt) = @_;
 158         my $tmp = {}; # old shard dir => File::Temp->newdir object or undef
 159         my @queue; # ([old//src,newdir]) - list of args for cpdb() or compact()
 160
 161         my $old = $ibx->search->xdir(1);
 162         -d $old or die "$old does not exist\n";
 163         my $reshard = $opt->{reshard};
 164         if (defined $reshard && $reshard <= 0) {
 165                 die "--reshard must be a positive number\n";
 166         }
 167
 168         # we want temporary directories to be as deep as possible,
 169         # so v2 shards can keep "xap$SCHEMA_VERSION" on a separate FS.
 170         if ($ibx->version == 1) {
 171                 if (defined $reshard) {
 172                         warn
 173 "--reshard=$reshard ignored for v1 $ibx->{inboxdir}\n";
 174                 }
 175                 my $dir = dirname($old);
 176                 same_fs_or_die($dir, $old);
 177                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 178                 my $wip = File::Temp->newdir("xapian$v-XXXXXXXX", DIR => $dir);
 179                 $tmp->{$old} = $wip;
 180                 push @queue, [ $old, $wip ];
 181         } else {
 182                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 183                 my @old_shards;
 184                 while (defined(my $dn = readdir($dh))) {
 185                         if ($dn =~ /\A[0-9]+\z/) {
 186                                 push @old_shards, $dn;
 187                         } elsif ($dn eq '.' || $dn eq '..') {
 188                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 189                         } else {
 190                                 warn "W: skipping unknown dir: $old/$dn\n"
 191                         }
 192                 }
 193                 die "No Xapian shards found in $old\n" unless @old_shards;
 194
 195                 my ($src, $max_shard);
 196                 if (!defined($reshard) || $reshard == scalar(@old_shards)) {
 197                         # 1:1 copy
 198                         $max_shard = scalar(@old_shards) - 1;
 199                 } else {
 200                         # M:N copy
 201                         $max_shard = $reshard - 1;
 202                         $src = [ map { "$old/$_" } @old_shards ];
 203                 }
 204                 foreach my $dn (0..$max_shard) {
 205                         my $tmpl = "$dn-XXXXXXXX";
 206                         my $wip = File::Temp->newdir($tmpl, DIR => $old);
 207                         same_fs_or_die($old, $wip->dirname);
 208                         my $cur = "$old/$dn";
 209                         push @queue, [ $src // $cur , $wip ];
 210                         $tmp->{$cur} = $wip;
 211                 }
 212                 # mark old shards to be unlinked
 213                 if ($src) {
 214                         $tmp->{$_} ||= undef for @$src;
 215                 }
 216         }
 217         ($tmp, \@queue);
 218 }
 219
 220 sub check_compact () { runnable_or_die($XAPIAN_COMPACT) }
 221
 222 sub run {
 223         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 224         my $cb = \&${\"PublicInbox::Xapcmd::$task"};
 225         PublicInbox::Admin::progress_prepare($opt ||= {});
 226         defined(my $dir = $ibx->{inboxdir}) or die "no inboxdir defined\n";
 227         -d $dir or die "inboxdir=$dir does not exist\n";
 228         check_compact() if $opt->{compact};
 229         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 230
 231         if (!$opt->{-coarse_lock}) {
 232                 $reindex = $opt->{reindex} = {};
 233                 $reindex->{from} = []; # per-epoch ranges
 234                 require PublicInbox::SearchIdx;
 235                 PublicInbox::SearchIdx::load_xapian_writable();
 236         }
 237
 238         local %SIG = %SIG;
 239         setup_signals();
 240         $ibx->umask_prepare;
 241         $ibx->with_umask(sub {
 242                 my $im = $ibx->importer(0);
 243                 $im->lock_acquire;
 244                 my ($tmp, $queue) = prepare_run($ibx, $opt);
 245
 246                 # fine-grained locking if we prepare for reindex
 247                 if (!$opt->{-coarse_lock}) {
 248                         prepare_reindex($ibx, $im, $reindex);
 249                         $im->lock_release;
 250                 }
 251
 252                 $ibx->cleanup;
 253                 process_queue($queue, $cb, $opt);
 254                 $im->lock_acquire if !$opt->{-coarse_lock};
 255                 commit_changes($ibx, $im, $tmp, $opt);
 256         });
 257 }
 258
 259 sub cpdb_retryable ($$) {
 260         my ($src, $pfx) = @_;
 261         if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 262                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 263                 $src->reopen;
 264                 return 1;
 265         }
 266         if ($@) {
 267                 warn "$pfx E: ", ref($@), "\n";
 268                 die;
 269         }
 270         0;
 271 }
 272
 273 sub progress_pfx ($) {
 274         my ($wip) = @_; # tempdir v2: ([0-9])+-XXXXXXXX
 275         my @p = split('/', $wip);
 276
 277         # return "xap15/0" for v2, or "xapian15" for v1:
 278         ($p[-1] =~ /\A([0-9]+)/) ? "$p[-2]/$1" : $p[-1];
 279 }
 280
 281 # xapian-compact wrapper
 282 sub compact ($$) {
 283         my ($args, $opt) = @_;
 284         my ($src, $newdir) = @$args;
 285         my $dst = ref($newdir) ? $newdir->dirname : $newdir;
 286         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 287         my $pr = $opt->{-progress};
 288         my $rdr = {};
 289
 290         foreach my $fd (0..2) {
 291                 defined(my $dfd = $opt->{$fd}) or next;
 292                 $rdr->{$fd} = $dfd;
 293         }
 294
 295         # we rely on --no-renumber to keep docids synched to NNTP
 296         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 297         for my $sw (qw(no-full fuller)) {
 298                 push @$cmd, "--$sw" if $opt->{$sw};
 299         }
 300         for my $sw (qw(blocksize)) {
 301                 defined(my $v = $opt->{$sw}) or next;
 302                 push @$cmd, "--$sw", $v;
 303         }
 304         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 305         push @$cmd, $src, $dst;
 306         my $rd = popen_rd($cmd, undef, $rdr);
 307         while (<$rd>) {
 308                 if ($pr) {
 309                         s/\r/\r$pfx /g;
 310                         $pr->("$pfx $_");
 311                 }
 312         }
 313         close $rd or die join(' ', @$cmd)." failed: $?n";
 314 }
 315
 316 sub cpdb_loop ($$$;$$) {
 317         my ($src, $dst, $pr_data, $cur_shard, $reshard) = @_;
 318         my ($pr, $fmt, $nr, $pfx);
 319         if ($pr_data) {
 320                 $pr = $pr_data->{pr};
 321                 $fmt = $pr_data->{fmt};
 322                 $nr = \($pr_data->{nr});
 323                 $pfx = $pr_data->{pfx};
 324         }
 325
 326         my ($it, $end);
 327         do {
 328                 eval {
 329                         $it = $src->postlist_begin('');
 330                         $end = $src->postlist_end('');
 331                 };
 332         } while (cpdb_retryable($src, $pfx));
 333
 334         do {
 335                 eval {
 336                         for (; $it != $end; $it++) {
 337                                 my $docid = $it->get_docid;
 338                                 if (defined $reshard) {
 339                                         my $dst_shard = $docid % $reshard;
 340                                         next if $dst_shard != $cur_shard;
 341                                 }
 342                                 my $doc = $src->get_document($docid);
 343                                 $dst->replace_document($docid, $doc);
 344                                 if ($pr_data && !(++$$nr  & 1023)) {
 345                                         $pr->(sprintf($fmt, $$nr));
 346                                 }
 347                         }
 348
 349                         # unlike copydatabase(1), we don't copy spelling
 350                         # and synonym data (or other user metadata) since
 351                         # the Perl APIs don't expose iterators for them
 352                         # (and public-inbox does not use those features)
 353                 };
 354         } while (cpdb_retryable($src, $pfx));
 355 }
 356
 357 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 358 # to the overhead of Perl.
 359 sub cpdb ($$) {
 360         my ($args, $opt) = @_;
 361         my ($old, $newdir) = @$args;
 362         my $new = $newdir->dirname;
 363         my ($src, $cur_shard);
 364         my $reshard;
 365         PublicInbox::SearchIdx::load_xapian_writable() or die;
 366         my $XapianDatabase = $PublicInbox::Search::X{Database};
 367         if (ref($old) eq 'ARRAY') {
 368                 ($cur_shard) = ($new =~ m!xap[0-9]+/([0-9]+)\b!);
 369                 defined $cur_shard or
 370                         die "BUG: could not extract shard # from $new";
 371                 $reshard = $opt->{reshard};
 372                 defined $reshard or die 'BUG: got array src w/o --reshard';
 373
 374                 # resharding, M:N copy means have full read access
 375                 foreach (@$old) {
 376                         if ($src) {
 377                                 my $sub = $XapianDatabase->new($_);
 378                                 $src->add_database($sub);
 379                         } else {
 380                                 $src = $XapianDatabase->new($_);
 381                         }
 382                 }
 383         } else {
 384                 $src = $XapianDatabase->new($old);
 385         }
 386
 387         my ($tmp, $ft);
 388         local %SIG = %SIG;
 389         if ($opt->{compact}) {
 390                 my $dir = dirname($new);
 391                 same_fs_or_die($dir, $new);
 392                 $ft = File::Temp->newdir("$new.compact-XXXXXX", DIR => $dir);
 393                 setup_signals();
 394                 $tmp = $ft->dirname;
 395         } else {
 396                 $tmp = $new;
 397         }
 398
 399         # like copydatabase(1), be sure we don't overwrite anything in case
 400         # of other bugs:
 401         my $creat = eval($PublicInbox::Search::Xap.'::DB_CREATE()');
 402         die if $@;
 403         my $XapianWritableDatabase = $PublicInbox::Search::X{WritableDatabase};
 404         my $dst = $XapianWritableDatabase->new($tmp, $creat);
 405         my $pr = $opt->{-progress};
 406         my $pfx = $opt->{-progress_pfx} = progress_pfx($new);
 407         my $pr_data = { pr => $pr, pfx => $pfx, nr => 0 } if $pr;
 408
 409         do {
 410                 eval {
 411                         # update the only metadata key for v1:
 412                         my $lc = $src->get_metadata('last_commit');
 413                         $dst->set_metadata('last_commit', $lc) if $lc;
 414
 415                         # only the first xapian shard (0) gets 'indexlevel'
 416                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 417                                 my $l = $src->get_metadata('indexlevel');
 418                                 if ($l eq 'medium') {
 419                                         $dst->set_metadata('indexlevel', $l);
 420                                 }
 421                         }
 422                         if ($pr_data) {
 423                                 my $tot = $src->get_doccount;
 424
 425                                 # we can only estimate when resharding,
 426                                 # because removed spam causes slight imbalance
 427                                 my $est = '';
 428                                 if (defined $cur_shard && $reshard > 1) {
 429                                         $tot = int($tot/$reshard);
 430                                         $est = 'around ';
 431                                 }
 432                                 my $fmt = "$pfx % ".length($tot)."u/$tot\n";
 433                                 $pr->("$pfx copying $est$tot documents\n");
 434                                 $pr_data->{fmt} = $fmt;
 435                                 $pr_data->{total} = $tot;
 436                         }
 437                 };
 438         } while (cpdb_retryable($src, $pfx));
 439
 440         if (defined $reshard) {
 441                 # we rely on document IDs matching NNTP article number,
 442                 # so we can't have the Xapian sharding DB support rewriting
 443                 # document IDs.  Thus we iterate through each shard
 444                 # individually.
 445                 $src = undef;
 446                 foreach (@$old) {
 447                         my $old = $XapianDatabase->new($_);
 448                         cpdb_loop($old, $dst, $pr_data, $cur_shard, $reshard);
 449                 }
 450         } else {
 451                 cpdb_loop($src, $dst, $pr_data);
 452         }
 453
 454         $pr->(sprintf($pr_data->{fmt}, $pr_data->{nr})) if $pr;
 455         return unless $opt->{compact};
 456
 457         $src = $dst = undef; # flushes and closes
 458
 459         # this is probably the best place to do xapian-compact
 460         # since $dst isn't readable by HTTP or NNTP clients, yet:
 461         compact([ $tmp, $new ], $opt);
 462         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 463 }
 464
 465 1;