script/lei

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   7 use PublicInbox::CmdIPC4;
   8 my $narg = 5;
   9 my $sock;
  10 my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
  11 my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
  12         require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
  13         $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  14         PublicInbox::Spawn->can('send_cmd4');
  15 };
  16
  17 my %pids;
  18 my $sigchld = sub {
  19         my $flags = scalar(@_) ? POSIX::WNOHANG() : 0;
  20         for my $pid (keys %pids) {
  21                 delete($pids{$pid}) if waitpid($pid, $flags) == $pid;
  22         }
  23 };
  24 my @parent;
  25 my $exec_cmd = sub {
  26         my ($fds, $argc, @argv) = @_;
  27         my $parent = $$;
  28         require POSIX;
  29         my @old = (*STDIN{IO}, *STDOUT{IO}, *STDERR{IO});
  30         my @rdr;
  31         for my $fd (@$fds) {
  32                 open(my $newfh, '+<&=', $fd) or die "open +<&=$fd: $!";
  33                 push @rdr, shift(@old), $newfh;
  34         }
  35         my $do_exec = sub {
  36                 while (my ($io, $newfh) = splice(@rdr, 0, 2)) {
  37                         open $io, '+<&', $newfh or die "open +<&=: $!";
  38                 }
  39                 my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
  40                 @ENV{keys %env} = values %env;
  41                 exec(@argv);
  42                 warn "exec: @argv: $!\n";
  43                 POSIX::_exit(1);
  44         };
  45         $SIG{CHLD} = $sigchld;
  46         my $pid = fork // die "fork: $!";
  47         if ($pid == 0) {
  48                 $do_exec->() if $fds->[1]; # git-credential, pager
  49
  50                 # parent backgrounds on MUA
  51                 POSIX::setsid() > 0 or die "setsid: $!";
  52                 @parent = ($parent);
  53                 return; # continue $recv_cmd in background
  54         }
  55         if ($fds->[1]) {
  56                 $pids{$pid} = undef;
  57         } else {
  58                 $do_exec->(); # MUA reuses stdout
  59         }
  60 };
  61
  62 if ($send_cmd && eval {
  63         my $path = do {
  64                 my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
  65                 die \0 if $runtime_dir eq '/dev/null/lei'; # oneshot forced
  66                 if ($runtime_dir eq '/lei') {
  67                         require File::Spec;
  68                         $runtime_dir = File::Spec->tmpdir."/lei-$<";
  69                 }
  70                 unless (-d $runtime_dir) {
  71                         require File::Path;
  72                         File::Path::mkpath($runtime_dir, 0, 0700);
  73                 }
  74                 "$runtime_dir/$narg.seq.sock";
  75         };
  76         my $addr = pack_sockaddr_un($path);
  77         socket($sock, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
  78         unless (connect($sock, $addr)) { # start the daemon if not started
  79                 local $ENV{PERL5LIB} = join(':', @INC);
  80                 open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
  81                         -E PublicInbox::LEI::lazy_start(@ARGV)],
  82                         $path, $! + 0, $narg) or die "popen: $!";
  83                 while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
  84                 close($daemon) or warn <<"";
  85 lei-daemon could not start, exited with \$?=$?
  86
  87                 # try connecting again anyways, unlink+bind may be racy
  88                 connect($sock, $addr) or die <<"";
  89 connect($path): $! (after attempted daemon start)
  90 Falling back to (slow) one-shot mode
  91
  92         }
  93         # (Socket::MsgHdr|Inline::C), $sock are all available:
  94         open my $dh, '<', '.' or die "open(.) $!";
  95         my $buf = join("\0", scalar(@ARGV), @ARGV);
  96         while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
  97         $buf .= "\0\0";
  98         my $n = $send_cmd->($sock, [0, 1, 2, fileno($dh)], $buf, MSG_EOR);
  99         if (!$n) {
 100                 die "sendmsg: $! (check RLIMIT_NOFILE)\n" if $!{ETOOMANYREFS};
 101                 die "sendmsg: $!\n";
 102         }
 103         1;
 104 }) { # connected and request sent to lei-daemon, wait for responses or EOF
 105         my $x_it_code = 0;
 106         while (1) {
 107                 my (@fds) = $recv_cmd->($sock, my $buf, 4096 * 33);
 108                 if (scalar(@fds) == 1 && !defined($fds[0])) {
 109                         next if $!{EINTR};
 110                         last if $!{ECONNRESET};
 111                         die "recvmsg: $!";
 112                 }
 113                 last if $buf eq '';
 114                 if ($buf =~ /\Aexec (.+)\z/) {
 115                         $exec_cmd->(\@fds, split(/\0/, $1));
 116                 } elsif ($buf eq '-WINCH') {
 117                         kill($buf, @parent); # for MUA
 118                 } elsif ($buf =~ /\Ax_it ([0-9]+)\z/) {
 119                         $x_it_code = $1 + 0;
 120                         last;
 121                 } elsif ($buf =~ /\Achild_error ([0-9]+)\z/) {
 122                         $x_it_code = $1 + 0;
 123                 } else {
 124                         $sigchld->();
 125                         die $buf;
 126                 }
 127         }
 128         $sigchld->();
 129         if (my $sig = ($x_it_code & 127)) {
 130                 kill $sig, $$;
 131                 sleep(1) while 1;
 132         }
 133         exit($x_it_code >> 8);
 134 } else { # for systems lacking Socket::MsgHdr or Inline::C
 135         warn $@ if $@ && !ref($@);
 136         require PublicInbox::LEI;
 137         PublicInbox::LEI::oneshot(__PACKAGE__);
 138 }