script/public-inbox-edit

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Used for editing messages in a public-inbox.
   6 # Supports v2 inboxes only, for now.
   7 use strict;
   8 use warnings;
   9 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  10 use PublicInbox::AdminEdit;
  11 use File::Temp 0.19 (); # 0.19 for TMPDIR
  12 use PublicInbox::ContentHash qw(content_hash);
  13 use PublicInbox::MID qw(mid_clean mids);
  14 PublicInbox::Admin::check_require('-index');
  15 use PublicInbox::Eml;
  16 use PublicInbox::InboxWritable;
  17 use PublicInbox::Import;
  18
  19 my $usage = "$0 -m MESSAGE_ID [--all] [INBOX_DIRS]";
  20 my $opt = { verbose => 1, all => 0, -min_inbox_version => 2, raw => 0 };
  21 my @opt = qw(mid|m=s file|F=s raw);
  22 GetOptions($opt, @PublicInbox::AdminEdit::OPT, @opt) or
  23         die "bad command-line args\n$usage\n";
  24
  25 my $cfg = PublicInbox::Config->new;
  26 my $editor = $ENV{MAIL_EDITOR}; # e.g. "mutt -f"
  27 unless (defined $editor) {
  28         my $k = 'publicinbox.mailEditor';
  29         $editor = $cfg->{lc($k)} if $cfg;
  30         unless (defined $editor) {
  31                 warn "\`$k' not configured, trying \`git var GIT_EDITOR'\n";
  32                 chomp($editor = `git var GIT_EDITOR`);
  33                 warn "Will use $editor to edit mail\n";
  34         }
  35 }
  36
  37 my $mid = $opt->{mid};
  38 my $file = $opt->{file};
  39 if (defined $mid && defined $file) {
  40         die "the --mid and --file options are mutually exclusive\n";
  41 }
  42
  43 my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, $opt, $cfg);
  44 PublicInbox::AdminEdit::check_editable(\@ibxs);
  45
  46 my $found = {}; # chash => [ [ibx, smsg] [, [ibx, smsg] ] ]
  47
  48 sub find_mid ($$$) {
  49         my ($found, $mid, $ibxs) = @_;
  50         foreach my $ibx (@$ibxs) {
  51                 my $over = $ibx->over;
  52                 my ($id, $prev);
  53                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
  54                         my $ref = $ibx->msg_by_smsg($smsg);
  55                         my $mime = PublicInbox::Eml->new($ref);
  56                         my $chash = content_hash($mime);
  57                         my $tuple = [ $ibx, $smsg ];
  58                         push @{$found->{$chash} ||= []}, $tuple
  59                 }
  60                 PublicInbox::InboxWritable::cleanup($ibx);
  61         }
  62         $found;
  63 }
  64
  65 sub show_cmd ($$) {
  66         my ($ibx, $smsg) = @_;
  67         " GIT_DIR=$ibx->{inboxdir}/all.git \\\n    git show $smsg->{blob}\n";
  68 }
  69
  70 sub show_found ($) {
  71         my ($found) = @_;
  72         foreach my $to_edit (values %$found) {
  73                 foreach my $tuple (@$to_edit) {
  74                         my ($ibx, $smsg) = @$tuple;
  75                         warn show_cmd($ibx, $smsg);
  76                 }
  77         }
  78 }
  79
  80 if (defined($mid)) {
  81         $mid = mid_clean($mid);
  82         find_mid($found, $mid, \@ibxs);
  83         my $nr = scalar(keys %$found);
  84         die "No message found for <$mid>\n" unless $nr;
  85         if ($nr > 1) {
  86                 warn <<"";
  87 Multiple messages with different content found matching
  88 <$mid>:
  89
  90                 show_found($found);
  91                 die "Use --force to edit all of them\n" if !$opt->{force};
  92                 warn "Will edit all of them\n";
  93         }
  94 } else {
  95         my $mime = PublicInbox::InboxWritable::mime_from_path($file) or
  96                 die "open($file) failed: $!";
  97         my $mids = mids($mime->header_obj);
  98         find_mid($found, $_, \@ibxs) for (@$mids); # populates $found
  99         my $chash = content_hash($mime);
 100         my $to_edit = $found->{$chash};
 101         unless ($to_edit) {
 102                 my $nr = scalar(keys %$found);
 103                 if ($nr > 0) {
 104                         warn <<"";
 105 $nr matches to Message-ID(s) in $file, but none matched content
 106 Partial matches below:
 107
 108                         show_found($found);
 109                 } elsif ($nr == 0) {
 110                         $mids = join('', map { "  <$_>\n" } @$mids);
 111                         warn <<"";
 112 No matching messages found matching Message-ID(s) in $file
 113 $mids
 114
 115                 }
 116                 exit 1;
 117         }
 118         $found = { $chash => $to_edit };
 119 }
 120
 121 my %tmpopt = (
 122         TEMPLATE => 'public-inbox-edit-XXXXXX',
 123         TMPDIR => 1,
 124         SUFFIX => $opt->{raw} ? '.eml' : '.mbox',
 125 );
 126
 127 foreach my $to_edit (values %$found) {
 128         my $edit_fh = File::Temp->new(%tmpopt);
 129         $edit_fh->autoflush(1);
 130         my $edit_fn = $edit_fh->filename;
 131         my ($ibx, $smsg) = @{$to_edit->[0]};
 132         my $old_raw = $ibx->msg_by_smsg($smsg);
 133         PublicInbox::InboxWritable::cleanup($ibx);
 134
 135         my $tmp = $$old_raw;
 136         if (!$opt->{raw}) {
 137                 my $oid = $smsg->{blob};
 138                 print $edit_fh "From mboxrd\@$oid Thu Jan  1 00:00:00 1970\n"
 139                         or die "failed to write From_ line: $!";
 140                 $tmp =~ s/^(>*From )/>$1/gm;
 141         }
 142         print $edit_fh $tmp or
 143                 die "failed to write tempfile for editing: $!";
 144
 145         # run the editor, respecting spaces/quote
 146 retry_edit:
 147         if (system(qw(sh -c), $editor.' "$@"', $editor, $edit_fn)) {
 148                 if (!(-t STDIN) && !$opt->{force}) {
 149                         die "E: $editor failed: $?\n";
 150                 }
 151                 print STDERR "$editor failed, ";
 152                 print STDERR "continuing as forced\n" if $opt->{force};
 153                 while (!$opt->{force}) {
 154                         print STDERR "(r)etry, (c)ontinue, (q)uit?\n";
 155                         chomp(my $op = <STDIN> || '');
 156                         $op = lc($op);
 157                         goto retry_edit if $op eq 'r';
 158                         if ($op eq 'q') {
 159                                 # n.b. we'll lose the exit signal, here,
 160                                 # oh well; "q" is user-specified anyways.
 161                                 exit($? >> 8);
 162                         }
 163                         last if $op eq 'c'; # continuing
 164                         print STDERR "\`$op' not recognized\n";
 165                 }
 166         }
 167
 168         # reread the edited file, not using $edit_fh since $EDITOR may
 169         # rename/relink $edit_fn
 170         open my $new_fh, '<', $edit_fn or
 171                 die "can't read edited file ($edit_fn): $!\n";
 172         my $new_raw = do { local $/; <$new_fh> };
 173
 174         if (!$opt->{raw}) {
 175                 # get rid of the From we added
 176                 $new_raw =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 177
 178                 # check if user forgot to purge (in mutt) after editing
 179                 if ($new_raw =~ /^From /sm) {
 180                         if (-t STDIN) {
 181                                 print STDERR <<'';
 182 Extra "From " lines detected in new mbox.
 183 Did you forget to purge the original message from the mbox after editing?
 184
 185                                 while (1) {
 186                                         print STDERR <<"";
 187 (y)es to re-edit, (n)o to continue
 188
 189                                         chomp(my $op = <STDIN> || '');
 190                                         $op = lc($op);
 191                                         goto retry_edit if $op eq 'y';
 192                                         last if $op eq 'n'; # continuing
 193                                         print STDERR "\`$op' not recognized\n";
 194                                 }
 195                         } else { # non-interactive path
 196                                 # unlikely to happen, as extra From lines are
 197                                 # only a common mistake (for me) with
 198                                 # interactive use
 199                                 warn <<"";
 200 W: possible message boundary splitting error
 201
 202                         }
 203                 }
 204                 # unescape what we escaped:
 205                 $new_raw =~ s/^>(>*From )/$1/gm;
 206         }
 207
 208         my $new_mime = PublicInbox::Eml->new(\$new_raw);
 209         my $old_mime = PublicInbox::Eml->new($old_raw);
 210
 211         # make sure we don't compare unwanted headers, since mutt adds
 212         # Content-Length, Status, and Lines headers:
 213         PublicInbox::Import::drop_unwanted_headers($new_mime);
 214         PublicInbox::Import::drop_unwanted_headers($old_mime);
 215
 216         # allow changing Received: and maybe other headers which can
 217         # contain sensitive info.
 218         my $nhdr = $new_mime->header_obj;
 219         my $ohdr = $old_mime->header_obj;
 220         if (($nhdr->as_string eq $ohdr->as_string) &&
 221             (content_hash($new_mime) eq content_hash($old_mime))) {
 222                 warn "No change detected to:\n", show_cmd($ibx, $smsg);
 223
 224                 next unless $opt->{verbose};
 225                 # should we consider this machine-parseable?
 226                 PublicInbox::AdminEdit::show_rewrites(\*STDOUT, $ibx, []);
 227                 next;
 228         }
 229
 230         foreach my $tuple (@$to_edit) {
 231                 $ibx = PublicInbox::InboxWritable->new($tuple->[0]);
 232                 $smsg = $tuple->[1];
 233                 my $im = $ibx->importer(0);
 234                 my $commits = $im->replace($old_mime, $new_mime);
 235                 $im->done;
 236                 unless ($commits) {
 237                         warn "Failed to replace:\n", show_cmd($ibx, $smsg);
 238                         next;
 239                 }
 240                 next unless $opt->{verbose};
 241                 # should we consider this machine-parseable?
 242                 PublicInbox::AdminEdit::show_rewrites(\*STDOUT, $ibx, $commits);
 243         }
 244 }