script/lei

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   7 use PublicInbox::CmdIPC4;
   8 my $narg = 5;
   9 my $sock;
  10 my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
  11 my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
  12         require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
  13         $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  14         PublicInbox::Spawn->can('send_cmd4');
  15 };
  16
  17 my %pids;
  18 my $sigchld = sub {
  19         my $flags = scalar(@_) ? POSIX::WNOHANG() : 0;
  20         for my $pid (keys %pids) {
  21                 delete($pids{$pid}) if waitpid($pid, $flags) == $pid;
  22         }
  23 };
  24 my @parent;
  25 my $exec_cmd = sub {
  26         my ($fds, $argc, @argv) = @_;
  27         my $parent = $$;
  28         require POSIX;
  29         my @old = (*STDIN{IO}, *STDOUT{IO}, *STDERR{IO});
  30         my @rdr;
  31         for my $fd (@$fds) {
  32                 open(my $newfh, '+<&=', $fd) or die "open +<&=$fd: $!";
  33                 push @rdr, shift(@old), $newfh;
  34         }
  35         my $do_exec = sub {
  36                 my @non_std; # ex. $op_p from lei_edit_search
  37                 while (my ($io, $newfh) = splice(@rdr, 0, 2)) {
  38                         my $old_io = !!$io;
  39                         open $io, '+<&', $newfh or die "open +<&=: $!";
  40                         push @non_std, $io unless $old_io;
  41                 }
  42                 if (@non_std) {
  43                         require Fcntl;
  44                         fcntl($_, Fcntl::F_SETFD(), 0) for @non_std;
  45                 }
  46                 my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
  47                 @ENV{keys %env} = values %env;
  48                 exec(@argv);
  49                 warn "exec: @argv: $!\n";
  50                 POSIX::_exit(1);
  51         };
  52         $SIG{CHLD} = $sigchld;
  53         my $pid = fork // die "fork: $!";
  54         if ($pid == 0) {
  55                 $do_exec->() if $fds->[1]; # git-credential, pager
  56
  57                 # parent backgrounds on MUA
  58                 POSIX::setsid() > 0 or die "setsid: $!";
  59                 @parent = ($parent);
  60                 return; # continue $recv_cmd in background
  61         }
  62         if ($fds->[1]) {
  63                 $pids{$pid} = undef;
  64         } else {
  65                 $do_exec->(); # MUA reuses stdout
  66         }
  67 };
  68
  69 if ($send_cmd && eval {
  70         my $path = do {
  71                 my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
  72                 die \0 if $runtime_dir eq '/dev/null/lei'; # oneshot forced
  73                 if ($runtime_dir eq '/lei') {
  74                         require File::Spec;
  75                         $runtime_dir = File::Spec->tmpdir."/lei-$<";
  76                 }
  77                 unless (-d $runtime_dir) {
  78                         require File::Path;
  79                         File::Path::mkpath($runtime_dir, 0, 0700);
  80                 }
  81                 "$runtime_dir/$narg.seq.sock";
  82         };
  83         my $addr = pack_sockaddr_un($path);
  84         socket($sock, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
  85         unless (connect($sock, $addr)) { # start the daemon if not started
  86                 local $ENV{PERL5LIB} = join(':', @INC);
  87                 open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
  88                         -E PublicInbox::LEI::lazy_start(@ARGV)],
  89                         $path, $! + 0, $narg) or die "popen: $!";
  90                 while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
  91                 close($daemon) or warn <<"";
  92 lei-daemon could not start, exited with \$?=$?
  93
  94                 # try connecting again anyways, unlink+bind may be racy
  95                 connect($sock, $addr) or die <<"";
  96 connect($path): $! (after attempted daemon start)
  97 Falling back to (slow) one-shot mode
  98
  99         }
 100         # (Socket::MsgHdr|Inline::C), $sock are all available:
 101         open my $dh, '<', '.' or die "open(.) $!";
 102         my $buf = join("\0", scalar(@ARGV), @ARGV);
 103         while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
 104         $buf .= "\0\0";
 105         my $n = $send_cmd->($sock, [0, 1, 2, fileno($dh)], $buf, MSG_EOR);
 106         if (!$n) {
 107                 die "sendmsg: $! (check RLIMIT_NOFILE)\n" if $!{ETOOMANYREFS};
 108                 die "sendmsg: $!\n";
 109         }
 110         1;
 111 }) { # connected and request sent to lei-daemon, wait for responses or EOF
 112         my $x_it_code = 0;
 113         while (1) {
 114                 my (@fds) = $recv_cmd->($sock, my $buf, 4096 * 33);
 115                 if (scalar(@fds) == 1 && !defined($fds[0])) {
 116                         next if $!{EINTR};
 117                         last if $!{ECONNRESET};
 118                         die "recvmsg: $!";
 119                 }
 120                 last if $buf eq '';
 121                 if ($buf =~ /\Aexec (.+)\z/) {
 122                         $exec_cmd->(\@fds, split(/\0/, $1));
 123                 } elsif ($buf eq '-WINCH') {
 124                         kill($buf, @parent); # for MUA
 125                 } elsif ($buf =~ /\Ax_it ([0-9]+)\z/) {
 126                         $x_it_code ||= $1 + 0;
 127                         last;
 128                 } elsif ($buf =~ /\Achild_error ([0-9]+)\z/) {
 129                         $x_it_code ||= $1 + 0;
 130                 } else {
 131                         $sigchld->();
 132                         die $buf;
 133                 }
 134         }
 135         $sigchld->();
 136         if (my $sig = ($x_it_code & 127)) {
 137                 kill $sig, $$;
 138                 sleep(1) while 1;
 139         }
 140         exit($x_it_code >> 8);
 141 } else { # for systems lacking Socket::MsgHdr or Inline::C
 142         warn $@ if $@ && !ref($@);
 143         require PublicInbox::LEI;
 144         PublicInbox::LEI::oneshot(__PACKAGE__);
 145 }