script/lei

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
   7 use PublicInbox::CmdIPC4;
   8 my $narg = 5;
   9 my $sock;
  10 my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
  11 my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
  12         require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
  13         $recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
  14         PublicInbox::Spawn->can('send_cmd4');
  15 };
  16
  17 my @orig_pid;
  18 my $exec_cmd = sub {
  19         my ($fds, $argc, @argv) = @_;
  20         die "BUG: already exec-ed\n" if @orig_pid;
  21         @orig_pid = ($$);
  22         require POSIX; # WNOHANG
  23         my @old = (*STDIN{IO}, *STDOUT{IO}, *STDERR{IO});
  24         my @rdr;
  25         for my $fd (@$fds) {
  26                 open(my $tmpfh, '+<&=', $fd) or die "open +<&=$fd: $!";
  27                 push @rdr, shift(@old), $tmpfh;
  28         }
  29         my $pid = fork // die "fork: $!";
  30         if ($pid == 0) {
  31                 POSIX::setsid() > 0 or die "setsid: $!";
  32                 return; # continue $recv_cmd in background
  33         }
  34         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
  35         while (my ($old_io, $tmpfh) = splice(@rdr, 0, 2)) {
  36                 open $old_io, '+<&', $tmpfh or die "open +<&=: $!";
  37         }
  38         @ENV{keys %env} = values %env;
  39         exec(@argv);
  40         warn "exec: @argv: $!\n";
  41         POSIX::_exit(1);
  42 };
  43
  44 if ($send_cmd && eval {
  45         my $path = do {
  46                 my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
  47                 if ($runtime_dir eq '/lei') {
  48                         require File::Spec;
  49                         $runtime_dir = File::Spec->tmpdir."/lei-$<";
  50                 }
  51                 unless (-d $runtime_dir) {
  52                         require File::Path;
  53                         File::Path::mkpath($runtime_dir, 0, 0700);
  54                 }
  55                 "$runtime_dir/$narg.seq.sock";
  56         };
  57         my $addr = pack_sockaddr_un($path);
  58         socket($sock, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
  59         unless (connect($sock, $addr)) { # start the daemon if not started
  60                 local $ENV{PERL5LIB} = join(':', @INC);
  61                 open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
  62                         -E PublicInbox::LEI::lazy_start(@ARGV)],
  63                         $path, $! + 0, $narg) or die "popen: $!";
  64                 while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
  65                 close($daemon) or warn <<"";
  66 lei-daemon could not start, exited with \$?=$?
  67
  68                 # try connecting again anyways, unlink+bind may be racy
  69                 connect($sock, $addr) or die <<"";
  70 connect($path): $! (after attempted daemon start)
  71 Falling back to (slow) one-shot mode
  72
  73         }
  74         # (Socket::MsgHdr|Inline::C), $sock are all available:
  75         open my $dh, '<', '.' or die "open(.) $!";
  76         my $buf = join("\0", scalar(@ARGV), @ARGV);
  77         while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
  78         $buf .= "\0\0";
  79         my $n = $send_cmd->($sock, [0, 1, 2, fileno($dh)], $buf, MSG_EOR);
  80         if (!$n) {
  81                 die "sendmsg: $! (check RLIMIT_NOFILE)\n" if $!{ETOOMANYREFS};
  82                 die "sendmsg: $!\n";
  83         }
  84         1;
  85 }) { # connected and request sent to lei-daemon, wait for responses or EOF
  86         my $x_it_code = 0;
  87         while (1) {
  88                 my (@fds) = $recv_cmd->($sock, my $buf, 4096 * 33);
  89                 if (scalar(@fds) == 1 && !defined($fds[0])) {
  90                         next if $!{EINTR};
  91                         last if $!{ECONNRESET};
  92                         die "recvmsg: $!";
  93                 }
  94                 last if $buf eq '';
  95                 if ($buf =~ /\Aexec (.+)\z/) {
  96                         $exec_cmd->(\@fds, split(/\0/, $1));
  97                 } elsif ($buf eq '-WINCH') {
  98                         kill($buf, @orig_pid); # for MUA
  99                 } elsif ($buf =~ /\Ax_it ([0-9]+)\z/) {
 100                         $x_it_code = $1 + 0;
 101                         last;
 102                 } elsif ($buf =~ /\Achild_error ([0-9]+)\z/) {
 103                         $x_it_code = $1 + 0;
 104                 } else {
 105                         die $buf;
 106                 }
 107         }
 108         if (my $sig = ($x_it_code & 127)) {
 109                 kill $sig, $$;
 110                 sleep(1) while 1;
 111         }
 112         exit($x_it_code >> 8);
 113 } else { # for systems lacking Socket::MsgHdr or Inline::C
 114         warn $@ if $@;
 115         require PublicInbox::LEI;
 116         PublicInbox::LEI::oneshot(__PACKAGE__);
 117 }