lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which spawn);
   7 use PublicInbox::Over;
   8 use PublicInbox::Search;
   9 use File::Temp qw(tempdir);
  10 use File::Path qw(remove_tree);
  11 use File::Basename qw(dirname);
  12
  13 # support testing with dev versions of Xapian which installs
  14 # commands with a version number suffix (e.g. "xapian-compact-1.5")
  15 our $XAPIAN_COMPACT = $ENV{XAPIAN_COMPACT} || 'xapian-compact';
  16 our @COMPACT_OPT = qw(jobs|j=i quiet|q blocksize|b=s no-full|n fuller|F);
  17
  18 sub commit_changes ($$$) {
  19         my ($ibx, $tmp, $opt) = @_;
  20
  21         my $reindex = $opt->{reindex};
  22         my $im = $ibx->importer(0);
  23         $im->lock_acquire if !$opt->{-coarse_lock};
  24
  25         $SIG{INT} or die 'BUG: $SIG{INT} not handled';
  26
  27         while (my ($old, $new) = each %$tmp) {
  28                 my @st = stat($old) or die "failed to stat($old): $!\n";
  29
  30                 my $over = "$old/over.sqlite3";
  31                 if (-f $over) { # only for v1, v2 over is untouched
  32                         $over = PublicInbox::Over->new($over);
  33                         my $tmp_over = "$new/over.sqlite3";
  34                         $over->connect->sqlite_backup_to_file($tmp_over);
  35                         $over = undef;
  36                 }
  37                 chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  38
  39                 # Xtmpdir->DESTROY won't remove $new after this:
  40                 rename($old, "$new/old") or die "rename $old => $new/old: $!\n";
  41                 rename($new, $old) or die "rename $new => $old: $!\n";
  42                 my $prev = "$old/old";
  43                 remove_tree($prev) or die "failed to remove $prev: $!\n";
  44         }
  45         $tmp->done;
  46         if (!$opt->{-coarse_lock}) {
  47                 $opt->{-skip_lock} = 1;
  48                 PublicInbox::Admin::index_inbox($ibx, $opt);
  49                 # implicit lock_release
  50         } else {
  51                 $im->lock_release;
  52         }
  53 }
  54
  55 sub cb_spawn {
  56         my ($cb, $args, $opt) = @_; # $cb = cpdb() or compact()
  57         defined(my $pid = fork) or die "fork: $!";
  58         return $pid if $pid > 0;
  59         $cb->($args, $opt);
  60         exit 0;
  61 }
  62
  63 sub runnable_or_die ($) {
  64         my ($exe) = @_;
  65         which($exe) or die "$exe not found in PATH\n";
  66 }
  67
  68 sub prepare_reindex ($$) {
  69         my ($ibx, $reindex) = @_;
  70         if ($ibx->{version} == 1) {
  71                 my $dir = $ibx->search->xdir(1);
  72                 my $xdb = Search::Xapian::Database->new($dir);
  73                 if (my $lc = $xdb->get_metadata('last_commit')) {
  74                         $reindex->{from} = $lc;
  75                 }
  76         } else { # v2
  77                 my $v2w = $ibx->importer(0);
  78                 my $max;
  79                 $v2w->git_dir_latest(\$max) or return;
  80                 my $from = $reindex->{from};
  81                 my $mm = $ibx->mm;
  82                 my $v = PublicInbox::Search::SCHEMA_VERSION();
  83                 foreach my $i (0..$max) {
  84                         $from->[$i] = $mm->last_commit_xap($v, $i);
  85                 }
  86         }
  87 }
  88
  89 sub same_fs_or_die ($$) {
  90         my ($x, $y) = @_;
  91         return if ((stat($x))[0] == (stat($y))[0]); # 0 - st_dev
  92         die "$x and $y reside on different filesystems\n";
  93 }
  94
  95 sub process_queue {
  96         my ($queue, $cb, $max, $opt) = @_;
  97         if ($max <= 1) {
  98                 while (defined(my $args = shift @$queue)) {
  99                         $cb->($args, $opt);
 100                 }
 101                 return;
 102         }
 103
 104         # run in parallel:
 105         my %pids;
 106         while (@$queue) {
 107                 while (scalar(keys(%pids)) < $max && scalar(@$queue)) {
 108                         my $args = shift @$queue;
 109                         $pids{cb_spawn($cb, $args, $opt)} = $args;
 110                 }
 111
 112                 while (scalar keys %pids) {
 113                         my $pid = waitpid(-1, 0);
 114                         my $args = delete $pids{$pid};
 115                         die join(' ', @$args)." failed: $?\n" if $?;
 116                 }
 117         }
 118 }
 119
 120 sub run {
 121         my ($ibx, $task, $opt) = @_; # task = 'cpdb' or 'compact'
 122         my $cb = \&${\"PublicInbox::Xapcmd::$task"};
 123         PublicInbox::Admin::progress_prepare($opt ||= {});
 124         my $dir = $ibx->{mainrepo} or die "no mainrepo in inbox\n";
 125         runnable_or_die($XAPIAN_COMPACT) if $opt->{compact};
 126         my $reindex; # v1:{ from => $x40 }, v2:{ from => [ $x40, $x40, .. ] } }
 127         my $from; # per-epoch ranges
 128
 129         if (!$opt->{-coarse_lock}) {
 130                 $reindex = $opt->{reindex} = {};
 131                 $from = $reindex->{from} = [];
 132                 require Search::Xapian::WritableDatabase;
 133         }
 134
 135         $ibx->umask_prepare;
 136         my $old = $ibx->search->xdir(1);
 137         -d $old or die "$old does not exist\n";
 138
 139         my $tmp = PublicInbox::Xtmpdirs->new;
 140         my $v = $ibx->{version} ||= 1;
 141         my @q;
 142
 143         # we want temporary directories to be as deep as possible,
 144         # so v2 partitions can keep "xap$SCHEMA_VERSION" on a separate FS.
 145         if ($v == 1) {
 146                 my $old_parent = dirname($old);
 147                 same_fs_or_die($old_parent, $old);
 148                 my $v = PublicInbox::Search::SCHEMA_VERSION();
 149                 $tmp->{$old} = tempdir("xapian$v-XXXXXXXX", DIR => $old_parent);
 150                 push @q, [ $old, $tmp->{$old} ];
 151         } else {
 152                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
 153                 while (defined(my $dn = readdir($dh))) {
 154                         if ($dn =~ /\A[0-9]+\z/) {
 155                                 my $tmpl = "$dn-XXXXXXXX";
 156                                 my $dst = tempdir($tmpl, DIR => $old);
 157                                 same_fs_or_die($old, $dst);
 158                                 my $cur = "$old/$dn";
 159                                 push @q, [ $cur, $dst ];
 160                                 $tmp->{$cur} = $dst;
 161                         } elsif ($dn eq '.' || $dn eq '..') {
 162                         } elsif ($dn =~ /\Aover\.sqlite3/) {
 163                         } else {
 164                                 warn "W: skipping unknown dir: $old/$dn\n"
 165                         }
 166                 }
 167                 die "No Xapian parts found in $old\n" unless @q;
 168         }
 169         my $im = $ibx->importer(0);
 170         my $max = $opt->{jobs} || scalar(@q);
 171         $ibx->with_umask(sub {
 172                 $im->lock_acquire;
 173
 174                 # fine-grained locking if we prepare for reindex
 175                 if (!$opt->{-coarse_lock}) {
 176                         prepare_reindex($ibx, $reindex);
 177                         $im->lock_release;
 178                 }
 179
 180                 delete($ibx->{$_}) for (qw(mm over search)); # cleanup
 181                 process_queue(\@q, $cb, $max, $opt);
 182                 commit_changes($ibx, $tmp, $opt);
 183         });
 184 }
 185
 186 sub cpdb_retryable ($$) {
 187         my ($src, $pfx) = @_;
 188         if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 189                 warn "$pfx Xapian DB modified, reopening and retrying\n";
 190                 $src->reopen;
 191                 return 1;
 192         }
 193         if ($@) {
 194                 warn "$pfx E: ", ref($@), "\n";
 195                 die;
 196         }
 197         0;
 198 }
 199
 200 sub progress_pfx ($) {
 201         my @p = split('/', $_[0]);
 202
 203         # return "xap15/0" for v2, or "xapian15" for v1:
 204         ($p[-1] =~ /\A[0-9]+\z/) ? "$p[-2]/$p[-1]" : $p[-1];
 205 }
 206
 207 # xapian-compact wrapper
 208 sub compact ($$) {
 209         my ($args, $opt) = @_;
 210         my ($src, $dst) = @$args;
 211         my ($r, $w);
 212         my $pfx = $opt->{-progress_pfx} ||= progress_pfx($src);
 213         my $pr = $opt->{-progress};
 214         my $rdr = {};
 215
 216         foreach my $fd (0..2) {
 217                 defined(my $dfd = $opt->{$fd}) or next;
 218                 $rdr->{$fd} = $dfd;
 219         }
 220         $rdr->{1} = fileno($w) if $pr && pipe($r, $w);
 221
 222         # we rely on --no-renumber to keep docids synched to NNTP
 223         my $cmd = [ $XAPIAN_COMPACT, '--no-renumber' ];
 224         for my $sw (qw(no-full fuller)) {
 225                 push @$cmd, "--$sw" if $opt->{$sw};
 226         }
 227         for my $sw (qw(blocksize)) {
 228                 defined(my $v = $opt->{$sw}) or next;
 229                 push @$cmd, "--$sw", $v;
 230         }
 231         $pr->("$pfx `".join(' ', @$cmd)."'\n") if $pr;
 232         push @$cmd, $src, $dst;
 233         my $pid = spawn($cmd, undef, $rdr);
 234         if ($pr) {
 235                 close $w or die "close: \$w: $!";
 236                 foreach (<$r>) {
 237                         s/\r/\r$pfx /g;
 238                         $pr->("$pfx $_");
 239                 }
 240         }
 241         my $rp = waitpid($pid, 0);
 242         if ($? || $rp != $pid) {
 243                 die join(' ', @$cmd)." failed: $? (pid=$pid, reaped=$rp)\n";
 244         }
 245 }
 246
 247 # Like copydatabase(1), this is horribly slow; and it doesn't seem due
 248 # to the overhead of Perl.
 249 sub cpdb ($$) {
 250         my ($args, $opt) = @_;
 251         my ($old, $new) = @$args;
 252         my $src = Search::Xapian::Database->new($old);
 253         my ($xtmp, $tmp);
 254         if ($opt->{compact}) {
 255                 my $newdir = dirname($new);
 256                 same_fs_or_die($newdir, $new);
 257                 $tmp = tempdir("$new.compact-XXXXXX", DIR => $newdir);
 258                 $xtmp = PublicInbox::Xtmpdirs->new;
 259                 $xtmp->{$new} = $tmp;
 260         } else {
 261                 $tmp = $new;
 262         }
 263
 264         # like copydatabase(1), be sure we don't overwrite anything in case
 265         # of other bugs:
 266         my $creat = Search::Xapian::DB_CREATE();
 267         my $dst = Search::Xapian::WritableDatabase->new($tmp, $creat);
 268         my ($it, $end);
 269         my ($nr, $tot, $fmt); # progress output
 270         my $pr = $opt->{-progress};
 271         my $pfx = $opt->{-progress_pfx} = progress_pfx($old);
 272
 273         do {
 274                 eval {
 275                         # update the only metadata key for v1:
 276                         my $lc = $src->get_metadata('last_commit');
 277                         $dst->set_metadata('last_commit', $lc) if $lc;
 278
 279                         # only the first xapian partition (0) gets 'indexlevel'
 280                         if ($new =~ m!(?:xapian[0-9]+|xap[0-9]+/0)\b!) {
 281                                 my $l = $src->get_metadata('indexlevel');
 282                                 if ($l eq 'medium') {
 283                                         $dst->set_metadata('indexlevel', $l);
 284                                 }
 285                         }
 286
 287                         $it = $src->postlist_begin('');
 288                         $end = $src->postlist_end('');
 289                         if ($pr) {
 290                                 $nr = 0;
 291                                 $tot = $src->get_doccount;
 292                                 $fmt = "$pfx % ".length($tot)."u/$tot\n";
 293                                 $pr->("$pfx copying $tot documents\n");
 294                         }
 295                 };
 296         } while (cpdb_retryable($src, $pfx));
 297
 298         do {
 299                 eval {
 300                         while ($it != $end) {
 301                                 my $docid = $it->get_docid;
 302                                 my $doc = $src->get_document($docid);
 303                                 $dst->replace_document($docid, $doc);
 304                                 $it->inc;
 305                                 if ($pr && !(++$nr & 1023)) {
 306                                         $pr->(sprintf($fmt, $nr));
 307                                 }
 308                         }
 309
 310                         # unlike copydatabase(1), we don't copy spelling
 311                         # and synonym data (or other user metadata) since
 312                         # the Perl APIs don't expose iterators for them
 313                         # (and public-inbox does not use those features)
 314                 };
 315         } while (cpdb_retryable($src, $pfx));
 316
 317         $pr->(sprintf($fmt, $nr)) if $pr;
 318         return unless $xtmp;
 319
 320         $src = $dst = undef; # flushes and closes
 321
 322         # this is probably the best place to do xapian-compact
 323         # since $dst isn't readable by HTTP or NNTP clients, yet:
 324         compact([ $tmp, $new ], $opt);
 325         remove_tree($tmp) or die "failed to remove $tmp: $!\n";
 326         $xtmp->done;
 327 }
 328
 329 # slightly easier-to-manage manage than END{} blocks
 330 package PublicInbox::Xtmpdirs;
 331 use strict;
 332 use warnings;
 333 use File::Path qw(remove_tree);
 334 my %owner;
 335
 336 sub new {
 337         # http://www.tldp.org/LDP/abs/html/exitcodes.html
 338         $SIG{INT} = sub { exit(130) };
 339         $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = sub { exit(1) };
 340         my $self = bless {}, $_[0]; # old partition => new (tmp) partition
 341         $owner{"$self"} = $$;
 342         $self;
 343 }
 344
 345 sub done {
 346         my ($self) = @_;
 347         delete $owner{"$self"};
 348
 349         my %known_pids;
 350         $known_pids{$_}++ foreach values %owner;
 351         if (!$known_pids{$$}) {
 352                 $SIG{INT} = $SIG{HUP} = $SIG{PIPE} = $SIG{TERM} = 'DEFAULT';
 353         }
 354         %$self = ();
 355 }
 356
 357 sub DESTROY {
 358         my ($self) = @_;
 359         my $owner_pid = delete $owner{"$self"} or return;
 360         return if $owner_pid != $$;
 361         foreach my $new (values %$self) {
 362                 remove_tree($new) unless -d "$new/old";
 363         }
 364         done($self);
 365 }
 366
 367 1;