script/public-inbox-compact

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use warnings;
   6 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
   7 use PublicInbox::Search;
   8 use PublicInbox::Config;
   9 use PublicInbox::InboxWritable;
  10 use Cwd 'abs_path';
  11 use File::Temp qw(tempdir);
  12 use File::Path qw(remove_tree);
  13 use PublicInbox::Spawn qw(spawn);
  14 my $usage = "Usage: public-inbox-compact REPO_DIR\n";
  15 my $dir = shift or die $usage;
  16 my $config = PublicInbox::Config->new;
  17 my $ibx;
  18 $dir = abs_path($dir);
  19 $config->each_inbox(sub {
  20         $ibx = $_[0] if abs_path($_[0]->{mainrepo}) eq $dir
  21 });
  22 unless ($ibx) {
  23         warn "W: $dir not configured in ".
  24                 PublicInbox::Config::default_file() . "\n";
  25         $ibx = {
  26                 mainrepo => $dir,
  27                 name => 'ignored',
  28                 address => [ 'old@example.com' ],
  29         };
  30         $ibx = PublicInbox::Inbox->new($ibx);
  31 }
  32 my $v = ($ibx->{version} || 1);
  33 $ibx = PublicInbox::InboxWritable->new($ibx);
  34 $ibx->umask_prepare;
  35
  36 sub commit_changes ($$$) {
  37         my ($im, $old, $new) = @_;
  38         my @st = stat($old) or die "failed to stat($old): $!\n";
  39
  40         my $over = "$old/over.sqlite3";
  41         if (-f $over) {
  42                 require PublicInbox::Over;
  43                 $over = PublicInbox::Over->new($over);
  44                 $over->connect->sqlite_backup_to_file("$new/over.sqlite3");
  45         }
  46         rename($old, "$new/old") or die "rename $old => $new/old: $!\n";
  47         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  48         rename($new, $old) or die "rename $new => $old: $!\n";
  49         $im->lock_release;
  50         remove_tree("$old/old") or die "failed to remove $old/old: $!\n";
  51 }
  52 my @compact = qw(xapian-compact --no-renumber);
  53 if ($v == 2) {
  54         require PublicInbox::V2Writable;
  55         my $v2w = PublicInbox::V2Writable->new($ibx);
  56         my $xap_v = 'xap'.PublicInbox::Search::SCHEMA_VERSION;
  57         my $old = "$dir/$xap_v";
  58         opendir my $dh, $old or die "Failed to opendir $old: $!\n";
  59         my $new = tempdir('compact-XXXXXXXX', CLEANUP => 1, DIR => $dir);
  60         $ibx->with_umask(sub {
  61                 $v2w->lock_acquire;
  62                 my %pids;
  63                 while (defined(my $dn = readdir($dh))) {
  64                         if ($dn =~ /\A\d+\z/) {
  65                                 my $cmd = [ @compact, "$old/$dn", "$new/$dn" ];
  66                                 $pids{spawn($cmd)} = join(' ', @$cmd);
  67                         } elsif ($dn eq '.' || $dn eq '..') {
  68                         } elsif ($dn =~ /\Aover\.sqlite3/) {
  69                         } else {
  70                                 warn "W: skipping unknown Xapian DB: $old/$dn\n"
  71                         }
  72                 }
  73                 close $dh;
  74                 die "No Xapian parts found in $old\n" unless keys %pids;
  75                 while (scalar keys %pids) {
  76                         my $pid = waitpid(-1, 0);
  77                         my $desc = delete $pids{$pid};
  78                         die "$desc failed: $?\n" if $?;
  79                 }
  80                 commit_changes($v2w, $old, $new);
  81         });
  82 } elsif ($v == 1) {
  83         require PublicInbox::Import;
  84         my $im = PublicInbox::Import->new($ibx->git, undef, undef, $ibx);
  85         my $xap_v = 'xapian'.PublicInbox::Search::SCHEMA_VERSION;
  86         my $v1_root = "$dir/public-inbox";
  87         my $old = "$v1_root/$xap_v";
  88         -d $old or die "$old does not exist\n";
  89         my $new = tempdir('compact-XXXXXXXX', CLEANUP => 1, DIR => $v1_root);
  90         $ibx->with_umask(sub {
  91                 $im->lock_acquire;
  92                 PublicInbox::Import::run_die([@compact, $old, $new]);
  93                 commit_changes($im, $old, $new);
  94         });
  95 } else {
  96         die "Unsupported inbox version: $v\n";
  97 }