public-inbox-httpd

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Standalone HTTP server for public-inbox.
   6 use strict;
   7 use warnings;
   8 use Plack::Util;
   9 use PublicInbox::Daemon;
  10 use PublicInbox::HTTP;
  11 use PublicInbox::WWW;
  12 use Plack::Request;
  13 use Plack::Builder;
  14 PublicInbox::WWW->preload;
  15 my $have_deflater = eval { require Plack::Middleware::Deflater; 1 };
  16 my %httpds;
  17 my $config;
  18 my $app;
  19 my $refresh = sub {
  20         if (@ARGV) {
  21                 eval { $app = Plack::Util::load_psgi(@ARGV) };
  22                 if ($@) {
  23                         die $@,
  24 "$0 runs in /, command-line paths must be absolute\n";
  25                 }
  26         } else {
  27                 my $www = PublicInbox::WWW->new;
  28                 $app = eval {
  29                         my $deflate_types = eval {
  30                                 require Plack::Middleware::Deflater;
  31                                 [ 'text/html', 'text/plain',
  32                                         'application/atom+xml' ]
  33                         };
  34                         builder {
  35                                 enable 'Chunked';
  36                                 if ($deflate_types) {
  37                                         enable 'Deflater',
  38                                                 content_type => $deflate_types
  39                                 }
  40                                 enable 'Head';
  41                                 sub { $www->call(@_) };
  42                         };
  43                 };
  44         }
  45 };
  46
  47 daemon_run('0.0.0.0:8080', $refresh,
  48         sub ($$$) { # post_accept
  49                 my ($client, $addr, $srv) = @_;
  50                 my $fd = fileno($srv);
  51                 my $h = $httpds{$fd} ||= PublicInbox::HTTPD->new($srv, $app);
  52                 PublicInbox::HTTP->new($client, $addr, $h),
  53         });
  54
  55 1;
  56
  57 package PublicInbox::HTTPD::Async;
  58 use strict;
  59 use warnings;
  60 use base qw(Danga::Socket);
  61 use fields qw(cb);
  62
  63 sub new {
  64         my ($class, $io, $cb) = @_;
  65         my $self = fields::new($class);
  66         $io->blocking(0);
  67         $self->SUPER::new($io);
  68         $self->{cb} = $cb;
  69         $self->watch_read(1);
  70         $self;
  71 }
  72
  73 sub event_read { $_[0]->{cb}->() }
  74 sub event_hup { $_[0]->{cb}->() }
  75 sub sysread { shift->{sock}->sysread(@_) }
  76
  77 1;
  78
  79 package PublicInbox::HTTPD;
  80 use strict;
  81 use warnings;
  82 use Plack::Util;
  83
  84 sub pi_httpd_async {
  85         my ($io, $cb) = @_;
  86         PublicInbox::HTTPD::Async->new($io, $cb);
  87 }
  88
  89 sub new {
  90         my ($class, $sock, $app) = @_;
  91         my $n = getsockname($sock) or die "not a socket: $sock $!\n";
  92         my ($port, $addr);
  93         if (length($n) >= 28) {
  94                 require Socket6;
  95                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
  96         } else {
  97                 ($port, $addr) = Socket::unpack_sockaddr_in($n);
  98         }
  99
 100         my %env = (
 101                 REMOTE_HOST => '',
 102                 REMOTE_PORT => 0,
 103                 SERVER_NAME => $addr,
 104                 SERVER_PORT => $port,
 105                 SCRIPT_NAME => '',
 106                 'psgi.version' => [ 1, 1 ],
 107                 'psgi.errors' => \*STDERR,
 108                 'psgi.url_scheme' => 'http',
 109                 'psgi.nonblocking' => Plack::Util::TRUE,
 110                 'psgi.streaming' => Plack::Util::TRUE,
 111                 'psgi.run_once'  => Plack::Util::FALSE,
 112                 'psgi.multithread' => Plack::Util::FALSE,
 113                 'psgi.multiprocess' => Plack::Util::TRUE,
 114                 'psgix.harakiri'=> Plack::Util::FALSE,
 115                 'psgix.input.buffered' => Plack::Util::TRUE,
 116                 'pi-httpd.async' => do {
 117                         no warnings 'once';
 118                         *pi_httpd_async
 119                 },
 120         );
 121         bless {
 122                 err => \*STDERR,
 123                 out => \*STDOUT,
 124                 app => $app,
 125                 env => \%env,
 126         }, $class;
 127 }
 128
 129 1;