lib/PublicInbox/Xapcmd.pm

   1 # Copyright (C) 2018-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Xapcmd;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(which spawn);
   7 use PublicInbox::Over;
   8 use File::Temp qw(tempdir);
   9 use File::Path qw(remove_tree);
  10
  11 sub commit_changes ($$$) {
  12         my ($im, $old, $new) = @_;
  13         my @st = stat($old) or die "failed to stat($old): $!\n";
  14
  15         my $over = "$old/over.sqlite3";
  16         if (-f $over) {
  17                 $over = PublicInbox::Over->new($over);
  18                 $over->connect->sqlite_backup_to_file("$new/over.sqlite3");
  19         }
  20         rename($old, "$new/old") or die "rename $old => $new/old: $!\n";
  21         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  22         rename($new, $old) or die "rename $new => $old: $!\n";
  23         $im->lock_release;
  24         remove_tree("$old/old") or die "failed to remove $old/old: $!\n";
  25 }
  26
  27 sub run {
  28         my ($ibx, $cmd, $env, $opt) = @_;
  29         $opt ||= {};
  30         my $dir = $ibx->{mainrepo} or die "no mainrepo in inbox\n";
  31         which($cmd->[0]) or die "$cmd->[0] not found in PATH\n";
  32         $ibx->umask_prepare;
  33         my $old = $ibx->search->xdir(1);
  34         -d $old or die "$old does not exist\n";
  35         my $new = tempdir($cmd->[0].'-XXXXXXXX', CLEANUP => 1, DIR => $dir);
  36         my $v = $ibx->{version} || 1;
  37         my @cmds;
  38         if ($v == 1) {
  39                 push @cmds, [@$cmd, $old, $new];
  40         } else {
  41                 opendir my $dh, $old or die "Failed to opendir $old: $!\n";
  42                 while (defined(my $dn = readdir($dh))) {
  43                         if ($dn =~ /\A\d+\z/) {
  44                                 push @cmds, [@$cmd, "$old/$dn", "$new/$dn"];
  45                         } elsif ($dn eq '.' || $dn eq '..') {
  46                         } elsif ($dn =~ /\Aover\.sqlite3/) {
  47                         } else {
  48                                 warn "W: skipping unknown dir: $old/$dn\n"
  49                         }
  50                 }
  51                 die "No Xapian parts found in $old\n" unless @cmds;
  52         }
  53         my $im = $ibx->importer(0);
  54         my $max = $opt->{jobs} || scalar(@cmds);
  55         $ibx->with_umask(sub {
  56                 $im->lock_acquire;
  57                 my %pids;
  58                 while (@cmds) {
  59                         while (scalar(keys(%pids)) < $max && scalar(@cmds)) {
  60                                 my $x = shift @cmds;
  61                                 $pids{spawn($x, $env, $opt)} = $x;
  62                         }
  63
  64                         while (scalar keys %pids) {
  65                                 my $pid = waitpid(-1, 0);
  66                                 my $x = delete $pids{$pid};
  67                                 die join(' ', @$x)." failed: $?\n" if $?;
  68                         }
  69                 }
  70                 commit_changes($im, $old, $new);
  71         });
  72 }
  73
  74 1;