lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which popen_rd);
   7 use PublicInbox::Over;
   8 use PublicInbox::SearchIdx;
   9 use File::Temp 0.19 (); # ->newdir
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12 use POSIX ();
  13
  14 # support testing with dev versions of Xapian which installs
  15 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  16 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  17 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  18
  19 sub commit_changes ($$$$) {
  20         my ($ibx, $im, $tmp, $opt) = @_;
  21         my $reshard = $opt->{reshard};
  22         my $reindex = $opt->{reindex};
  23
  24         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  25         my @old_shard;
  26         my $over_chg;
  27
  28         while (my ($old, $newdir) = each %$tmp) {
  29                 next if $old eq ''; # no invalid paths
  30                 my @st = stat($old);
  31                 if (!@st && !defined($opt->{reshard})) {
  32                         die "failed to stat($old): $!";
  33                 }
  34
  35                 my $new = $newdir->dirname if defined($newdir);
  36                 my $over = "$old/over.sqlite3";
  37                 if (-f $over) { # only for v1, v2 over is untouched
  38                         defined $new or die "BUG: $over exists when culling v2";
  39                         $over = PublicInbox::Over->new($over);
  40                         my $tmp_over = "$new/over.sqlite3";
  41                         $over->connect->sqlite_backup_to_file($tmp_over);
  42                         $over = undef;
  43                         $over_chg = 1;
  44                 }
  45
  46                 if (!defined($new)) { # culled shard
  47                         push @old_shard, $old;
  48                         next;
  49                 }
  50
  51                 if (@st) {
  52                         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  53                         rename($old, "$new/old") or
  54                                         die "rename $old => $new/old: $!\n";
  55                 }
  56                 # Xtmpdir->DESTROY won't remove $new after this:
  57                 rename($new, $old) or die "rename $new => $old: $!\n";
  58                 if (@st) {
  59                         my $prev = "$old/old";
  60                         remove_tree($prev) or
  61                                 die "failed to remove $prev: $!\n";
  62                 }
  63         }
  64
  65         # trigger ->check_inodes in read-only daemons
  66         syswrite($im->{lockfh}, '.') if $over_chg;
  67
  68         remove_tree(@old_shard);
  69         $tmp = undef;
  70         if (!$opt->{-coarse_lock}) {
  71                 $opt->{-skip_lock} = 1;
  72
  73                 if ($im->can('count_shards')) {
  74                         my $pr = $opt->{-progress};
  75                         my $n = $im->count_shards;
  76                         if (defined $reshard && $n != $reshard) {
  77                                 die
  78 "BUG: counted $n shards after resharding to $reshard";
  79                         }
  80                         my $prev = $im->{shards};
  81                         if ($pr && $prev != $n) {
  82                                 $pr->("shard count changed: $prev => $n\n");
  83                                 $im->{shards} = $n;
  84                         }
  85                 }
  86
  87                 PublicInbox::Admin::index_inbox($ibx, $im, $opt);
  88         }
  89 }
  90
  91 sub cb_spawn {
  92         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  93         defined(my $pid = fork) or die "fork: $!";
  94         return $pid if $pid > 0;
  95         $cb->($args, $opt);
  96         POSIX::_exit(0);
  97 }
  98
  99 sub runnable_or_die ($) {
 100         my ($exe) = @_;
 101         which($exe) or die "$exe not found in PATH\n";
 102 }
 103
 104 sub prepare_reindex ($$$) {
 105         my ($ibx, $im, $reindex) = @_;
 106         if ($ibx->version == 1) {
 107                 my $dir = $ibx->search->xdir(1);
 108                 my $xdb = $PublicInbox::Search::X{Database}->new($dir);
 109                 if (my $lc = $xdb->get_metadata('last_commit')) {
 110                         $reindex->{from} = $lc;
 111                 }
 112         } else { # v2
 113                 my $max;
 114                 $im->git_dir_latest(\$max) or return;
 115                 my $from = $reindex->{from};
 116                 my $mm = $ibx->mm;
 117                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 118                 foreach my $i (0..$max) {
 119                         $from->[$i] = $mm->last_commit_xap($v, $i);
 120                 }
 121         }
 122 }
 123
 124 sub same_fs_or_die ($$) {
 125         my ($x, $y) = @_;
 126         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
 127         die "$x and $y reside on different filesystems\n";
 128 }
 129
 130 sub process_queue {
 131         my ($queue, $cb, $opt) = @_;
 132         my $max = $opt->{jobs} || scalar(@$queue);
 133         if ($max <= 1) {
 134                 while (defined(my $args = shift @$queue)) {
 135                         $cb->($args, $opt);
 136                 }
 137                 return;
 138         }
 139
 140         # run in parallel:
 141         my %pids;
 142         while (@$queue) {
 143                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 144                         my $args = shift @$queue;
 145                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 146                 }
 147
 148                 while (scalar keys %pids) {
 149                         my $pid = waitpid(-1, 0);
 150                         my $args = delete $pids{$pid};
 151                         if ($args) {
 152                                 die join(' ', @$args)." failed: $?\n" if $?;
 153                         } else {
 154                                 warn "unknown PID($pid) reaped: $?\n";
 155                         }
 156                 }
 157         }
 158 }
 159
 160 sub setup_signals () {
 161         # http://www.tldp.org/LDP/abs/html/exitcodes.html
 162         $SIG{INT} = sub { exit(130) };
 163         $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = sub { exit(1) };
 164 }
 165
 166 sub prepare_run {
 167         my ($ibx, $opt) = @_;
 168         my $tmp = {}; # old shard dir => File::Temp->newdir object or undef
 169         my @queue; # ([old//src,newdir]) - list of args for cpdb() or compact()
 170
 171         my $old = $ibx->search->xdir(1);
 172         -d $old or die "$old does not exist\n";
 173         my $reshard = $opt->{reshard};
 174         if (defined $reshard && $reshard <= 0) {
 175                 die "--reshard must be a positive number\n";
 176         }
 177
 178         # we want temporary directories to be as deep as possible,
 179         # so v2 shards can keep "xap$SCHEMA_VERSION" on a separate FS.
 180         if ($ibx->version == 1) {
 181                 if (defined $reshard) {
 182                         warn
 183 "--reshard=$reshard ignored for v1 $ibx->{inboxdir}\n";
 184                 }
 185                 my $dir = dirname($old);
 186                 same_fs_or_die($dir, $old);
 187                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 188                 my $wip = File::Temp->newdir("xapian$v-XXXXXXXX", DIR => $dir);
 189                 $tmp->{$old} = $wip;
 190                 push @queue, [ $old, $wip ];
 191         } else {
 192                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 193                 my @old_shards;
 194                 while (defined(my $dn = readdir($dh))) {
 195                         if ($dn =~ /\A[0-9]+\z/) {
 196                                 push @old_shards, $dn;
 197                         } elsif ($dn eq '.' || $dn eq '..') {
 198                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 199                         } else {
 200                                 warn "W: skipping unknown dir: $old/$dn\n"
 201                         }
 202                 }
 203                 die "No Xapian shards found in $old\n" unless @old_shards;
 204
 205                 my ($src, $max_shard);
 206                 if (!defined($reshard) || $reshard == scalar(@old_shards)) {
 207                         # 1:1 copy
 208                         $max_shard = scalar(@old_shards) - 1;
 209                 } else {
 210                         # M:N copy
 211                         $max_shard = $reshard - 1;
 212                         $src = [ map { "$old/$_" } @old_shards ];
 213                 }
 214                 foreach my $dn (0..$max_shard) {
 215                         my $tmpl = "$dn-XXXXXXXX";
 216                         my $wip = File::Temp->newdir($tmpl, DIR => $old);
 217                         same_fs_or_die($old, $wip->dirname);
 218                         my $cur = "$old/$dn";
 219                         push @queue, [ $src // $cur , $wip ];
 220                         $tmp->{$cur} = $wip;
 221                 }
 222                 # mark old shards to be unlinked
 223                 if ($src) {
 224                         $tmp->{$_} ||= undef for @$src;
 225                 }
 226         }
 227         ($tmp, \@queue);
 228 }
 229
 230 sub check_compact () { runnable_or_die($XAPIAN_COMPACT) }
 231
 232 sub run {
 233         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 234         my $cb = \&${\"PublicInbox::Xapcmd::$task"};
 235         PublicInbox::Admin::progress_prepare($opt ||= {});
 236         defined(my $dir = $ibx->{inboxdir}) or die "no inboxdir defined\n";
 237         -d $dir or die "inboxdir=$dir does not exist\n";
 238         check_compact() if $opt->{compact};
 239         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 240
 241         if (!$opt->{-coarse_lock}) {
 242                 $reindex = $opt->{reindex} = {};
 243                 $reindex->{from} = []; # per-epoch ranges
 244                 require PublicInbox::SearchIdx;
 245                 PublicInbox::SearchIdx::load_xapian_writable();
 246         }
 247
 248         local %SIG = %SIG;
 249         setup_signals();
 250         $ibx->umask_prepare;
 251         $ibx->with_umask(sub {
 252                 my $im = $ibx->importer(0);
 253                 $im->lock_acquire;
 254                 my ($tmp, $queue) = prepare_run($ibx, $opt);
 255
 256                 # fine-grained locking if we prepare for reindex
 257                 if (!$opt->{-coarse_lock}) {
 258                         prepare_reindex($ibx, $im, $reindex);
 259                         $im->lock_release;
 260                 }
 261
 262                 $ibx->cleanup;
 263                 process_queue($queue, $cb, $opt);
 264                 $im->lock_acquire if !$opt->{-coarse_lock};
 265                 commit_changes($ibx, $im, $tmp, $opt);
 266         });
 267 }
 268
 269 sub cpdb_retryable ($$) {
 270         my ($src, $pfx) = @_;
 271         if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 272                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 273                 $src->reopen;
 274                 return 1;
 275         }
 276         if ($@) {
 277                 warn "$pfx E: ", ref($@), "\n";
 278                 die;
 279         }
 280         0;
 281 }
 282
 283 sub progress_pfx ($) {
 284         my ($wip) = @_; # tempdir v2: ([0-9])+-XXXXXXXX
 285         my @p = split('/', $wip);
 286
 287         # return "xap15/0" for v2, or "xapian15" for v1:
 288         ($p[-1] =~ /\A([0-9]+)/) ? "$p[-2]/$1" : $p[-1];
 289 }
 290
 291 # xapian-compact wrapper
 292 sub compact ($$) {
 293         my ($args, $opt) = @_;
 294         my ($src, $newdir) = @$args;
 295         my $dst = ref($newdir) ? $newdir->dirname : $newdir;
 296         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 297         my $pr = $opt->{-progress};
 298         my $rdr = {};
 299
 300         foreach my $fd (0..2) {
 301                 defined(my $dfd = $opt->{$fd}) or next;
 302                 $rdr->{$fd} = $dfd;
 303         }
 304
 305         # we rely on --no-renumber to keep docids synched to NNTP
 306         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 307         for my $sw (qw(no-full fuller)) {
 308                 push @$cmd, "--$sw" if $opt->{$sw};
 309         }
 310         for my $sw (qw(blocksize)) {
 311                 defined(my $v = $opt->{$sw}) or next;
 312                 push @$cmd, "--$sw", $v;
 313         }
 314         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 315         push @$cmd, $src, $dst;
 316         my $rd = popen_rd($cmd, undef, $rdr);
 317         while (<$rd>) {
 318                 if ($pr) {
 319                         s/\r/\r$pfx /g;
 320                         $pr->("$pfx $_");
 321                 }
 322         }
 323         close $rd or die join(' ', @$cmd)." failed: $?n";
 324 }
 325
 326 sub cpdb_loop ($$$;$$) {
 327         my ($src, $dst, $pr_data, $cur_shard, $reshard) = @_;
 328         my ($pr, $fmt, $nr, $pfx);
 329         if ($pr_data) {
 330                 $pr = $pr_data->{pr};
 331                 $fmt = $pr_data->{fmt};
 332                 $nr = \($pr_data->{nr});
 333                 $pfx = $pr_data->{pfx};
 334         }
 335
 336         my ($it, $end);
 337         do {
 338                 eval {
 339                         $it = $src->postlist_begin('');
 340                         $end = $src->postlist_end('');
 341                 };
 342         } while (cpdb_retryable($src, $pfx));
 343
 344         do {
 345                 eval {
 346                         for (; $it != $end; $it++) {
 347                                 my $docid = $it->get_docid;
 348                                 if (defined $reshard) {
 349                                         my $dst_shard = $docid % $reshard;
 350                                         next if $dst_shard != $cur_shard;
 351                                 }
 352                                 my $doc = $src->get_document($docid);
 353                                 $dst->replace_document($docid, $doc);
 354                                 if ($pr_data && !(++$$nr  & 1023)) {
 355                                         $pr->(sprintf($fmt, $$nr));
 356                                 }
 357                         }
 358
 359                         # unlike copydatabase(1), we don't copy spelling
 360                         # and synonym data (or other user metadata) since
 361                         # the Perl APIs don't expose iterators for them
 362                         # (and public-inbox does not use those features)
 363                 };
 364         } while (cpdb_retryable($src, $pfx));
 365 }
 366
 367 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 368 # to the overhead of Perl.
 369 sub cpdb ($$) {
 370         my ($args, $opt) = @_;
 371         my ($old, $newdir) = @$args;
 372         my $new = $newdir->dirname;
 373         my ($src, $cur_shard);
 374         my $reshard;
 375         PublicInbox::SearchIdx::load_xapian_writable() or die;
 376         my $XapianDatabase = $PublicInbox::Search::X{Database};
 377         if (ref($old) eq 'ARRAY') {
 378                 ($cur_shard) = ($new =~ m!xap[0-9]+/([0-9]+)\b!);
 379                 defined $cur_shard or
 380                         die "BUG: could not extract shard # from $new";
 381                 $reshard = $opt->{reshard};
 382                 defined $reshard or die 'BUG: got array src w/o --reshard';
 383
 384                 # resharding, M:N copy means have full read access
 385                 foreach (@$old) {
 386                         if ($src) {
 387                                 my $sub = $XapianDatabase->new($_);
 388                                 $src->add_database($sub);
 389                         } else {
 390                                 $src = $XapianDatabase->new($_);
 391                         }
 392                 }
 393         } else {
 394                 $src = $XapianDatabase->new($old);
 395         }
 396
 397         my ($tmp, $ft);
 398         local %SIG = %SIG;
 399         if ($opt->{compact}) {
 400                 my $dir = dirname($new);
 401                 same_fs_or_die($dir, $new);
 402                 $ft = File::Temp->newdir("$new.compact-XXXXXX", DIR => $dir);
 403                 setup_signals();
 404                 $tmp = $ft->dirname;
 405         } else {
 406                 $tmp = $new;
 407         }
 408
 409         # like copydatabase(1), be sure we don't overwrite anything in case
 410         # of other bugs:
 411         my $creat = eval($PublicInbox::Search::Xap.'::DB_CREATE()');
 412         die if $@;
 413         my $XapianWritableDatabase = $PublicInbox::Search::X{WritableDatabase};
 414         my $dst = $XapianWritableDatabase->new($tmp, $creat);
 415         my $pr = $opt->{-progress};
 416         my $pfx = $opt->{-progress_pfx} = progress_pfx($new);
 417         my $pr_data = { pr => $pr, pfx => $pfx, nr => 0 } if $pr;
 418
 419         do {
 420                 eval {
 421                         # update the only metadata key for v1:
 422                         my $lc = $src->get_metadata('last_commit');
 423                         $dst->set_metadata('last_commit', $lc) if $lc;
 424
 425                         # only the first xapian shard (0) gets 'indexlevel'
 426                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 427                                 my $l = $src->get_metadata('indexlevel');
 428                                 if ($l eq 'medium') {
 429                                         $dst->set_metadata('indexlevel', $l);
 430                                 }
 431                         }
 432                         if ($pr_data) {
 433                                 my $tot = $src->get_doccount;
 434
 435                                 # we can only estimate when resharding,
 436                                 # because removed spam causes slight imbalance
 437                                 my $est = '';
 438                                 if (defined $cur_shard && $reshard > 1) {
 439                                         $tot = int($tot/$reshard);
 440                                         $est = 'around ';
 441                                 }
 442                                 my $fmt = "$pfx % ".length($tot)."u/$tot\n";
 443                                 $pr->("$pfx copying $est$tot documents\n");
 444                                 $pr_data->{fmt} = $fmt;
 445                                 $pr_data->{total} = $tot;
 446                         }
 447                 };
 448         } while (cpdb_retryable($src, $pfx));
 449
 450         if (defined $reshard) {
 451                 # we rely on document IDs matching NNTP article number,
 452                 # so we can't have the Xapian sharding DB support rewriting
 453                 # document IDs.  Thus we iterate through each shard
 454                 # individually.
 455                 $src = undef;
 456                 foreach (@$old) {
 457                         my $old = $XapianDatabase->new($_);
 458                         cpdb_loop($old, $dst, $pr_data, $cur_shard, $reshard);
 459                 }
 460         } else {
 461                 cpdb_loop($src, $dst, $pr_data);
 462         }
 463
 464         $pr->(sprintf($pr_data->{fmt}, $pr_data->{nr})) if $pr;
 465         return unless $opt->{compact};
 466
 467         $src = $dst = undef; # flushes and closes
 468
 469         # this is probably the best place to do xapian-compact
 470         # since $dst isn't readable by HTTP or NNTP clients, yet:
 471         compact([ $tmp, $new ], $opt);
 472         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 473 }
 474
 475 1;