public-inbox.cgi

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   3 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   4 #
   5 # We focus on the lowest common denominators here:
   6 # - targeted at text-only console browsers (lynx, w3m, etc..)
   7 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   8 # - No JavaScript, graphics or icons allowed.
   9 # - Must not rely on static content
  10 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  11
  12 use 5.008;
  13 use strict;
  14 use warnings;
  15 use CGI qw(:cgi :escapeHTML -nosticky); # PSGI/FastCGI/mod_perl compat
  16 use Encode qw(decode_utf8);
  17 use PublicInbox::Config;
  18 use URI::Escape qw(uri_unescape);
  19 use Digest::SHA qw(sha1_hex);
  20 our $LISTNAME_RE = qr!\A(?:/.*?)?/([\w\.\-]+)!;
  21 our $pi_config;
  22 BEGIN {
  23         $pi_config = PublicInbox::Config->new;
  24         # TODO: detect and reload config as needed
  25         if ($ENV{MOD_PERL}) {
  26                 CGI->compile;
  27         }
  28 }
  29
  30 my $ret = main();
  31
  32 my ($status, $headers, $body) = @$ret;
  33 set_binmode($headers);
  34 if (@ARGV && $ARGV[0] eq 'static') {
  35         print $body;
  36 } else { # CGI
  37         print "Status: $status\r\n";
  38         while (my ($k, $v) = each %$headers) {
  39                 print "$k: $v\r\n";
  40         }
  41         print "\r\n", $body;
  42 }
  43
  44 # TODO: plack support
  45
  46 # private functions below
  47
  48 sub main {
  49         # some servers (Ruby webrick) include scheme://host[:port] here,
  50         # which confuses CGI.pm when generating self_url.
  51         # RFC 3875 does not mention REQUEST_URI at all,
  52         # so nuke it since CGI.pm functions without it.
  53         delete $ENV{REQUEST_URI};
  54
  55         my $cgi = CGI->new;
  56         my %ctx;
  57         if ($cgi->request_method !~ /\AGET|HEAD\z/) {
  58                 return r("405 Method Not Allowed");
  59         }
  60         my $path_info = decode_utf8($cgi->path_info);
  61
  62         # top-level indices and feeds
  63         if ($path_info eq "/") {
  64                 r404();
  65         } elsif ($path_info =~ m!$LISTNAME_RE/(?:index\.html)?\z!o) {
  66                 invalid_list(\%ctx, $1) || get_index(\%ctx, $cgi, 1);
  67         } elsif ($path_info =~ m!$LISTNAME_RE/index\.atom\.xml\z!o) {
  68                 invalid_list(\%ctx, $1) || get_atom(\%ctx, $cgi, 1);
  69         } elsif ($path_info =~ m!$LISTNAME_RE/all\.atom\.xml\z!o) {
  70                 invalid_list(\%ctx, $1) || get_atom(\%ctx, $cgi, 0);
  71
  72         # single-message pages
  73         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.txt\z!o) {
  74                 invalid_list_mid(\%ctx, $1, $2) || get_mid_txt(\%ctx, $cgi);
  75         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.html\z!o) {
  76                 invalid_list_mid(\%ctx, $1, $2) || get_mid_html(\%ctx, $cgi);
  77         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\z!o) {
  78                 redirect_mid_html($cgi, $1, $2);
  79
  80         # full-message page
  81         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\.html\z!o) {
  82                 invalid_list_mid(\%ctx, $1, $2) || get_full_html(\%ctx, $cgi);
  83         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\z!o) {
  84                 redirect_mid_html($cgi, $1, $2);
  85
  86         } elsif ($path_info =~ m!$LISTNAME_RE\z!o) {
  87                 invalid_list(\%ctx, $1) || redirect_list_index(\%ctx, $cgi);
  88         } else {
  89                 r404();
  90         }
  91 }
  92
  93 sub r404 { r("404 Not Found") }
  94
  95 # simple response for errors
  96 sub r { [ $_[0], { 'Content-Type' => 'text/plain' }, '' ] }
  97
  98 # returns undef if valid, array ref response if invalid
  99 sub invalid_list {
 100         my ($ctx, $listname) = @_;
 101         my $git_dir = $pi_config->get($listname, "mainrepo");
 102         if (defined $git_dir) {
 103                 $ctx->{git_dir} = $git_dir;
 104                 $ctx->{listname} = $listname;
 105                 return undef;
 106         }
 107         r404();
 108 }
 109
 110 # returns undef if valid, array ref response if invalid
 111 sub invalid_list_mid {
 112         my ($ctx, $listname, $mid) = @_;
 113         my $ret = invalid_list($ctx, $listname, $mid) and return $ret;
 114         $ctx->{mid} = uri_unescape($mid);
 115         undef;
 116 }
 117
 118 # /$LISTNAME/index.atom.xml                     -> Atom feed
 119 # /$LISTNAME/all.atom.xml                       -> Atom feed, includes replies
 120 sub get_atom {
 121         my ($ctx, $cgi, $top) = @_;
 122         require PublicInbox::Feed;
 123         [ '200 OK', { 'Content-Type' => 'application/xml' },
 124           PublicInbox::Feed->generate({
 125                         git_dir => $ctx->{git_dir},
 126                         listname => $ctx->{listname},
 127                         pi_config => $pi_config,
 128                         cgi => $cgi,
 129                         top => $top,
 130                 })
 131         ];
 132 }
 133
 134 # /$LISTNAME/?before=$GIT_COMMIT                 -> HTML only
 135 sub get_index {
 136         my ($ctx, $cgi, $top) = @_;
 137         require PublicInbox::Feed;
 138         [ '200 OK', { 'Content-Type' => 'text/html' },
 139           PublicInbox::Feed->generate_html_index({
 140                         git_dir => $ctx->{git_dir},
 141                         listname => $ctx->{listname},
 142                         pi_config => $pi_config,
 143                         cgi => $cgi,
 144                         top => $top,
 145                 })
 146         ];
 147 }
 148
 149 # just returns a string ref for the blob in the current ctx
 150 sub mid2blob {
 151         my ($ctx) = @_;
 152         local $ENV{GIT_DIR} = $ctx->{git_dir};
 153         my $hex = sha1_hex($ctx->{mid});
 154         $hex =~ /\A([a-f0-9]{2})([a-f0-9]{38})\z/i or
 155                         die "BUG: not a SHA-1 hex: $hex";
 156         my $blob = `git cat-file blob HEAD:$1/$2 2>/dev/null`;
 157         $? == 0 ? \$blob : undef;
 158 }
 159
 160 # /$LISTNAME/m/$MESSAGE_ID.txt                    -> raw original
 161 sub get_mid_txt {
 162         my ($ctx, $cgi) = @_;
 163         my $x = mid2blob($ctx);
 164         $x ? [ "200 OK", {'Content-Type' => 'text/plain'}, $$x ] : r404();
 165 }
 166
 167 # /$LISTNAME/m/$MESSAGE_ID.html                   -> HTML content (short quotes)
 168 sub get_mid_html {
 169         my ($ctx, $cgi) = @_;
 170         my $x = mid2blob($ctx);
 171         return r404() unless $x;
 172
 173         my $pfx = $cgi->self_url;
 174         $pfx =~ s!/m/.+\z!/!; # FIXME: this is not robust
 175
 176         require PublicInbox::View;
 177         require Email::MIME;
 178         [ "200 OK", {'Content-Type' => 'text/html'},
 179                 PublicInbox::View->as_html(Email::MIME->new($$x), $pfx)];
 180 }
 181
 182 # /$LISTNAME/f/$MESSAGE_ID.html                   -> HTML content (fullquotes)
 183 sub get_full_html {
 184         my ($ctx, $cgi) = @_;
 185         my $x = mid2blob($ctx);
 186         return r404() unless $x;
 187         require PublicInbox::View;
 188         require Email::MIME;
 189         [ "200 OK", {'Content-Type' => 'text/html'},
 190                 PublicInbox::View->as_html(Email::MIME->new($$x))];
 191 }
 192
 193 sub redirect_list_index {
 194         my ($ctx, $cgi) = @_;
 195         do_redirect($cgi->self_url . "/");
 196 }
 197
 198 sub do_redirect {
 199         my ($url) = @_;
 200         [ '301 Moved Permanently',
 201           { Location => $url, 'Content-Type' => 'text/plain' },
 202           "Redirecting to $url\n"
 203         ]
 204 }
 205
 206 # only used for CGI and static file generation modes
 207 sub set_binmode {
 208         my ($headers) = @_;
 209         if ($headers->{'Content-Type'} eq 'text/plain') {
 210                 # no way to validate raw messages, mixed encoding is possible.
 211                 binmode STDOUT;
 212         } else { # strict encoding for HTML and XML
 213                 binmode STDOUT, ':encoding(UTF-8)';
 214         }
 215 }