script/lei

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
   7 use PublicInbox::CmdIPC4;
   8 my $narg = 4;
   9 my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
  10 my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
  11         require PublicInbox::CmdIPC1; # 2nd choice
  12         $narg = 1;
  13         $recv_cmd = PublicInbox::CmdIPC1->can('recv_cmd1');
  14         PublicInbox::CmdIPC1->can('send_cmd1');
  15 } // do {
  16         require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
  17         $narg = 4;
  18         $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  19         PublicInbox::Spawn->can('send_cmd4');
  20 };
  21
  22 sub exec_cmd {
  23         my ($fds, $argc, @argv) = @_;
  24         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
  25         my @m = (*STDIN{IO}, '<&=',  *STDOUT{IO}, '>&=',
  26                 *STDERR{IO}, '>&=');
  27         for my $fd (@$fds) {
  28                 my ($old_io, $mode) = splice(@m, 0, 2);
  29                 open($old_io, $mode, $fd) or die "open $mode$fd: $!";
  30         }
  31         %ENV = (%ENV, %env);
  32         exec(@argv);
  33         die "exec: @argv: $!";
  34 }
  35
  36 my ($sock, $pwd);
  37 if ($send_cmd && eval {
  38         my $path = do {
  39                 my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
  40                 if ($runtime_dir eq '/lei') {
  41                         require File::Spec;
  42                         $runtime_dir = File::Spec->tmpdir."/lei-$<";
  43                 }
  44                 unless (-d $runtime_dir) {
  45                         require File::Path;
  46                         File::Path::mkpath($runtime_dir, 0, 0700);
  47                 }
  48                 "$runtime_dir/$narg.sock";
  49         };
  50         my $addr = pack_sockaddr_un($path);
  51         socket($sock, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
  52         unless (connect($sock, $addr)) { # start the daemon if not started
  53                 local $ENV{PERL5LIB} = join(':', @INC);
  54                 open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
  55                         -E PublicInbox::LEI::lazy_start(@ARGV)],
  56                         $path, $! + 0, $narg) or die "popen: $!";
  57                 while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
  58                 close($daemon) or warn <<"";
  59 lei-daemon could not start, exited with \$?=$?
  60
  61                 # try connecting again anyways, unlink+bind may be racy
  62                 connect($sock, $addr) or die <<"";
  63 connect($path): $! (after attempted daemon start)
  64 Falling back to (slow) one-shot mode
  65
  66         }
  67         require Cwd;
  68         $pwd = $ENV{PWD} // '';
  69         my $cwd = Cwd::fastcwd() // die "fastcwd(PWD=$pwd): $!";
  70         if ($pwd ne $cwd) { # prefer ENV{PWD} if it's a symlink to real cwd
  71                 my @st_cwd = stat($cwd) or die "stat(cwd=$cwd): $!";
  72                 my @st_pwd = stat($pwd); # PWD invalid, use cwd
  73                 # make sure st_dev/st_ino match for {PWD} to be valid
  74                 $pwd = $cwd if (!@st_pwd || $st_pwd[1] != $st_cwd[1] ||
  75                                         $st_pwd[0] != $st_cwd[0]);
  76         } else {
  77                 $pwd = $cwd;
  78         }
  79         1;
  80 }) { # (Socket::MsgHdr|IO::FDPass|Inline::C), $sock, $pwd are all available:
  81         local $ENV{PWD} = $pwd;
  82         my $buf = join("\0", scalar(@ARGV), @ARGV);
  83         while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
  84         $buf .= "\0\0";
  85         select $sock;
  86         $| = 1; # unbuffer selected $sock
  87         $send_cmd->($sock, [ 0, 1, 2 ], $buf, 0);
  88         while (my (@fds) = $recv_cmd->($sock, $buf, 4096 * 33)) {
  89                 if ($buf =~ /\Aexit=([0-9]+)\n\z/) {
  90                         exit($1);
  91                 } elsif ($buf =~ /\Aexec (.+)\n\z/) {
  92                         exec_cmd(\@fds, split(/\0/, $1));
  93                 } else {
  94                         die $buf;
  95                 }
  96         }
  97 } else { # for systems lacking Socket::MsgHdr, IO::FDPass or Inline::C
  98         warn $@ if $@;
  99         require PublicInbox::LEI;
 100         PublicInbox::LEI::oneshot(__PACKAGE__);
 101 }