lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use PublicInbox::Spawn qw(which popen_rd nodatacow_dir);
   6 use PublicInbox::Admin qw(setup_signals);
   7 use PublicInbox::Over;
   8 use PublicInbox::SearchIdx;
   9 use File::Temp 0.19 (); # ->newdir
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12 use POSIX qw(WNOHANG);
  13
  14 # support testing with dev versions of Xapian which installs
  15 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  16 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  17 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  18
  19 sub commit_changes ($$$$) {
  20         my ($ibx, $im, $tmp, $opt) = @_;
  21         my $reshard = $opt->{reshard};
  22         my $reindex = $opt->{reindex};
  23
  24         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  25         my @old_shard;
  26         my $over_chg;
  27
  28         while (my ($old, $newdir) = each %$tmp) {
  29                 next if $old eq ''; # no invalid paths
  30                 my @st = stat($old);
  31                 if (!@st && !defined($opt->{reshard})) {
  32                         die "failed to stat($old): $!";
  33                 }
  34
  35                 my $new = $newdir->dirname if defined($newdir);
  36                 my $over = "$old/over.sqlite3";
  37                 if (-f $over) { # only for v1, v2 over is untouched
  38                         defined $new or die "BUG: $over exists when culling v2";
  39                         $over = PublicInbox::Over->new($over);
  40                         my $tmp_over = "$new/over.sqlite3";
  41                         $over->connect->sqlite_backup_to_file($tmp_over);
  42                         $over = undef;
  43                         $over_chg = 1;
  44                 }
  45
  46                 if (!defined($new)) { # culled shard
  47                         push @old_shard, $old;
  48                         next;
  49                 }
  50
  51                 if (@st) {
  52                         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  53                         rename($old, "$new/old") or
  54                                         die "rename $old => $new/old: $!\n";
  55                 }
  56                 rename($new, $old) or die "rename $new => $old: $!\n";
  57                 if (@st) {
  58                         my $prev = "$old/old";
  59                         remove_tree($prev) or
  60                                 die "failed to remove $prev: $!\n";
  61                 }
  62         }
  63
  64         # trigger ->check_inodes in read-only daemons
  65         syswrite($im->{lockfh}, '.') if $over_chg;
  66
  67         remove_tree(@old_shard);
  68         $tmp = undef;
  69         if (!$opt->{-coarse_lock}) {
  70                 $opt->{-skip_lock} = 1;
  71
  72                 if ($im->can('count_shards')) {
  73                         my $pr = $opt->{-progress};
  74                         my $n = $im->count_shards;
  75                         if (defined $reshard && $n != $reshard) {
  76                                 die
  77 "BUG: counted $n shards after resharding to $reshard";
  78                         }
  79                         my $prev = $im->{shards};
  80                         if ($pr && $prev != $n) {
  81                                 $pr->("shard count changed: $prev => $n\n");
  82                                 $im->{shards} = $n;
  83                         }
  84                 }
  85
  86                 PublicInbox::Admin::index_inbox($ibx, $im, $opt);
  87         }
  88 }
  89
  90 sub cb_spawn {
  91         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  92         defined(my $pid = fork) or die "fork: $!";
  93         return $pid if $pid > 0;
  94         $cb->($args, $opt);
  95         POSIX::_exit(0);
  96 }
  97
  98 sub runnable_or_die ($) {
  99         my ($exe) = @_;
 100         which($exe) or die "$exe not found in PATH\n";
 101 }
 102
 103 sub prepare_reindex ($$$) {
 104         my ($ibx, $im, $reindex) = @_;
 105         if ($ibx->version == 1) {
 106                 my $dir = $ibx->search->xdir(1);
 107                 my $xdb = $PublicInbox::Search::X{Database}->new($dir);
 108                 if (my $lc = $xdb->get_metadata('last_commit')) {
 109                         $reindex->{from} = $lc;
 110                 }
 111         } else { # v2
 112                 my $max;
 113                 $im->git_dir_latest(\$max) or return;
 114                 my $from = $reindex->{from};
 115                 my $mm = $ibx->mm;
 116                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 117                 foreach my $i (0..$max) {
 118                         $from->[$i] = $mm->last_commit_xap($v, $i);
 119                 }
 120         }
 121 }
 122
 123 sub same_fs_or_die ($$) {
 124         my ($x, $y) = @_;
 125         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
 126         die "$x and $y reside on different filesystems\n";
 127 }
 128
 129 sub kill_pids {
 130         my ($sig, $pids) = @_;
 131         kill($sig, keys %$pids); # pids may be empty
 132 }
 133
 134 sub process_queue {
 135         my ($queue, $cb, $opt) = @_;
 136         my $max = $opt->{jobs} // scalar(@$queue);
 137         if ($max <= 1) {
 138                 while (defined(my $args = shift @$queue)) {
 139                         $cb->($args, $opt);
 140                 }
 141                 return;
 142         }
 143
 144         # run in parallel:
 145         my %pids;
 146         local %SIG = %SIG;
 147         setup_signals(\&kill_pids, \%pids);
 148         while (@$queue) {
 149                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 150                         my $args = shift @$queue;
 151                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 152                 }
 153
 154                 my $flags = 0;
 155                 while (scalar keys %pids) {
 156                         my $pid = waitpid(-1, $flags) or last;
 157                         last if $pid < 0;
 158                         my $args = delete $pids{$pid};
 159                         if ($args) {
 160                                 die join(' ', @$args)." failed: $?\n" if $?;
 161                         } else {
 162                                 warn "unknown PID($pid) reaped: $?\n";
 163                         }
 164                         $flags = WNOHANG if scalar(@$queue);
 165                 }
 166         }
 167 }
 168
 169 sub prepare_run {
 170         my ($ibx, $opt) = @_;
 171         my $tmp = {}; # old shard dir => File::Temp->newdir object or undef
 172         my @queue; # ([old//src,newdir]) - list of args for cpdb() or compact()
 173         my $old;
 174         if (my $srch = $ibx->search) {
 175                 $old = $srch->xdir(1);
 176                 -d $old or die "$old does not exist\n";
 177         }
 178         my $reshard = $opt->{reshard};
 179         if (defined $reshard && $reshard <= 0) {
 180                 die "--reshard must be a positive number\n";
 181         }
 182
 183         # we want temporary directories to be as deep as possible,
 184         # so v2 shards can keep "xap$SCHEMA_VERSION" on a separate FS.
 185         if ($old && $ibx->version == 1) {
 186                 if (defined $reshard) {
 187                         warn
 188 "--reshard=$reshard ignored for v1 $ibx->{inboxdir}\n";
 189                 }
 190                 my $dir = dirname($old);
 191                 same_fs_or_die($dir, $old);
 192                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 193                 my $wip = File::Temp->newdir("xapian$v-XXXXXXXX", DIR => $dir);
 194                 $tmp->{$old} = $wip;
 195                 nodatacow_dir($wip->dirname);
 196                 push @queue, [ $old, $wip ];
 197         } elsif ($old) {
 198                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 199                 my @old_shards;
 200                 while (defined(my $dn = readdir($dh))) {
 201                         if ($dn =~ /\A[0-9]+\z/) {
 202                                 push @old_shards, $dn;
 203                         } elsif ($dn eq '.' || $dn eq '..') {
 204                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 205                         } else {
 206                                 warn "W: skipping unknown dir: $old/$dn\n"
 207                         }
 208                 }
 209                 die "No Xapian shards found in $old\n" unless @old_shards;
 210
 211                 my ($src, $max_shard);
 212                 if (!defined($reshard) || $reshard == scalar(@old_shards)) {
 213                         # 1:1 copy
 214                         $max_shard = scalar(@old_shards) - 1;
 215                 } else {
 216                         # M:N copy
 217                         $max_shard = $reshard - 1;
 218                         $src = [ map { "$old/$_" } @old_shards ];
 219                 }
 220                 foreach my $dn (0..$max_shard) {
 221                         my $tmpl = "$dn-XXXXXXXX";
 222                         my $wip = File::Temp->newdir($tmpl, DIR => $old);
 223                         same_fs_or_die($old, $wip->dirname);
 224                         my $cur = "$old/$dn";
 225                         push @queue, [ $src // $cur , $wip ];
 226                         nodatacow_dir($wip->dirname);
 227                         $tmp->{$cur} = $wip;
 228                 }
 229                 # mark old shards to be unlinked
 230                 if ($src) {
 231                         $tmp->{$_} ||= undef for @$src;
 232                 }
 233         }
 234         ($tmp, \@queue);
 235 }
 236
 237 sub check_compact () { runnable_or_die($XAPIAN_COMPACT) }
 238
 239 sub _run {
 240         my ($ibx, $cb, $opt, $reindex) = @_;
 241         my $im = $ibx->importer(0);
 242         $im->lock_acquire;
 243         my ($tmp, $queue) = prepare_run($ibx, $opt);
 244
 245         # fine-grained locking if we prepare for reindex
 246         if (!$opt->{-coarse_lock}) {
 247                 prepare_reindex($ibx, $im, $reindex);
 248                 $im->lock_release;
 249         }
 250
 251         $ibx->cleanup;
 252         process_queue($queue, $cb, $opt);
 253         $im->lock_acquire if !$opt->{-coarse_lock};
 254         commit_changes($ibx, $im, $tmp, $opt);
 255 }
 256
 257 sub run {
 258         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 259         my $cb = \&$task;
 260         PublicInbox::Admin::progress_prepare($opt ||= {});
 261         defined(my $dir = $ibx->{inboxdir}) or die "no inboxdir defined\n";
 262         -d $dir or die "inboxdir=$dir does not exist\n";
 263         check_compact() if $opt->{compact} && $ibx->search;
 264         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 265
 266         if (!$opt->{-coarse_lock}) {
 267                 $reindex = $opt->{reindex} = { # per-epoch ranges for v2
 268                         from => $ibx->version == 1 ? '' : [],
 269                 };
 270                 PublicInbox::SearchIdx::load_xapian_writable();
 271         }
 272
 273         local %SIG = %SIG;
 274         setup_signals();
 275         $ibx->umask_prepare;
 276         $ibx->with_umask(\&_run, $ibx, $cb, $opt, $reindex);
 277 }
 278
 279 sub cpdb_retryable ($$) {
 280         my ($src, $pfx) = @_;
 281         if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 282                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 283                 $src->reopen;
 284                 return 1;
 285         }
 286         if ($@) {
 287                 warn "$pfx E: ", ref($@), "\n";
 288                 die;
 289         }
 290         0;
 291 }
 292
 293 sub progress_pfx ($) {
 294         my ($wip) = @_; # tempdir v2: ([0-9])+-XXXXXXXX
 295         my @p = split('/', $wip);
 296
 297         # return "xap15/0" for v2, or "xapian15" for v1:
 298         ($p[-1] =~ /\A([0-9]+)/) ? "$p[-2]/$1" : $p[-1];
 299 }
 300
 301 sub kill_compact { # setup_signals callback
 302         my ($sig, $pidref) = @_;
 303         kill($sig, $$pidref) if defined($$pidref);
 304 }
 305
 306 # xapian-compact wrapper
 307 sub compact ($$) {
 308         my ($args, $opt) = @_;
 309         my ($src, $newdir) = @$args;
 310         my $dst = ref($newdir) ? $newdir->dirname : $newdir;
 311         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 312         my $pr = $opt->{-progress};
 313         my $rdr = {};
 314
 315         foreach my $fd (0..2) {
 316                 defined(my $dfd = $opt->{$fd}) or next;
 317                 $rdr->{$fd} = $dfd;
 318         }
 319
 320         # we rely on --no-renumber to keep docids synched to NNTP
 321         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 322         for my $sw (qw(no-full fuller)) {
 323                 push @$cmd, "--$sw" if $opt->{$sw};
 324         }
 325         for my $sw (qw(blocksize)) {
 326                 defined(my $v = $opt->{$sw}) or next;
 327                 push @$cmd, "--$sw", $v;
 328         }
 329         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 330         push @$cmd, $src, $dst;
 331         my ($rd, $pid);
 332         local %SIG = %SIG;
 333         setup_signals(\&kill_compact, \$pid);
 334         ($rd, $pid) = popen_rd($cmd, undef, $rdr);
 335         while (<$rd>) {
 336                 if ($pr) {
 337                         s/\r/\r$pfx /g;
 338                         $pr->("$pfx $_");
 339                 }
 340         }
 341         waitpid($pid, 0);
 342         die "@$cmd failed: \$?=$?\n" if $?;
 343 }
 344
 345 sub cpdb_loop ($$$;$$) {
 346         my ($src, $dst, $pr_data, $cur_shard, $reshard) = @_;
 347         my ($pr, $fmt, $nr, $pfx);
 348         if ($pr_data) {
 349                 $pr = $pr_data->{pr};
 350                 $fmt = $pr_data->{fmt};
 351                 $nr = \($pr_data->{nr});
 352                 $pfx = $pr_data->{pfx};
 353         }
 354
 355         my ($it, $end);
 356         do {
 357                 eval {
 358                         $it = $src->postlist_begin('');
 359                         $end = $src->postlist_end('');
 360                 };
 361         } while (cpdb_retryable($src, $pfx));
 362
 363         do {
 364                 eval {
 365                         for (; $it != $end; $it++) {
 366                                 my $docid = $it->get_docid;
 367                                 if (defined $reshard) {
 368                                         my $dst_shard = $docid % $reshard;
 369                                         next if $dst_shard != $cur_shard;
 370                                 }
 371                                 my $doc = $src->get_document($docid);
 372                                 $dst->replace_document($docid, $doc);
 373                                 if ($pr_data && !(++$$nr  & 1023)) {
 374                                         $pr->(sprintf($fmt, $$nr));
 375                                 }
 376                         }
 377
 378                         # unlike copydatabase(1), we don't copy spelling
 379                         # and synonym data (or other user metadata) since
 380                         # the Perl APIs don't expose iterators for them
 381                         # (and public-inbox does not use those features)
 382                 };
 383         } while (cpdb_retryable($src, $pfx));
 384 }
 385
 386 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 387 # to the overhead of Perl.
 388 sub cpdb ($$) {
 389         my ($args, $opt) = @_;
 390         my ($old, $newdir) = @$args;
 391         my $new = $newdir->dirname;
 392         my ($src, $cur_shard);
 393         my $reshard;
 394         PublicInbox::SearchIdx::load_xapian_writable() or die;
 395         my $XapianDatabase = $PublicInbox::Search::X{Database};
 396         if (ref($old) eq 'ARRAY') {
 397                 ($cur_shard) = ($new =~ m!xap[0-9]+/([0-9]+)\b!);
 398                 defined $cur_shard or
 399                         die "BUG: could not extract shard # from $new";
 400                 $reshard = $opt->{reshard};
 401                 defined $reshard or die 'BUG: got array src w/o --reshard';
 402
 403                 # resharding, M:N copy means have full read access
 404                 foreach (@$old) {
 405                         if ($src) {
 406                                 my $sub = $XapianDatabase->new($_);
 407                                 $src->add_database($sub);
 408                         } else {
 409                                 $src = $XapianDatabase->new($_);
 410                         }
 411                 }
 412         } else {
 413                 $src = $XapianDatabase->new($old);
 414         }
 415
 416         my ($tmp, $ft);
 417         local %SIG = %SIG;
 418         if ($opt->{compact}) {
 419                 my $dir = dirname($new);
 420                 same_fs_or_die($dir, $new);
 421                 $ft = File::Temp->newdir("$new.compact-XXXXXX", DIR => $dir);
 422                 setup_signals();
 423                 $tmp = $ft->dirname;
 424                 nodatacow_dir($tmp);
 425         } else {
 426                 $tmp = $new;
 427         }
 428
 429         # like copydatabase(1), be sure we don't overwrite anything in case
 430         # of other bugs:
 431         my $flag = eval($PublicInbox::Search::Xap.'::DB_CREATE()');
 432         die if $@;
 433         my $XapianWritableDatabase = $PublicInbox::Search::X{WritableDatabase};
 434         $flag |= $PublicInbox::SearchIdx::DB_NO_SYNC if !$opt->{fsync};
 435         my $dst = $XapianWritableDatabase->new($tmp, $flag);
 436         my $pr = $opt->{-progress};
 437         my $pfx = $opt->{-progress_pfx} = progress_pfx($new);
 438         my $pr_data = { pr => $pr, pfx => $pfx, nr => 0 } if $pr;
 439
 440         do {
 441                 eval {
 442                         # update the only metadata key for v1:
 443                         my $lc = $src->get_metadata('last_commit');
 444                         $dst->set_metadata('last_commit', $lc) if $lc;
 445
 446                         # only the first xapian shard (0) gets 'indexlevel'
 447                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 448                                 my $l = $src->get_metadata('indexlevel');
 449                                 if ($l eq 'medium') {
 450                                         $dst->set_metadata('indexlevel', $l);
 451                                 }
 452                         }
 453                         if ($pr_data) {
 454                                 my $tot = $src->get_doccount;
 455
 456                                 # we can only estimate when resharding,
 457                                 # because removed spam causes slight imbalance
 458                                 my $est = '';
 459                                 if (defined $cur_shard && $reshard > 1) {
 460                                         $tot = int($tot/$reshard);
 461                                         $est = 'around ';
 462                                 }
 463                                 my $fmt = "$pfx % ".length($tot)."u/$tot\n";
 464                                 $pr->("$pfx copying $est$tot documents\n");
 465                                 $pr_data->{fmt} = $fmt;
 466                                 $pr_data->{total} = $tot;
 467                         }
 468                 };
 469         } while (cpdb_retryable($src, $pfx));
 470
 471         if (defined $reshard) {
 472                 # we rely on document IDs matching NNTP article number,
 473                 # so we can't have the Xapian sharding DB support rewriting
 474                 # document IDs.  Thus we iterate through each shard
 475                 # individually.
 476                 $src = undef;
 477                 foreach (@$old) {
 478                         my $old = $XapianDatabase->new($_);
 479                         cpdb_loop($old, $dst, $pr_data, $cur_shard, $reshard);
 480                 }
 481         } else {
 482                 cpdb_loop($src, $dst, $pr_data);
 483         }
 484
 485         $pr->(sprintf($pr_data->{fmt}, $pr_data->{nr})) if $pr;
 486         return unless $opt->{compact};
 487
 488         $src = $dst = undef; # flushes and closes
 489
 490         # this is probably the best place to do xapian-compact
 491         # since $dst isn't readable by HTTP or NNTP clients, yet:
 492         compact([ $tmp, $new ], $opt);
 493         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 494 }
 495
 496 1;