script/lei

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
   7 use PublicInbox::CmdIPC4;
   8 my $narg = 4;
   9 my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
  10 my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
  11         require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
  12         $narg = 4;
  13         $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  14         PublicInbox::Spawn->can('send_cmd4');
  15 };
  16
  17 sub exec_cmd {
  18         my ($fds, $argc, @argv) = @_;
  19         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
  20         my @m = (*STDIN{IO}, '<&=',  *STDOUT{IO}, '>&=',
  21                 *STDERR{IO}, '>&=');
  22         for my $fd (@$fds) {
  23                 my ($old_io, $mode) = splice(@m, 0, 2);
  24                 open($old_io, $mode, $fd) or die "open $mode$fd: $!";
  25         }
  26         %ENV = (%ENV, %env);
  27         exec(@argv);
  28         die "exec: @argv: $!";
  29 }
  30
  31 my ($sock, $pwd);
  32 if ($send_cmd && eval {
  33         my $path = do {
  34                 my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
  35                 if ($runtime_dir eq '/lei') {
  36                         require File::Spec;
  37                         $runtime_dir = File::Spec->tmpdir."/lei-$<";
  38                 }
  39                 unless (-d $runtime_dir) {
  40                         require File::Path;
  41                         File::Path::mkpath($runtime_dir, 0, 0700);
  42                 }
  43                 "$runtime_dir/$narg.sock";
  44         };
  45         my $addr = pack_sockaddr_un($path);
  46         socket($sock, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
  47         unless (connect($sock, $addr)) { # start the daemon if not started
  48                 local $ENV{PERL5LIB} = join(':', @INC);
  49                 open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
  50                         -E PublicInbox::LEI::lazy_start(@ARGV)],
  51                         $path, $! + 0, $narg) or die "popen: $!";
  52                 while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
  53                 close($daemon) or warn <<"";
  54 lei-daemon could not start, exited with \$?=$?
  55
  56                 # try connecting again anyways, unlink+bind may be racy
  57                 connect($sock, $addr) or die <<"";
  58 connect($path): $! (after attempted daemon start)
  59 Falling back to (slow) one-shot mode
  60
  61         }
  62         require Cwd;
  63         $pwd = $ENV{PWD} // '';
  64         my $cwd = Cwd::fastcwd() // die "fastcwd(PWD=$pwd): $!";
  65         if ($pwd ne $cwd) { # prefer ENV{PWD} if it's a symlink to real cwd
  66                 my @st_cwd = stat($cwd) or die "stat(cwd=$cwd): $!";
  67                 my @st_pwd = stat($pwd); # PWD invalid, use cwd
  68                 # make sure st_dev/st_ino match for {PWD} to be valid
  69                 $pwd = $cwd if (!@st_pwd || $st_pwd[1] != $st_cwd[1] ||
  70                                         $st_pwd[0] != $st_cwd[0]);
  71         } else {
  72                 $pwd = $cwd;
  73         }
  74         1;
  75 }) { # (Socket::MsgHdr|Inline::C), $sock, $pwd are all available:
  76         local $ENV{PWD} = $pwd;
  77         my $buf = join("\0", scalar(@ARGV), @ARGV);
  78         while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
  79         $buf .= "\0\0";
  80         select $sock;
  81         $| = 1; # unbuffer selected $sock
  82         $send_cmd->($sock, [ 0, 1, 2 ], $buf, 0);
  83         while (my (@fds) = $recv_cmd->($sock, $buf, 4096 * 33)) {
  84                 if ($buf =~ /\Aexit=([0-9]+)\n\z/) {
  85                         exit($1);
  86                 } elsif ($buf =~ /\Aexec (.+)\n\z/) {
  87                         exec_cmd(\@fds, split(/\0/, $1));
  88                 } else {
  89                         die $buf;
  90                 }
  91         }
  92 } else { # for systems lacking Socket::MsgHdr or Inline::C
  93         warn $@ if $@;
  94         require PublicInbox::LEI;
  95         PublicInbox::LEI::oneshot(__PACKAGE__);
  96 }