script/lei

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   7 use Errno qw(EINTR ECONNRESET);
   8 use PublicInbox::CmdIPC4;
   9 my $narg = 5;
  10 my ($sock, $pwd);
  11 my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
  12 my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
  13         require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
  14         $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  15         PublicInbox::Spawn->can('send_cmd4');
  16 };
  17
  18 sub sigchld {
  19         my ($sig) = @_;
  20         my $flags = $sig ? POSIX::WNOHANG() : 0;
  21         while (waitpid(-1, $flags) > 0) {}
  22 }
  23
  24 sub exec_cmd {
  25         my ($fds, $argc, @argv) = @_;
  26         my @m = (*STDIN{IO}, '<&=',  *STDOUT{IO}, '>&=', *STDERR{IO}, '>&=');
  27         my @rdr;
  28         for my $fd (@$fds) {
  29                 my ($old_io, $mode) = splice(@m, 0, 2);
  30                 open(my $tmpfh, $mode, $fd) or die "open $mode$fd: $!";
  31                 push @rdr, $old_io, $mode, $tmpfh;
  32         }
  33         require POSIX; # WNOHANG
  34         $SIG{CHLD} = \&sigchld;
  35         my $pid = fork // die "fork: $!";
  36         if ($pid == 0) {
  37                 my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
  38                 while (my ($old_io, $mode, $tmpfh) = splice(@rdr, 0, 3)) {
  39                         open $old_io, $mode, $tmpfh or die "open $mode: $!";
  40                 }
  41                 %ENV = (%ENV, %env);
  42                 exec(@argv);
  43                 die "exec: @argv: $!";
  44         }
  45 }
  46
  47 if ($send_cmd && eval {
  48         my $path = do {
  49                 my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
  50                 if ($runtime_dir eq '/lei') {
  51                         require File::Spec;
  52                         $runtime_dir = File::Spec->tmpdir."/lei-$<";
  53                 }
  54                 unless (-d $runtime_dir) {
  55                         require File::Path;
  56                         File::Path::mkpath($runtime_dir, 0, 0700);
  57                 }
  58                 "$runtime_dir/$narg.seq.sock";
  59         };
  60         my $addr = pack_sockaddr_un($path);
  61         socket($sock, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
  62         unless (connect($sock, $addr)) { # start the daemon if not started
  63                 local $ENV{PERL5LIB} = join(':', @INC);
  64                 open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
  65                         -E PublicInbox::LEI::lazy_start(@ARGV)],
  66                         $path, $! + 0, $narg) or die "popen: $!";
  67                 while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
  68                 close($daemon) or warn <<"";
  69 lei-daemon could not start, exited with \$?=$?
  70
  71                 # try connecting again anyways, unlink+bind may be racy
  72                 connect($sock, $addr) or die <<"";
  73 connect($path): $! (after attempted daemon start)
  74 Falling back to (slow) one-shot mode
  75
  76         }
  77         1;
  78 }) { # (Socket::MsgHdr|Inline::C), $sock, $pwd are all available:
  79         open my $dh, '<', '.' or die "open(.) $!";
  80         my $buf = join("\0", scalar(@ARGV), @ARGV);
  81         while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
  82         $buf .= "\0\0";
  83         $send_cmd->($sock, [ 0, 1, 2, fileno($dh) ], $buf, MSG_EOR);
  84         my $x_it_code = 0;
  85         while (1) {
  86                 my (@fds) = $recv_cmd->($sock, $buf, 4096 * 33);
  87                 if (scalar(@fds) == 1 && !defined($fds[0])) {
  88                         last if $! == ECONNRESET;
  89                         next if $! == EINTR;
  90                         die "recvmsg: $!";
  91                 }
  92                 last if $buf eq '';
  93                 if ($buf =~ /\Ax_it ([0-9]+)\z/) {
  94                         $x_it_code = $1 + 0;
  95                         last;
  96                 } elsif ($buf =~ /\Achild_error ([0-9]+)\z/) {
  97                         $x_it_code = $1 + 0;
  98                 } elsif ($buf =~ /\Aexec (.+)\z/) {
  99                         exec_cmd(\@fds, split(/\0/, $1));
 100                 } else {
 101                         sigchld();
 102                         die $buf;
 103                 }
 104         }
 105         sigchld();
 106         if (my $sig = ($x_it_code & 127)) {
 107                 kill $sig, $$;
 108                 sleep;
 109         }
 110         exit($x_it_code >> 8);
 111 } else { # for systems lacking Socket::MsgHdr or Inline::C
 112         warn $@ if $@;
 113         require PublicInbox::LEI;
 114         PublicInbox::LEI::oneshot(__PACKAGE__);
 115 }