script/public-inbox-httpd

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Standalone HTTP server for public-inbox.
   6 use strict;
   7 use warnings;
   8 use Plack::Util;
   9 use PublicInbox::Daemon;
  10 use PublicInbox::HTTP;
  11 use Plack::Request;
  12 use Plack::Builder;
  13 my %httpds;
  14 my $app;
  15 my $refresh = sub {
  16         if (@ARGV) {
  17                 eval { $app = Plack::Util::load_psgi(@ARGV) };
  18                 if ($@) {
  19                         die $@,
  20 "$0 runs in /, command-line paths must be absolute\n";
  21                 }
  22         } else {
  23                 require PublicInbox::WWW;
  24                 PublicInbox::WWW->preload;
  25                 my $www = PublicInbox::WWW->new;
  26                 $app = eval {
  27                         builder {
  28                                 enable 'Chunked';
  29                                 eval {
  30                                         enable 'Deflater',
  31                                                 content_type => [ qw(
  32                                                         text/html
  33                                                         text/plain
  34                                                         application/atom+xml
  35                                                         )]
  36                                 };
  37                                 $@ and warn
  38 "Plack::Middleware::Deflater missing, bandwidth will be wasted\n";
  39
  40                                 eval { enable 'ReverseProxy' };
  41                                 $@ and warn
  42 "Plack::Middleware::ReverseProxy missing,\n",
  43 "URL generation for redirects may be wrong if behind a reverse proxy\n";
  44
  45                                 enable 'Head';
  46                                 sub { $www->call(@_) };
  47                         };
  48                 };
  49         }
  50 };
  51
  52 daemon_run('0.0.0.0:8080', $refresh,
  53         sub ($$$) { # post_accept
  54                 my ($client, $addr, $srv) = @_;
  55                 my $fd = fileno($srv);
  56                 my $h = $httpds{$fd} ||= PublicInbox::HTTPD->new($srv, $app);
  57                 PublicInbox::HTTP->new($client, $addr, $h),
  58         });
  59
  60 1;
  61
  62 package PublicInbox::HTTPD::Async;
  63 use strict;
  64 use warnings;
  65 use base qw(Danga::Socket);
  66 use fields qw(cb);
  67
  68 sub new {
  69         my ($class, $io, $cb) = @_;
  70         my $self = fields::new($class);
  71         IO::Handle::blocking($io, 0);
  72         $self->SUPER::new($io);
  73         $self->{cb} = $cb;
  74         $self->watch_read(1);
  75         $self;
  76 }
  77
  78 sub event_read { $_[0]->{cb}->() }
  79 sub event_hup { $_[0]->{cb}->() }
  80 sub event_err { $_[0]->{cb}->() }
  81 sub sysread { shift->{sock}->sysread(@_) }
  82
  83 1;
  84
  85 package PublicInbox::HTTPD;
  86 use strict;
  87 use warnings;
  88 use Plack::Util;
  89
  90 sub pi_httpd_async {
  91         my ($io, $cb) = @_;
  92         PublicInbox::HTTPD::Async->new($io, $cb);
  93 }
  94
  95 sub new {
  96         my ($class, $sock, $app) = @_;
  97         my $n = getsockname($sock) or die "not a socket: $sock $!\n";
  98         my ($port, $addr);
  99         if (length($n) >= 28) {
 100                 require Socket6;
 101                 ($port, $addr) = Socket6::unpack_sockaddr_in6($n);
 102         } else {
 103                 ($port, $addr) = Socket::unpack_sockaddr_in($n);
 104         }
 105
 106         my %env = (
 107                 REMOTE_HOST => '',
 108                 REMOTE_PORT => 0,
 109                 SERVER_NAME => $addr,
 110                 SERVER_PORT => $port,
 111                 SCRIPT_NAME => '',
 112                 'psgi.version' => [ 1, 1 ],
 113                 'psgi.errors' => \*STDERR,
 114                 'psgi.url_scheme' => 'http',
 115                 'psgi.nonblocking' => Plack::Util::TRUE,
 116                 'psgi.streaming' => Plack::Util::TRUE,
 117                 'psgi.run_once'  => Plack::Util::FALSE,
 118                 'psgi.multithread' => Plack::Util::FALSE,
 119                 'psgi.multiprocess' => Plack::Util::TRUE,
 120                 'psgix.harakiri'=> Plack::Util::FALSE,
 121                 'psgix.input.buffered' => Plack::Util::TRUE,
 122                 'pi-httpd.async' => do {
 123                         no warnings 'once';
 124                         *pi_httpd_async
 125                 },
 126         );
 127         bless {
 128                 err => \*STDERR,
 129                 out => \*STDOUT,
 130                 app => $app,
 131                 env => \%env,
 132         }, $class;
 133 }
 134
 135 1;