script/public-inbox-clone

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 # Wrapper to git clone remote public-inboxes
   5 use v5.12;
   6 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
   7 my $opt = {};
   8 my $help = <<EOF; # the following should fit w/o scrolling in 80x24 term:
   9 usage: public-inbox-clone INBOX_URL [DESTINATION]
  10
  11   clone remote public-inboxes
  12
  13 options:
  14
  15   --epoch=RANGE       range of v2 epochs to clone (e.g `2..5', `~0', `~1..')
  16   --objstore [DIR]    share storage for coderepos
  17   --torsocks VAL      whether or not to wrap git and curl commands with
  18                       torsocks (default: `auto')
  19                       Must be one of: `auto', `no' or `yes'
  20   --dry-run | -n      show what would be cloned without cloning
  21   --verbose | -v      increase verbosity (may be repeated)
  22     --quiet | -q      increase verbosity (may be repeated)
  23     -C DIR            chdir to specified directory
  24 EOF
  25 GetOptions($opt, qw(help|h quiet|q verbose|v+ C=s@ c=s@ include|I=s@ exclude=s@
  26         inbox-config=s inbox-version=i objstore:s
  27         dry-run|n jobs|j=i no-torsocks torsocks=s epoch=s)) or die $help;
  28 if ($opt->{help}) { print $help; exit };
  29 require PublicInbox::Admin; # loads Config
  30 PublicInbox::Admin::do_chdir(delete $opt->{C});
  31 PublicInbox::Admin::setup_signals();
  32 $SIG{PIPE} = 'IGNORE';
  33
  34 my ($url, $dst, $extra) = @ARGV;
  35 die $help if !defined($url) || defined($extra);
  36 defined($dst) or ($dst) = ($url =~ m!/([^/]+)/?\z!);
  37 index($dst, "\n") >= 0 and die "`\\n' not allowed in `$dst'";
  38
  39 # n.b. this is still a truckload of code...
  40 require PublicInbox::LEI;
  41 require PublicInbox::LeiExternal;
  42 require PublicInbox::LeiMirror;
  43
  44 $url = PublicInbox::LeiExternal::ext_canonicalize($url);
  45 my $lei = bless {
  46         env => \%ENV, opt => $opt, cmd => 'public-inbox-clone',
  47         0 => *STDIN{GLOB}, 2 => *STDERR{GLOB},
  48 }, 'PublicInbox::LEI';
  49 open $lei->{1}, '+<&=', 1 or die "dup: $!";
  50 open $lei->{3}, '.' or die "open . $!";
  51 my $mrr = bless {
  52         lei => $lei,
  53         src => $url,
  54         dst => $dst,
  55 }, 'PublicInbox::LeiMirror';
  56
  57 $? = 0;
  58 $mrr->do_mirror;
  59 $mrr->can('_wq_done_wait')->([$mrr, $lei], $$);
  60 exit(($lei->{child_error} // 0) >> 8);