public-inbox-mda

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2013-2015 all contributors <meta@public-inbox.org>
   3 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   4 #
   5 # Mail delivery agent for public-inbox, run from your MTA upon mail delivery
   6 use strict;
   7 use warnings;
   8 my $usage = 'public-inbox-mda < rfc2822_message';
   9
  10 use Email::Filter;
  11 use Email::MIME;
  12 use Email::Address;
  13 use File::Path::Expand qw/expand_filename/;
  14 use IPC::Run qw(run);
  15 use PublicInbox::MDA;
  16 use PublicInbox::Filter;
  17 use PublicInbox::Config;
  18
  19 # n.b: hopefully we can setup the emergency path without bailing due to
  20 # user error, we really want to setup the emergency destination ASAP
  21 # in case there's bugs in our code or user error.
  22 my $emergency = $ENV{PI_EMERGENCY} || '~/.public-inbox/emergency/';
  23 $emergency = expand_filename($emergency);
  24
  25 # this reads the message from stdin
  26 my $filter = Email::Filter->new(emergency => $emergency);
  27 my $config = PublicInbox::Config->new;
  28
  29 my $recipient = $ENV{ORIGINAL_RECIPIENT};
  30 defined $recipient or die "ORIGINAL_RECIPIENT not defined in ENV\n";
  31 my $dst = $config->lookup($recipient); # first check
  32 defined $dst or exit(1);
  33 my $main_repo = $dst->{mainrepo} or exit(1);
  34 my $filtered; # string dest
  35
  36 if (PublicInbox::MDA->precheck($filter, $dst->{address}) &&
  37     do_spamc($filter->simple, \$filtered)) {
  38         # update our message with SA headers (in case our filter rejects it)
  39         my $msg = Email::MIME->new(\$filtered);
  40         $filtered = undef;
  41         $filter->simple($msg);
  42
  43         my $filter_arg;
  44         my $fcfg = $dst->{filter};
  45         if (!defined $fcfg || $filter eq 'reject') {
  46                 $filter_arg = $filter;
  47         } elsif ($fcfg eq 'scrub') {
  48                 $filter_arg = undef; # the default for legacy versions
  49         } else {
  50                 warn "publicinbox.$dst->{listname}.filter=$fcfg invalid\n";
  51                 warn "must be either 'scrub' or 'reject' (the default)\n";
  52         }
  53
  54         if (PublicInbox::Filter->run($msg, $filter_arg)) {
  55                 # run spamc again on the HTML-free message
  56                 if (do_spamc($msg, \$filtered)) {
  57                         $msg = Email::MIME->new(\$filtered);
  58                         PublicInbox::MDA->set_list_headers($msg, $dst);
  59                         $filter->simple($msg);
  60
  61                         my ($name, $email, $date) =
  62                                         PublicInbox::MDA->author_info($msg);
  63
  64                         END {
  65                                 index_sync($main_repo) if ($? == 0);
  66                         };
  67
  68                         local $ENV{GIT_AUTHOR_NAME} = $name;
  69                         local $ENV{GIT_AUTHOR_EMAIL} = $email;
  70                         local $ENV{GIT_AUTHOR_DATE} = $date;
  71                         local $ENV{GIT_COMMITTER_EMAIL} = $recipient;
  72                         local $ENV{GIT_COMMITTER_NAME} = $dst->{listname};
  73
  74                         $filter->pipe(PublicInbox::MDA->cmd, $main_repo);
  75                 }
  76         }
  77 } else {
  78         # Ensure emergency spam gets spamassassin headers.
  79         # This makes it easier to prioritize obvious spam from less obvious
  80         if (defined($filtered) && $filtered ne '') {
  81                 my $drop = Email::MIME->new(\$filtered);
  82                 $filtered = undef;
  83                 $filter->simple($drop);
  84         }
  85 }
  86 exit 0; # goes to emergency
  87
  88 # we depend on "report_safe 0" in /etc/spamassassin/*.cf with --headers
  89 # not using Email::Filter->pipe here since we want the stdout of
  90 # the command even on failure (spamc will set $? on error).
  91 sub do_spamc {
  92         my ($msg, $out) = @_;
  93         eval {
  94                 my $orig = $msg->as_string;
  95                 run([qw/spamc -E --headers/], \$orig, $out);
  96         };
  97
  98         return ($@ || $? || !defined($$out) || $$out eq '') ? 0 : 1;
  99 }
 100
 101 sub index_sync {
 102         my ($git_dir) = @_;
 103
 104         # potentially user-visible, ignore errors:
 105         system('git', "--git-dir=$git_dir", 'update-server-info');
 106
 107         eval {
 108                 require PublicInbox::SearchIdx;
 109                 PublicInbox::SearchIdx->new($git_dir, 2)->index_sync;
 110         };
 111 }