public-inbox-httpd

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Standalone HTTP server for public-inbox.
   6 use strict;
   7 use warnings;
   8 use Plack::Util;
   9 use PublicInbox::Daemon;
  10 use PublicInbox::HTTP;
  11 use Plack::Request;
  12 use Plack::Builder;
  13 my %httpds;
  14 my $app;
  15 my $refresh = sub {
  16         if (@ARGV) {
  17                 eval { $app = Plack::Util::load_psgi(@ARGV) };
  18                 if ($@) {
  19                         die $@,
  20 "$0 runs in /, command-line paths must be absolute\n";
  21                 }
  22         } else {
  23                 require PublicInbox::WWW;
  24                 PublicInbox::WWW->preload;
  25                 my $www = PublicInbox::WWW->new;
  26                 $app = eval {
  27                         my $deflate_types = eval {
  28                                 require Plack::Middleware::Deflater;
  29                                 [ 'text/html', 'text/plain',
  30                                         'application/atom+xml' ]
  31                         };
  32                         builder {
  33                                 enable 'Chunked';
  34                                 if ($deflate_types) {
  35                                         enable 'Deflater',
  36                                                 content_type => $deflate_types
  37                                 }
  38                                 enable 'ReverseProxy';
  39                                 enable 'Head';
  40                                 sub { $www->call(@_) };
  41                         };
  42                 };
  43         }
  44 };
  45
  46 daemon_run('0.0.0.0:8080', $refresh,
  47         sub ($$$) { # post_accept
  48                 my ($client, $addr, $srv) = @_;
  49                 my $fd = fileno($srv);
  50                 my $h = $httpds{$fd} ||= PublicInbox::HTTPD->new($srv, $app);
  51                 PublicInbox::HTTP->new($client, $addr, $h),
  52         });
  53
  54 1;
  55
  56 package PublicInbox::HTTPD::Async;
  57 use strict;
  58 use warnings;
  59 use base qw(Danga::Socket);
  60 use fields qw(cb);
  61
  62 sub new {
  63         my ($class, $io, $cb) = @_;
  64         my $self = fields::new($class);
  65         $io->blocking(0);
  66         $self->SUPER::new($io);
  67         $self->{cb} = $cb;
  68         $self->watch_read(1);
  69         $self;
  70 }
  71
  72 sub event_read { $_[0]->{cb}->() }
  73 sub event_hup { $_[0]->{cb}->() }
  74 sub event_err { $_[0]->{cb}->() }
  75 sub sysread { shift->{sock}->sysread(@_) }
  76
  77 1;
  78
  79 package PublicInbox::HTTPD;
  80 use strict;
  81 use warnings;
  82 use Plack::Util;
  83
  84 sub pi_httpd_async {
  85         my ($io, $cb) = @_;
  86         PublicInbox::HTTPD::Async->new($io, $cb);
  87 }
  88
  89 sub new {
  90         my ($class, $sock, $app) = @_;
  91         my $n = getsockname($sock) or die "not a socket: $sock $!\n";
  92         my ($port, $addr);
  93         if (length($n) >= 28) {
  94                 require Socket6;
  95                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
  96         } else {
  97                 ($port, $addr) = Socket::unpack_sockaddr_in($n);
  98         }
  99
 100         my %env = (
 101                 REMOTE_HOST => '',
 102                 REMOTE_PORT => 0,
 103                 SERVER_NAME => $addr,
 104                 SERVER_PORT => $port,
 105                 SCRIPT_NAME => '',
 106                 'psgi.version' => [ 1, 1 ],
 107                 'psgi.errors' => \*STDERR,
 108                 'psgi.url_scheme' => 'http',
 109                 'psgi.nonblocking' => Plack::Util::TRUE,
 110                 'psgi.streaming' => Plack::Util::TRUE,
 111                 'psgi.run_once'  => Plack::Util::FALSE,
 112                 'psgi.multithread' => Plack::Util::FALSE,
 113                 'psgi.multiprocess' => Plack::Util::TRUE,
 114                 'psgix.harakiri'=> Plack::Util::FALSE,
 115                 'psgix.input.buffered' => Plack::Util::TRUE,
 116                 'pi-httpd.async' => do {
 117                         no warnings 'once';
 118                         *pi_httpd_async
 119                 },
 120         );
 121         bless {
 122                 err => \*STDERR,
 123                 out => \*STDOUT,
 124                 app => $app,
 125                 env => \%env,
 126         }, $class;
 127 }
 128
 129 1;