script/public-inbox-compact

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use warnings;
   6 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
   7 use PublicInbox::V2Writable;
   8 use PublicInbox::Search;
   9 use PublicInbox::Config;
  10 use Cwd 'abs_path';
  11 use File::Temp qw(tempdir);
  12 use File::Path qw(remove_tree);
  13 my $usage = "Usage: public-inbox-compact REPO_DIR\n";
  14 my $dir = shift or die $usage;
  15 my $config = PublicInbox::Config->new;
  16 my $ibx;
  17 $dir = abs_path($dir);
  18 $config->each_inbox(sub {
  19         $ibx = $_[0] if abs_path($_[0]->{mainrepo}) eq $dir
  20 });
  21 unless ($ibx) {
  22         warn "W: $dir not configured in ".
  23                 PublicInbox::Config::default_file() . "\n";
  24         $ibx = {
  25                 mainrepo => $dir,
  26                 name => 'ignored',
  27                 address => [ 'old@example.com' ],
  28         };
  29         $ibx = PublicInbox::Inbox->new($ibx);
  30 }
  31 my $v = ($ibx->{version} || 1);
  32 $ibx = PublicInbox::InboxWritable->new($ibx);
  33 $ibx->umask_prepare;
  34
  35 sub commit_changes ($$$) {
  36         my ($im, $old, $new) = @_;
  37         my @st = stat($old) or die "failed to stat($old): $!\n";
  38         link("$old/over.sqlite3", "$new/over.sqlite3") or die
  39                 "failed to link {$old => $new}/over.sqlite3: $!\n";
  40         rename($old, "$new/old") or die "rename $old => $new/old: $!\n";
  41         chmod($st[2] & 07777, $new) or die "chmod $old: $!\n";
  42         rename($new, $old) or die "rename $new => $old: $!\n";
  43         $im->lock_release;
  44         remove_tree("$old/old") or die "failed to remove $old/old: $!\n";
  45 }
  46
  47 if ($v == 2) {
  48         require PublicInbox::V2Writable;
  49         my $v2w = PublicInbox::V2Writable->new($ibx);
  50         my $xap_v = 'xap'.PublicInbox::Search::SCHEMA_VERSION;
  51         my $old = "$dir/$xap_v";
  52         opendir my $dh, $old or die "Failed to opendir $old: $!\n";
  53         my $new = tempdir('compact-XXXXXXXX', CLEANUP => 1, DIR => $dir);
  54         $ibx->with_umask(sub {
  55                 $v2w->lock_acquire;
  56                 my @parts;
  57                 while (defined(my $dn = readdir($dh))) {
  58                         if ($dn =~ /\A\d+\z/) {
  59                                 push @parts, "$old/$dn";
  60                         } elsif ($dn eq '.' || $dn eq '..') {
  61                         } else {
  62                                 warn "W: skipping unknown Xapian DB: $old/$dn\n"
  63                         }
  64                 }
  65                 close $dh;
  66                 die "No Xapian parts found in $old\n" unless @parts;
  67                 my $cmd = ['xapian-compact', @parts, "$new/0" ];
  68                 PublicInbox::Import::run_die($cmd);
  69                 commit_changes($v2w, $old, $new);
  70         });
  71 } elsif ($v == 1) {
  72         require PublicInbox::Import;
  73         my $im = PublicInbox::Import->new($ibx->git, undef, undef, $ibx);
  74         my $xap_v = 'xapian'.PublicInbox::Search::SCHEMA_VERSION;
  75         my $v1_root = "$dir/public-inbox";
  76         my $old = "$v1_root/$xap_v";
  77         -d $old or die "$old does not exist\n";
  78         my $new = tempdir('compact-XXXXXXXX', CLEANUP => 1, DIR => $v1_root);
  79         $ibx->with_umask(sub {
  80                 $im->lock_acquire;
  81                 PublicInbox::Import::run_die(['xapian-compact', $old, $new]);
  82                 commit_changes($im, $old, $new);
  83         });
  84 } else {
  85         die "Unsupported inbox version: $v\n";
  86 }