public-inbox-init

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2014, all contributors (git clone git://80x24.org/public-inbox)
   3 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   4 use strict;
   5 use warnings;
   6 my $usage = "public-inbox-init NAME GIT_DIR HTTP_URL ADDRESS [ADDRESS..]";
   7 use PublicInbox::Config;
   8 use File::Temp qw/tempfile/;
   9 use File::Basename qw/dirname/;
  10 use File::Path qw/mkpath/;
  11 use File::Path::Expand qw/expand_filename/;
  12
  13 sub x { system(@_) and die join(' ', @_). " failed: $?\n" }
  14 sub usage { print STDERR "Usage: $usage\n"; exit 1 }
  15
  16 my $name = shift @ARGV or usage();
  17 my $git_dir = shift @ARGV or usage();
  18 my $http_url = shift @ARGV or usage();
  19 my (@address) = @ARGV;
  20 @address or usage();
  21
  22 my $pi_config = PublicInbox::Config->default_file;
  23 my $dir = dirname($pi_config);
  24 mkpath($dir); # will croak on fatal errors
  25 my ($fh, $filename) = tempfile('pi-init-XXXXXXXX', DIR => $dir);
  26 if (-e $pi_config) {
  27         open(my $oh, '<', $pi_config) or die "unable to read $pi_config: $!\n";
  28         local $/;
  29         my $old = <$oh>;
  30         print $fh $old or die "failed to write: $!\n";
  31         close $oh or die "failed to close $pi_config: $!\n";
  32
  33         # yes, this conflict checking is racy if multiple instances of this
  34         # script are run by the same $PI_DIR
  35         my $cfg = PublicInbox::Config->new;
  36         my $conflict;
  37         foreach my $addr (@address) {
  38                 my $found = $cfg->lookup($addr);
  39                 if ($found && ($found->{listname} ne $name)) {
  40                         print STDERR
  41                                 "`$addr' already defined for ",
  42                                 "`$found->{listname}',\n",
  43                                 "does not match intend `$name'\n";
  44                         $conflict = 1;
  45                 }
  46         }
  47
  48         exit(1) if $conflict;
  49 }
  50 close $fh or die "failed to close $filename: $!\n";
  51
  52 my $pfx = "publicinbox.$name";
  53 my @x = (qw/git config/, "--file=$filename");
  54 $git_dir = expand_filename($git_dir);
  55 x(qw(git init -q --bare), $git_dir);
  56 foreach my $addr (@address) {
  57         x(@x, "$pfx.address", $addr);
  58 }
  59 x(@x, "$pfx.url", $http_url);
  60 x(@x, "$pfx.mainrepo", $git_dir);
  61
  62 rename $filename, $pi_config or
  63         die "failed to rename `$filename' to `$pi_config': $!\n";