public-inbox-init

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   3 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   4 use strict;
   5 use warnings;
   6 my $usage = "public-inbox-init NAME GIT_DIR HTTP_URL ADDRESS [ADDRESS..]";
   7 use PublicInbox::Config;
   8 use File::Temp qw/tempfile/;
   9 use File::Basename qw/dirname/;
  10 use File::Path qw/mkpath/;
  11 use File::Path::Expand qw/expand_filename/;
  12
  13 sub x { system(@_) and die join(' ', @_). " failed: $?\n" }
  14 sub usage { print STDERR "Usage: $usage\n"; exit 1 }
  15
  16 my $name = shift @ARGV or usage();
  17 my $git_dir = shift @ARGV or usage();
  18 my $http_url = shift @ARGV or usage();
  19 my (@address) = @ARGV;
  20 @address or usage();
  21 my %seen;
  22
  23 my $pi_config = PublicInbox::Config->default_file;
  24 my $dir = dirname($pi_config);
  25 mkpath($dir); # will croak on fatal errors
  26 my ($fh, $filename) = tempfile('pi-init-XXXXXXXX', DIR => $dir);
  27 if (-e $pi_config) {
  28         open(my $oh, '<', $pi_config) or die "unable to read $pi_config: $!\n";
  29         my $old;
  30         {
  31                 local $/;
  32                 $old = <$oh>;
  33         }
  34         print $fh $old or die "failed to write: $!\n";
  35         close $oh or die "failed to close $pi_config: $!\n";
  36
  37         # yes, this conflict checking is racy if multiple instances of this
  38         # script are run by the same $PI_DIR
  39         my $cfg = PublicInbox::Config->new;
  40         my $conflict;
  41         foreach my $addr (@address) {
  42                 my $found = $cfg->lookup($addr);
  43                 if ($found) {
  44                         if ($found->{listname} ne $name) {
  45                                 print STDERR
  46                                         "`$addr' already defined for ",
  47                                         "`$found->{listname}',\n",
  48                                         "does not match intend `$name'\n";
  49                                 $conflict = 1;
  50                         } else {
  51                                 $seen{lc($addr)} = 1;
  52                         }
  53                 }
  54         }
  55
  56         exit(1) if $conflict;
  57 }
  58 close $fh or die "failed to close $filename: $!\n";
  59
  60 my $pfx = "publicinbox.$name";
  61 my @x = (qw/git config/, "--file=$filename");
  62 $git_dir = expand_filename($git_dir);
  63 x(qw(git init -q --bare), $git_dir);
  64 foreach my $addr (@address) {
  65         next if $seen{lc($addr)};
  66         x(@x, "--add", "$pfx.address", $addr);
  67 }
  68 x(@x, "$pfx.url", $http_url);
  69 x(@x, "$pfx.mainrepo", $git_dir);
  70
  71 rename $filename, $pi_config or
  72         die "failed to rename `$filename' to `$pi_config': $!\n";