public-inbox-httpd

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Standalone HTTP server for public-inbox.
   6 use strict;
   7 use warnings;
   8 use Plack::Util;
   9 use PublicInbox::Daemon;
  10 use PublicInbox::HTTP;
  11 use Plack::Request;
  12 use Plack::Builder;
  13 my %httpds;
  14 my $app;
  15 my $refresh = sub {
  16         if (@ARGV) {
  17                 eval { $app = Plack::Util::load_psgi(@ARGV) };
  18                 if ($@) {
  19                         die $@,
  20 "$0 runs in /, command-line paths must be absolute\n";
  21                 }
  22         } else {
  23                 require PublicInbox::WWW;
  24                 PublicInbox::WWW->preload;
  25                 my $www = PublicInbox::WWW->new;
  26                 $app = eval {
  27                         my $deflate_types = eval {
  28                                 require Plack::Middleware::Deflater;
  29                                 [ 'text/html', 'text/plain',
  30                                         'application/atom+xml' ]
  31                         };
  32                         builder {
  33                                 enable 'Chunked';
  34                                 if ($deflate_types) {
  35                                         enable 'Deflater',
  36                                                 content_type => $deflate_types
  37                                 }
  38                                 enable 'Head';
  39                                 sub { $www->call(@_) };
  40                         };
  41                 };
  42         }
  43 };
  44
  45 daemon_run('0.0.0.0:8080', $refresh,
  46         sub ($$$) { # post_accept
  47                 my ($client, $addr, $srv) = @_;
  48                 my $fd = fileno($srv);
  49                 my $h = $httpds{$fd} ||= PublicInbox::HTTPD->new($srv, $app);
  50                 PublicInbox::HTTP->new($client, $addr, $h),
  51         });
  52
  53 1;
  54
  55 package PublicInbox::HTTPD::Async;
  56 use strict;
  57 use warnings;
  58 use base qw(Danga::Socket);
  59 use fields qw(cb);
  60
  61 sub new {
  62         my ($class, $io, $cb) = @_;
  63         my $self = fields::new($class);
  64         $io->blocking(0);
  65         $self->SUPER::new($io);
  66         $self->{cb} = $cb;
  67         $self->watch_read(1);
  68         $self;
  69 }
  70
  71 sub event_read { $_[0]->{cb}->() }
  72 sub event_hup { $_[0]->{cb}->() }
  73 sub event_err { $_[0]->{cb}->() }
  74 sub sysread { shift->{sock}->sysread(@_) }
  75
  76 1;
  77
  78 package PublicInbox::HTTPD;
  79 use strict;
  80 use warnings;
  81 use Plack::Util;
  82
  83 sub pi_httpd_async {
  84         my ($io, $cb) = @_;
  85         PublicInbox::HTTPD::Async->new($io, $cb);
  86 }
  87
  88 sub new {
  89         my ($class, $sock, $app) = @_;
  90         my $n = getsockname($sock) or die "not a socket: $sock $!\n";
  91         my ($port, $addr);
  92         if (length($n) >= 28) {
  93                 require Socket6;
  94                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
  95         } else {
  96                 ($port, $addr) = Socket::unpack_sockaddr_in($n);
  97         }
  98
  99         my %env = (
 100                 REMOTE_HOST => '',
 101                 REMOTE_PORT => 0,
 102                 SERVER_NAME => $addr,
 103                 SERVER_PORT => $port,
 104                 SCRIPT_NAME => '',
 105                 'psgi.version' => [ 1, 1 ],
 106                 'psgi.errors' => \*STDERR,
 107                 'psgi.url_scheme' => 'http',
 108                 'psgi.nonblocking' => Plack::Util::TRUE,
 109                 'psgi.streaming' => Plack::Util::TRUE,
 110                 'psgi.run_once'  => Plack::Util::FALSE,
 111                 'psgi.multithread' => Plack::Util::FALSE,
 112                 'psgi.multiprocess' => Plack::Util::TRUE,
 113                 'psgix.harakiri'=> Plack::Util::FALSE,
 114                 'psgix.input.buffered' => Plack::Util::TRUE,
 115                 'pi-httpd.async' => do {
 116                         no warnings 'once';
 117                         *pi_httpd_async
 118                 },
 119         );
 120         bless {
 121                 err => \*STDERR,
 122                 out => \*STDOUT,
 123                 app => $app,
 124                 env => \%env,
 125         }, $class;
 126 }
 127
 128 1;